Topic: Batch hyperlinking based on attribute names in blocks

[ahazen]

I have hyperlinks to attach with names like 360-001.html or www.website.com/360-001. I was wondering if I could get help automating the hyperlinking process for these blocks. So block with attribute "001" would automatically be hyperlinked with www.website.com/360-001 when the command is run.

[ronjonp]

Is the attribute TAG named "001" or is that the value for the attribute? .. BTW .. welcome to TheSwamp 
HERE's a thread you can reference for adding a URL to an object.

[ahazen]

Thanks for the welcome! I hope to learn  . The TAG is 001. In this specific situation the attribute value is 360. I want to utilize the tag.

[ahazen]

Wait. I meant I want the Value for the attribute. Sorry, I flipped those mentally. The tag is 360 and the value is 001.

[ronjonp]

Give this a try:

Code - Auto/Visual Lisp: [Select]

1. (defun c:puturl (/ _ss2l tag val)
2.   (vl-load-com)
3.   (defun _ss2l (ss / n result)
4.     (if (= (type ss) 'pickset)
5.       (repeat (setq n (sslength ss)) (setq result (cons (ssname ss (setq n (1- n))) result)))
6.     )
7.   )
8.   (setq tag "360")
9.   (regapp "PE_URL")
10.   (foreach ename (_ss2l (ssget ":L" '((0 . "insert") (66 . 1))))
11.     (if
12.       (and
13.         (vl-some '(lambda (x) (and (= tag (vla-get-tagstring x)) (setq val (vla-get-textstring x))))
14.                  (vlax-invoke (vlax-ename->vla-object ename) 'getattributes)
15.         )
16.         (setq val (strcat "www.website.com/" tag "-" val))
17.       )
18.        (entmod (append (entget ename)
19.                        (list (list -3
20.                                    (list "PE_URL"
21.                                          (cons 1000 val)
22.                                          '(1002 . "{")
23.                                          (cons 1000 val)
24.                                          '(1002 . "{")
25.                                          '(1071 . 0)
26.                                          '(1002 . "}")
27.                                          '(1002 . "}")
28.                                    )
29.                              )
30.                        )
31.                )
32.        )
33.     )
34.   )
35.   (princ)
36. )

[ahazen]

That is working, I'll make some edits and get back to you, but that gave me the parts I was missing!

Thanks, that's a positive first impression to the forum!

[ronjonp]

Glad to help

[Lee Mac]

Another, using ActiveX:

Code - Auto/Visual Lisp: [Select]

1. (defun c:batchurl ( / h i o s v )
2.      (if (setq s (ssget "_:L" '((0 . "INSERT") (66 . 1))))
3.          (repeat (setq i (sslength s))
4.              (if (setq o (vlax-ename->vla-object (ssname s (setq i (1- i))))
5.                        h (vla-get-hyperlinks o)
6.                        v (vl-some '(lambda ( x ) (if (= "360" (vla-get-tagstring x)) (vla-get-textstring x))) (vlax-invoke o 'getattributes))
7.                  )
8.                  (if (zerop (vla-get-count h)) (vla-add h (strcat "www.website.com/360-" v)))
9.              )
10.          )
11.      )
12.      (princ)
13. )
14. (vl-load-com) (princ)

The above will only add a new hyperlink if the block has no existing hyperlinks to avoid duplication.

[roy_043]

@ ronjonp:
You are using entmod twice. I think the first call is not necessary.

[ronjonp]

@ ronjonp:
You are using entmod twice. I think the first call is not necessary.

Ahh yes .. that carried over from the other thread referenced to keep an existing hyperlink but change the text shown. Updated above.

[roy_043]

Ahh yes .. that carried over from the other thread referenced to keep an existing hyperlink but change the text shown. Updated above.

I don't know the thread you are referring to. But whenever you write new Xdata for an aplication all the old data is automatically removed. You cannot update a single item or append data. So I think that in the 'other thread' there is then also a superfluous call to entmod.

[ronjonp]

Ahh yes .. that carried over from the other thread referenced to keep an existing hyperlink but change the text shown. Updated above.

I don't know the thread you are referring to. But whenever you write new Xdata for an aplication all the old data is automatically removed. You cannot update a single item or append data. So I think that in the 'other thread' there is then also a superfluous call to entmod.

You are correct it is superfluous. I'll try to be better in the future    We also need to check that PE_URL is registered before writing xdata ( updated in code above ) .