Topic: Challenge: Plaque ...

[MP]

Challenge: Write a routine that inserts an arbitrary item between every item in a list. If the list contains only one item it should return the list unaltered.

Example:

(plaque '* '(tooth tooth tooth))

Should return (tooth * tooth * tooth)

(plaque '* '(tooth))

Should return (tooth)

My stabs ...

Code: [Select]

;; iterative using foreach

(defun plaque ( x lst / result )
    (cons (car lst)
        (foreach item (reverse (cdr lst))
            (setq result
                (cons x (cons item result))  
            )
        )
    )
)

;;  using mapcar

(defun plaque ( x lst )
    (cons (car lst)
        (apply 'append
            (mapcar
               '(lambda (item) (list x item))
                (cdr lst)
            )
        )
    )
)

;;  recursive

(defun plaque ( x lst / tail )
    (if lst
        (if (setq tail (cdr lst))
            (cons
                (car lst)
                (cons x (plaque x tail))    
            )
            lst
        )    
    )    
)

[Kerry]

Can I " phone a dentist " for help ?

[MP]

[CAB]

Code: [Select]

(defun plaque ( x lst / r )
  (setq r (list (car lst)))
  (while (setq lst (cdr lst))
    (setq r (cons x r)
          r (cons (car lst) r))
  )
  (reverse r)
)

[MP]

Excellent CAB, that would work.

Remember ToString?

Given this --

Code: [Select]

(defun Plaque ( x lst )
    (cons (car lst)
        (apply 'append
            (mapcar
               '(lambda (item) (list x item))
                (cdr lst)
            )
        )
    )
)
This is now more elegant to me:

Code: [Select]

(defun ToString ( x / typex )
    (cond
        (   (eq 'str (setq typex (type x)))
            (strcat "\"" x "\"")
        )
        (   (eq 'real typex)
            (rtos x 2 (if (zerop (- x (fix x))) 1 15))
        )
        (   (eq 'list typex)
            (strcat
                (chr 40)
                (if (vl-list-length x)
                    (apply 'strcat
                        (plaque " "
                            (mapcar 'ToString x)
                        )
                    )
                    (strcat
                        (ToString (car x))
                        " . "
                        (ToString (cdr x))
                    )
                )
                (chr 41)
            )
        )
        ((vl-princ-to-string x))
    )
)
Making things like this a real quick snap --

Code: [Select]

(defun ListToCsv ( lst )
    (apply 'strcat
        (plaque ","
            (mapcar 'ToString lst)
        )
    )
)