Topic: 2 points - crossing fence intersections - fast solution

[ribarm]

Hi, I have an issue to solve... I have 2 points and I want to check if some entities passes through fence created by those 2 points... I don't want to use (ssget "_F" (list p1 p2)) as it's slow and for some reason it's little buggy... I need checking weather points or entities are on visible screen or not... I just need fast and correct return (I don't want to entmake line p1 p2 and set visibility DXF 66 to 1 and check it with 'IntersectWith method - I don't want to iterate through database)... So if someone knows how please reply... Any help will be nice...

[ribarm]

I solved problem still with iteration, but fortunately now my main routine works correct (slow but correct)...

Code - Auto/Visual Lisp: [Select]

1. (defun p1p2intss ( p1 p2 ss df / i ent k p pl v1 d pll rtn ) (vl-load-com)
2.   (repeat (setq i (sslength ss))
3.     (setq ent (ssname ss (setq i (1- i))))
4.     (if (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-curve-getstartpoint (list ent))))
5.       (progn
6.         (setq k -0.5)
7.         (repeat (fix (/ (vlax-curve-getdistatparam ent (vlax-curve-getendparam ent)) df))
8.           (setq p (vlax-curve-getpointatdist ent (* df (setq k (1+ k)))))
9.           (setq pl (cons p pl))
10.         )
11.       )
12.     )
13.   )
14.   (setq v1 (mapcar '/ (mapcar '- p2 p1) (list (setq d (distance p1 p2)) d d)))
15.   (setq k -0.5)
16.   (repeat (fix (/ d df))
17.     (setq p (mapcar '+ p1 (mapcar '* v1 (list (* df (setq k (1+ k))) (* df k) (* df k)))))
18.     (setq pll (cons p pll))
19.   )
20.   (while (and (not rtn) pll)
21.     (setq p (car pll))
22.     (if (vl-some '(lambda ( x ) (< (distance x p) df)) pl)
23.       (setq rtn t)
24.       (setq rtn nil)
25.     )
26.     (setq pll (cdr pll))
27.   )
28.   rtn
29. )
30.  

Thanks, M.R.

[roy_043]

Marko, I don't understand. Your solution does not match the criteria set out in your first post. Also there is a new criterion ('only curves'). And where in your code do you check 'whether points or entities are on visible screen or not'?

As an aside: Your code assumes that one of the point lists (pll) is the shortest of the two. This need not be the case.

[ribarm]

Roy, yes I need it just for curves and placed in WCS... Two points are also in WCS... As I said I don't want to use (ssget) and not to create dummy line from p1 to p2... My function provides me the result quite fine to what I've expected (intersection may occur as a result only inaccurate at some small fuzz distances near endpoints of curves, otherwise I need to get T or nil and function does this pretty good)... Yes pll point list is smaller point list and it describes points representing imaginary line from p1 to p2... So I am checking smaller distances near those points that represent p1 p2 line and I think function may be very good and for checking 3D "intersections"... I have bigger code where I use this function in lieu to (ssget) and it doesn't matter weather curves or supplied points p1 or p2 are visible on screen or not... Function should calculate correct result...

Hope I've explained, M.R.

[roy_043]

Marko, you have misunderstood my previous post. I do understand your code. But how can it be 'quite fine' if it does not meet your own criteria? Your solution uses ssget (how else do you get a selection set?), it is iterative and slow. Three things that you clearly did not want.

[Lee Mac]

Why not simply:

Code - Auto/Visual Lisp: [Select]

1. (defun fence-p ( p q )
2.     (eval
3.         (list 'defun 'fence-p '( p q / r )
4.             (list 'vla-zoomwindow (vlax-get-acad-object)
5.                '(vlax-3D-point (mapcar 'min p q))
6.                '(vlax-3D-point (mapcar 'max p q))
7.             )
8.            '(setq r (ssget "_F" (list p q)))
9.             (list 'vla-zoomprevious (vlax-get-acad-object))
10.            'r
11.         )
12.     )
13.     (fence-p p q)
14. )

[RGUS]

Why not simply:

Code - Auto/Visual Lisp: [Select]

1. (defun fence-p ( p q )
2.     (eval
3.         (list 'defun 'fence-p '( p q / r )
4.             (list 'vla-zoomwindow (vlax-get-acad-object)
5.                '(vlax-3D-point (mapcar 'min p q))
6.                '(vlax-3D-point (mapcar 'max p q))
7.             )
8.            '(setq r (ssget "_F" (list p q)))
9.             (list 'vla-zoomprevious (vlax-get-acad-object))
10.            'r
11.         )
12.     )
13.     (fence-p p q)
14. )

Lee... I have to say... I really, really love the way you say... "Why not simply" ... and the rest of us go.... sigh!

[roy_043]

I don't know if Marko is referring to this problem when he speaks of 'buggy' in his first post, but (ssget "_F" ...) has a known issue with non-continuous linetypes. If the fence passes through a 'linetype gap' of an entity it will not be selected at that intersection. A similar problem occurs with the "_C" option of ssget: if the crossing falls inside a linetype gap of, for example, a line, the line will not be selected.

[Lee Mac]

Lee... I have to say... I really, really love the way you say... "Why not simply" ... and the rest of us go.... sigh!

 

(ssget "_F" ...) has a known issue with non-continuous linetypes. If the fence passes through a 'linetype gap' of an entity it will not be selected at that intersection. A similar problem occurs with the "_C" option of ssget: if the crossing falls inside a linetype gap of, for example, a line, the line will not be selected.

The following may reduce (but not completely eliminate) that risk:

Code - Auto/Visual Lisp: [Select]

1. (defun fence-p ( p q )
2.     (eval
3.         (list 'defun 'fence-p '( p q / idx obj rtn sel tmp )
4.             (list 'vla-zoomwindow (vlax-get-acad-object)
5.                '(vlax-3D-point (mapcar 'min p q))
6.                '(vlax-3D-point (mapcar 'max p q))
7.             )
8.            '(cond
9.                 (   (setq rtn (ssget "_F" (list p q))))
10.                 (   (setq sel (ssget "_C" p q))
11.                     (setq tmp (entmakex (list '(0 . "LINE") (cons 10 p) (cons 11 q)))
12.                           tmp (vlax-ename->vla-object tmp)
13.                           idx -1
14.                     )
15.                     (while (and (setq obj (ssname sel (setq idx (1+ idx)))) (null rtn))
16.                         (if (vlax-method-applicable-p (setq obj (vlax-ename->vla-object obj)) 'intersectwith)
17.                             (setq rtn (vlax-invoke obj 'intersectwith tmp acextendnone))
18.                         )
19.                     )
20.                     (vla-delete tmp)
21.                 )
22.             )  
23.             (list 'vla-zoomprevious (vlax-get-acad-object))
24.            '(and rtn)
25.         )
26.     )
27.     (fence-p p q)
28. )

[ribarm]

Marko, you have misunderstood my previous post. I do understand your code. But how can it be 'quite fine' if it does not meet your own criteria? Your solution uses ssget (how else do you get a selection set?), it is iterative and slow. Three things that you clearly did not want.

Yes, firstly in my main routine I select entities, but then I don't want to repeat (ssget "_F" (list p1 p2))... Yes, it's also buggy because of linetypes what I've forgot to test, but anyhow if there is some better solution than this "ssget", I am all your ears...

[ribarm]

Hi again, I want to thank to all... I've found that (ssget "_F" (list p1 p2)) was not buggy, but I forgot to (entdel ent) before (ssget) call and as I was testing (not (ssget "_F" (list p1 p2))) it always returned nil and my then statement wasn't processed... Now that's fixed, but have never thought ab linetypes like Roy stated... Nevertheless my issue was solved as I don't use too much dashed lines (curves) and now main routine is fast and produce desired results... Thanks to all, I just stumbled on a problem I tried to solve on my own way and missed to deeply check my main routine... Sorry for my subjective observation ab (ssget), but who knows maybe someone will find this topic useful after all...

Once again my apology if I took someones valuable time in tying to help me, I won't forget... Marko R.