Topic: Know if a string is letter or number

[the7347]

Hello community

As I can know if a string is letter or number, example "A" is a letter, "7" a number.

simple but I know of no function

thanks...

[ronjonp]

Code - Auto/Visual Lisp: [Select]

1. (numberp (read "7"))

[Lee Mac]

A few ways that spring to mind:

The following will return T if the content is numerical:

Code: [Select]

(numberp (read <str>))

Code: [Select]

(member (type (read <str>)) '(int real))

Code: [Select]

(distof <str> 2)

Code: [Select]

(wcmatch <str> "~*[~0-9]*")

Code: [Select]

(vl-every '(lambda ( x ) (< 47 x 58)) (vl-string->list <str>))
The last two are for integers only.

[GP]

Even (maybe):

Code: [Select]

(eval (read <str>))

[Marc'Antonio Alessi]

Code: [Select]

Comando: (setq astring ".2")
".2"

Comando: (numberp (read astring))
; errore: punto in posizione non corretta nell'input

Comando: (member (type (read astring)) '(int real))
; errore: punto in posizione non corretta nell'input

Comando: (distof astring 2)
0.2

Comando: (wcmatch astring "~*[~0-9]*")
nil

Comando: (vl-every '(lambda ( x ) (< 47 x 58)) (vl-string->list astring))
nil


Comando: (setq astring "0.2")
"0.2"

Comando: (numberp (read astring))
T

Comando: (member (type (read astring)) '(int real))
(REAL)

Comando: (distof astring 2)
0.2

Comando: (wcmatch astring "~*[~0-9]*")
nil

Comando: (vl-every '(lambda ( x ) (< 47 x 58)) (vl-string->list astring))
nil
I think this is better:

Code: [Select]

(defun IsnumericP (str)
  (numberp (distof str))
)

Comando: (IsnumericP "2")
T
Comando: (IsnumericP "2.0")
T
Comando: (IsnumericP ".2")
T


[Lee Mac]

Since any non-nil value will validate a conditional function, the expression need not explicitly return T.

(I did note that my last two examples were compatible with integers only - positive integers, I would add)

Lee

[the7347]

wow .... I'm amazed at the number of responses

I am grateful

[Marc'Antonio Alessi]

Since any non-nil value will validate a conditional function, the expression need not explicitly return T.
...

Sorry, I do not understand what you mean, maybe the more correct name of the function  was IsNumeric or NumericP?

[Lee Mac]

Since any non-nil value will validate a conditional function, the expression need not explicitly return T.
...

Sorry, I do not understand what you mean, maybe the more correct name of the function  was IsNumeric or NumericP?

For example, if an operation depends upon the content of a given string being numerical, the test for numerical content need not return a strict boolean value, since any non-nil value will validate a conditional function.

Therefore, rather than:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / str )
2.     (setq str (getstring "\nEnter some content: "))
3.     (if (numberp (distof str 2))
4.         (princ "\nYou entered a number.")
5.         (princ "\nYou didn't enter a number.")
6.     )
7.     (princ)
8. )

The code can be:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / str )
2.     (setq str (getstring "\nEnter some content: "))
3.     (if (distof str 2)
4.         (princ "\nYou entered a number.")
5.         (princ "\nYou didn't enter a number.")
6.     )
7.     (princ)
8. )

Since distof will return nil if the string content is not numerical.

[Marc'Antonio Alessi]

...
Since distof will return nil if the string content is not numerical.

Grazie mille for the explanation, all okay...     ...but there is at least one exception (that I know):

Code: [Select]

Comando: (distof "1/1")
1.0
Comando: (numberp "1/1")
nil

[David Bethel]

for a single character, maybe :

Code: [Select]

(setq str "7")
(wcmatch str "#")


[roy_043]

...
Since distof will return nil if the string content is not numerical.

Grazie mille for the explanation, all okay...     ...but there is at least one exception (that I know):

Code: [Select]

Comando: (distof "1/1")
1.0
Comando: (numberp "1/1")
nil

I think you are confused here. The numberp function will return nil for any string.
Note that both of Lee's last examples retain a call to the distof function.

[Marc'Antonio Alessi]

...
Since distof will return nil if the string content is not numerical.

Grazie mille for the explanation, all okay...     ...but there is at least one exception (that I know):

Code: [Select]

Comando: (distof "1/1")
1.0
Comando: (numberp "1/1")
nil

I think you are confused here. The numberp function will return nil for any string.
Note that both of Lee's last examples retain a call to the distof function.

Sorry, I had to write:

Code: [Select]

Comando: (numberp 1/1)
nilQuestion: if  (distof "1/1") = 1.0   1/1 is a number?

[Marc'Antonio Alessi]

Maybe it is better to write:
(distof "17 1/2")  = > 17.5

so 17 1/2 it is not a number but the result of distof 17.5 is a number.         ?

[Marc'Antonio Alessi]

Is this a valid test?

Code: [Select]

; Rel. 1.1
(defun NumericP (str)
  (and
    (distof str)
    (numberp (read (strcat "0" str)))
  )
)
(NumericP "1/1a") => nil
(NumericP "1/1" ) => nil
(NumericP "1.0" ) => T
(NumericP  ".1" ) => T