Topic: Marko, How Rotating 3D SOLID quickly ?

[andy_lee]

Hi marko .

Sometimes , need import 3D solid from  solidworks. (solidworks export "*.STEP" format , autocad import )

But , when import it……

This is "Front" view ,is not I need.


This is I need.


This is "SW ISOMETRIC" view ,is not I need.


This is I need



So, when I import it  ,How quick rotate  3D SOLID  to what I need  ?

1. choose all 3D object ,2. Choose a face  align X axis , 3. Choose a face align Y axis ?

Test DWG at #2



======================================================================













=======================================================================

[andy_lee]

command "_3drotate" is not I need.

Specify base point:
Pick a rotation axis: difficile to pick
Specify angle start point or type an angle:  I don't know the angle

This is Test.dwg

[ribarm]

Emk, I don't have my comp. at the moment and I am typing this from my phone... I am away from where I live and cant answer you until I came back home... Hope youll find solution and without my help... Sorry, but I cant analyze your request the way I would like to... Have a nice day and my regards to you and all swampers... M.R.

[andy_lee]

Emk, I don't have my comp. at the moment and I am typing this from my phone... I am away from where I live and cant answer you until I came back home... Hope youll find solution and without my help... Sorry, but I cant analyze your request the way I would like to... Have a nice day and my regards to you and all swampers... M.R.

Hi Marko. I can't find any solution from THESWAMP and CADTUTOR , but I can wait for you.
Thank you very much .

Best regards!

[ribarm]

Emk, Ill be absent for ab 2 weeks... I am sure someone will reply till then... My kind regards, Marko...

[roy_043]

Here is a solution using the TransformBy method.
The function c:test uses InverseMatrix by Gile.
The final result will vary depending on the selected face but also on the point that was picked in the selection process.

Code - Auto/Visual Lisp: [Select]

1. ;; http://www.theswamp.org/index.php?topic=22638.msg334208#msg334208
2. ;; InverseMatrix (gile) 2009/03/17
3. ;; Uses the Gauss-Jordan elimination method to calculate the inverse
4. ;; matrix of any dimension square matrix
5. ;;
6. ;; Argument : a square matrix
7. ;; Return : the inverse matrix (or nil if singular)
8. (defun InverseMatrix (mat / col piv row res)
9.   (setq mat (mapcar '(lambda (x1 x2) (append x1 x2)) mat (Imat (length mat))))
10.   (while mat
11.     (setq col (mapcar '(lambda (x) (abs (car x))) mat))
12.     (repeat (vl-position (apply 'max col) col)
13.       (setq mat (append (cdr mat) (list (car mat))))
14.     )
15.     (if (equal (setq piv (caar mat)) 0.0 1e-14)
16.       (setq mat nil
17.             res nil
18.       )
19.       (setq piv (/ 1.0 piv)
20.             row (mapcar '(lambda (x) (* x piv)) (car mat))
21.             mat (mapcar
22.                   '(lambda (r / e)
23.                      (setq e (car r))
24.                      (cdr (mapcar '(lambda (x n) (- x (* n e))) r row))
25.                   )
26.                   (cdr mat)
27.                 )
28.             res (cons
29.                   (cdr row)
30.                   (mapcar
31.                     '(lambda (r / e)
32.                        (setq e (car r))
33.                        (cdr (mapcar '(lambda (x n) (- x (* n e))) r row))
34.                      )
35.                     res
36.                   )
37.                 )
38.       )
39.     )
40.   )
41.   (reverse res)
42. )
43.  
44. ;; http://www.theswamp.org/index.php?topic=22638.msg334208#msg334208
45. ;; IMAT (gile)
46. ;; Returns the specified dimension identity matrix
47. ;;
48. ;; Argument
49. ;; d : the matrix dimension (positive integer)
50. (defun Imat (d / i n r m)
51.   (setq i d)
52.   (while (<= 0 (setq i (1- i)))
53.     (setq n d r nil)
54.     (while (<= 0 (setq n (1- n)))
55.       (setq r (cons (if (= i n) 1.0 0.0) r))
56.     )
57.     (setq m (cons r m))
58.   )
59. )
60.  
61. (defun _Conv_Pickset_To_EnameList (ss / i ret)
62.   (if ss
63.     (repeat (setq i (sslength ss))
64.       (setq ret (cons (ssname ss (setq i (1- i))) ret))
65.     )
66.   )
67. )
68.  
69. (defun c:test ( / doc mat name ss)
70.   (vl-load-com)
71.   (setq doc (vla-get-activedocument (vlax-get-acad-object)))
72.   (if (= (logand (getvar 'undoctl) 8) 8)
73.     (vla-endundomark doc)
74.   )
75.   (vla-startundomark doc)
76.   (if (setq ss (ssget))
77.     (progn
78.       (setvar 'cmdecho 0)
79.       (setq name (strcat "TMP_UCS_" (rtos (getvar 'cdate) 2 8)))
80.       (princ "\nSelect face for top: ")
81.       (command "_.ucs" "_face" "\\" "")
82.       (command "_.ucs" "_named" "_save" name)
83.       (setq mat
84.         (vlax-tmatrix
85.           (InverseMatrix (vlax-invoke (vla-get-activeucs doc) 'getucsmatrix))
86.         )
87.       )
88.       (foreach ent (_Conv_Pickset_To_EnameList ss)
89.         (vla-transformby (vlax-ename->vla-object ent) mat)
90.       )
91.       (command "_.ucs" "_world")
92.       (command "_.ucs" "_named" "_delete" name)
93.       (setvar 'cmdecho 1)
94.     )
95.   )
96.   (vla-endundomark doc)
97.   (princ)
98. )

[HofCAD]

Dear Emk,

Select the command Align
 1) Select all objects
 2) Specify first source point: S1
 3) Specify first destination point: 0.0
 4) Specify second source point: S2
 5) Specify second destination point: 0,0,1
 6) Specify third source point S3
 7) Specify third destination point: 0.1

Regards

[andy_lee]

Here is a solution using the TransformBy method.
The function c:test uses InverseMatrix by Gile.
The final result will vary depending on the selected face but also on the point that was picked in the selection process.

Many thanks roy. but
Select objects:
Select face for top: ; error: multi dimension safearray not supported

[andy_lee]

Dear Emk,

Select the command Align
 1) Select all objects
 2) Specify first source point: S1
 3) Specify first destination point: 0.0
 4) Specify second source point: S2
 5) Specify second destination point: 0,0,1
 6) Specify third source point S3
 7) Specify third destination point: 0.1

Regards

Dear Hof
I test ,but unsuccessful , and this method is not simple.

I think ,if need specify three point, can use coding ?  eg. choose a face ,can get 4 point .

[roy_043]

My code works fine on BricsCAD.
Maybe it will work on AutoCAD if you change:

Code - Auto/Visual Lisp: [Select]

1.       (setq mat
2.         (vlax-tmatrix
3.           (InverseMatrix (vlax-invoke (vla-get-activeucs doc) 'getucsmatrix))
4.         )
5.       )

To:

Code - Auto/Visual Lisp: [Select]

1.       (setq mat
2.         (vlax-tmatrix
3.           (InverseMatrix
4.             (vlax-safearray->list
5.               (vlax-variant-value (vla-getucsmatrix (vla-get-activeucs doc)))
6.             )
7.           )
8.         )
9.       )

[HofCAD]

Dear Emk,

Set all Dynamic Input features, including dynamic prompts, off (DYNMODE 0).
Otherwise you must provide the destination points 0,0 , 0,0,1 and 0,1
with an asterisk *0,0 , *0,0,1 and *0,1.
Turn the running object snap settings for Endpoint on,
or type the abbreviation END!
Then you can snap the Endpoints S1,S2 and S3!

Command: ALIGN
Select objects: ALL
4 found
Select objects: ‘Enter’
Specify first source point: END of ‘pick S1’
Specify first destination point: 0,0
Specify second source point: END of ‘pick S2’
Specify second destination point: 0,0,1
Specify third source point or <continue>: END of ‘pick S3’
Specify third destination point: 0,1

Explanation:
The selected objects move from the source point S1 to the destination point 0,0.
The selected object is rotated (S1 and S2) so that it aligns with the destination object (0,0 and 0,0,1).
The selected object is then rotated again (S2 and S3) so that it aligns with the destination object (0,0,1 and 0,1).

http://knowledge.autodesk.com/support/autocad/learn-explore/caas/CloudHelp/cloudhelp/2015/ENU/AutoCAD-Core/files/GUID-D0FA10D5-76EE-4B80-A285-43C7F39916DB-htm.html

Regards

[andy_lee]

My code works fine on BricsCAD.
Maybe it will work on AutoCAD if you change:

Code - Auto/Visual Lisp: [Select]

1.       (setq mat
2.         (vlax-tmatrix
3.           (InverseMatrix (vlax-invoke (vla-get-activeucs doc) 'getucsmatrix))
4.         )
5.       )

To:

Code - Auto/Visual Lisp: [Select]

1.       (setq mat
2.         (vlax-tmatrix
3.           (InverseMatrix
4.             (vlax-safearray->list
5.               (vlax-variant-value (vla-getucsmatrix (vla-get-activeucs doc)))
6.             )
7.           )
8.         )
9.       )

Many thanks ,roy .
It's so Beautiful!  This is " Select face for top " , how change to " select face for front " ?

[Lee Mac]

Many thanks ,roy .
It's so Beautiful!  This is " Select face for top " , how change to " select face for front " ?

Try changing:

Code - Auto/Visual Lisp: [Select]

80.       (princ "\nSelect face for top: ")
81.       (command "_.ucs" "_face" "\\" "")
82.       (command "_.ucs" "_named" "_save" name)

to:

Code - Auto/Visual Lisp: [Select]

80.       (princ "\nSelect face for front: ")
81.       (command "_.ucs" "_face" "\\" "" "_.ucs" "_x" "-90" "_.ucs" "_named" "_save" name)

[andy_lee]

Dear Emk,

Turn the running object snap settings for Endpoint on,
or type the abbreviation END!
Then you can snap the Endpoints S1,S2 and S3!

Command: ALIGN
Select objects: ALL
4 found
Select objects: ‘Enter’
Specify first source point: END of ‘pick S1’
Specify first destination point: 0,0,0
Specify second source point: END of ‘pick S2’
Specify second destination point: 0,0,1
Specify third source point or <continue>: END of ‘pick S3’
Specify third destination point: 0,1

Explanation:
The selected objects move from the source point S1 to the destination point 0,0,0.
The selected object is rotated (S1 and S2) so that it aligns with the destination object (0,0,0 and 0,0,1).
The selected object is then rotated again (S2 and S3) so that it aligns with the destination object (0,0,1 and 0,1).

http://knowledge.autodesk.com/support/autocad/learn-explore/caas/CloudHelp/cloudhelp/2015/ENU/AutoCAD-Core/files/GUID-D0FA10D5-76EE-4B80-A285-43C7F39916DB-htm.html

Regards

Dear Hof
Many thanks ,  successful!!! 
before,unsuccessful , Because.  "Dynamic Input " is Enable.  so if I enter "0,0,0" will become to "@0,0,0"

[andy_lee]

Many thanks ,roy .
It's so Beautiful!  This is " Select face for top " , how change to " select face for front " ?

Try changing:

Code - Auto/Visual Lisp: [Select]

80.       (princ "\nSelect face for top: ")
81.       (command "_.ucs" "_face" "\\" "")
82.       (command "_.ucs" "_named" "_save" name)

to:

Code - Auto/Visual Lisp: [Select]

80.       (princ "\nSelect face for front: ")
81.       (command "_.ucs" "_face" "\\" "" "_.ucs" "_x" "-90" "_.ucs" "_named" "_save" name)

Many thanks , Lee,  It's very nice !

[roy_043]

Thanks for jumping in Lee.
BTW: Strange limitation for (vlax-invoke) on AutoCAD.

[Lee Mac]

Many thanks , Lee,  It's very nice !

You're welcome - all credit to roy 

Thanks for jumping in Lee.
BTW: Strange limitation for (vlax-invoke) on AutoCAD.

No worries roy - I agree, it is strange that vlax-invoke was only implemented for 1-dimensional arrays in AutoCAD.

[andy_lee]

roy , lee , Hof ,marko
Your help was greatly appreciated.

[andy_lee]

Thanks for jumping in Lee.
BTW: Strange limitation for (vlax-invoke) on AutoCAD.

@roy_043
@Lee Mac
@ribarm

Dear Sir.
I am so sorry .I need to trouble you again.
Sometimes I use Roy's code Still have  a small problem.

Before,  I said:
I Need FRONT view like this:


But some times like this :

Or like this:

SO, There are four possibilities.

I think that must choose Two face ,  like this :
>>>Select face for front:
>>>Select face for top:

like this, the result is unique.

How modify this code ?  Thanks again!

[roy_043]

Andy, you should experiment with the point you use to select the face.

The final result will vary depending on the selected face but also on the point that was picked in the selection process.

[andy_lee]

Andy, you should experiment with the point you use to select the face.

The final result will vary depending on the selected face but also on the point that was picked in the selection process.

Andy, you should experiment with the point you use to select the face.

The final result will vary depending on the selected face but also on the point that was picked in the selection process.

Hi Roy. Thank you for your reply.

I use @HofCAD 's method.

Code: [Select]

(if
(setq ent (xd::ssget "\n>>>Choose 3D SOLID <Exit>:" '(":L" ((0 . "3DSOLID")))))
(progn
(while (not(setq ss1 (osnap (getpoint "\n>>>1.Pick a basic point: ") "endp" ))))
(while (not(setq ss2 (osnap (getpoint "\n>>>2.Pick a point on X axis: ") "endp" ))))
(while (not(setq ss3 (osnap (getpoint "\n>>>3.Pick a point on Z axis: ") "endp" ))))
(command "_.align" ent ""
"_non" ss1 "_non" "0,0"
"_non" ss2 "_non" "1,0,0"
"_non" ss3 "_non" "0,0,1"
)
(command "_.view" "_front" )
);end_progn
);end_if


[roy_043]

Sometimes I use Roy's code Still have  a small problem.

I use @HofCAD 's method.

?

But if you use the _Align command why not align along the X and Y-axis, instead of the X and Z-axis?

[andy_lee]

Sometimes I use Roy's code Still have  a small problem.

I use @HofCAD 's method.

?

But if you use the _Align command why not align along the X and Y-axis, instead of the X and Z-axis?

Hi Roy ,  align along the X and Y-axis & align along the X and Z-axis  is the same ,  all ok.

I think use " align along the X and Z-axis " is  easily . Because this two point on the same face.

[ahsattarian]

Try This  :   

Code - Auto/Visual Lisp: [Select]

1. (defun c:al3 ()
2.   (defun sub1 (v1 v2) ;|  Cross product of two vectors - #Normal Vector  |;
3.     (list
4.       (- (* (cadr v1) (caddr v2)) (* (caddr v1) (cadr v2)))
5.       (- (* (caddr v1) (car v2)) (* (car v1) (caddr v2)))
6.       (- (* (car v1) (cadr v2)) (* (cadr v1) (car v2)))
7.     )
8.   )
9.   ;;  http://www.theswamp.org/index.php?topic=22638.msg334208#msg334208  
10.   ;;  InverseMatrix (gile) 2009/03/17                                    
11.   ;;  Uses the Gauss-Jordan elimination method to calculate the inverse  
12.   ;;  matrix of any dimension square matrix                              
13.   ;;                                                                    
14.   ;;  Argument : a square matrix                                        
15.   ;;  Return : the inverse matrix (or nil if singular)                  
16.   (defun InverseMatrix (mat / col piv row res)
17.     (defun Imat (d / i n r m)
18.       (setq i d)
19.       (while (<= 0 (setq i (1- i)))
20.         (setq n d)
21.         (setq r nil)
22.         (while (<= 0 (setq n (1- n)))
23.           (if (= i n)
24.             (setq r (cons 1.0 r))
25.             (setq r (cons 0.0 r))
26.           )
27.         )
28.         (setq m (cons r m))
29.       )
30.     )
31.     (setq mat (mapcar '(lambda (x1 x2) (append x1 x2)) mat (Imat (length mat))))
32.     (while mat
33.       (setq col (mapcar '(lambda (x) (abs (car x))) mat))
34.       (repeat (vl-position (apply 'max col) col) (setq mat (append (cdr mat) (list (car mat)))))
35.       (if (equal (setq piv (caar mat)) 0.0 1e-14)
36.         (progn (setq mat nil) (setq res nil))
37.         (progn
38.           (setq piv (/ 1.0 piv))
39.           (setq row (mapcar '(lambda (x) (* x piv)) (car mat)))
40.           (setq mat (mapcar '(lambda (r / e) (setq e (car r)) (cdr (mapcar '(lambda (x n) (- x (* n e))) r row)))
41.                             (cdr mat)
42.                     )
43.           )
44.           (setq res (cons
45.                       (cdr row)
46.                       (mapcar '(lambda (r / e) (setq e (car r)) (cdr (mapcar '(lambda (x n) (- x (* n e))) r row))) res)
47.                     )
48.           )
49.         )
50.       )
51.     )
52.     (reverse res)
53.   )
54.   (vl-load-com)
55.   (setq ss (ssget ":l"))
56.   (initget "Points Face")
57.   (setq al3-var1 (getkword "\n Method : [ Points / Face ] : "))
58.   (cond
59.     ((= al3-var1 "Points")
60.      (command "ucs" "world")
61.      (setq po1 (getpoint "\n select origin point for new ucs : "))
62.      (setq po2 (getpoint "\n select point on x-axis of new ucs : " po1))
63.      (grdraw po1 po2 1 1)
64.      (setq po3 (getpoint "\n select y-axis direction of new ucs : " po1))
65.      (grdraw po1 po3 2 1)
66.      (grdraw po2 po3 3 1)
67.     )
68.     ((= al3-var1 "Face")
69.      (princ "\n Select Face for Top : ")
70.      (command "ucs" "face" "\\" "")
71.      (setq po1 (getvar "ucsorg"))
72.      (setq po2 (mapcar '+ po1 (getvar "ucsxdir")))
73.      (setq po3 (mapcar '+ po1 (getvar "ucsydir")))
74.     )
75.   )
76.   (setq doc (vla-get-activedocument (vlax-get-acad-object)))
77.   (setq v12 (list (- (car po2) (car po1)) (- (cadr po2) (cadr po1)) (- (caddr po2) (caddr po1))))
78.   (setq v13 (list (- (car po3) (car po1)) (- (cadr po3) (cadr po1)) (- (caddr po3) (caddr po1))))
79.   (setq z (sub1 v12 v13))
80.   (setq po4 (mapcar '+ po1 (sub1 z v12)))
81.   (setq nam (strcat (menucmd "M=$(edtime,$(getvar,date),YYYYMODDHHMMSS)") (itoa (abs (getvar "millisecs")))))
82.   (setq ucss (vla-get-usercoordinatesystems (vla-get-activedocument (vlax-get-acad-object))))
83.   (setq ucsobj (vla-add ucss (vlax-3d-point po1) (vlax-3d-point po2) (vlax-3d-point po4) nam))
84.   (vla-put-activeucs doc ucsobj)
85.   (vla-put-ucsiconon (vla-get-activeviewport doc) :vlax-true)
86.   (vla-put-ucsiconatorigin (vla-get-activeviewport doc) :vlax-true)
87.   (setq TransMatrix (vla-getucsmatrix ucsobj))
88.   (setq inf (vlax-safearray->list (vlax-variant-value TransMatrix)))
89.   (setq mat (vlax-tmatrix (InverseMatrix inf)))
90.   (foreach obj (mapcar 'vlax-ename->vla-object (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))))
91.     (vla-transformby obj mat)
92.   )
93.   (princ)
94. )