Topic: Best way to compare 2 drawings

[MSTG007]

I can not think of a way to compare two drawings. I want to be able compare the layers states of both (Color / On-off / thaw / etc.). What is the best way I can get a print out and compare what is difference between the two?

Thanks guys

[ronjonp]

You just want to compare the layers?

[MSTG007]

Yup, on PDF or something. I need to show people what is being changed.

[ronjonp]

So what if some linework changed on the two files?

[MSTG007]

I don't think that will be a big deal. What are you thinking of?

[ronjonp]

What I do to see 'changes' is open the old drawing, change all the layer colors to RED. Then xref the new drawing over top and change all the XREF colors to BLUE. Not high tech but has worked for me for many years.

[mjfarrell]

export the Layerstate(s)

Import them into EXCEL....place columns side by side on a pivot table to compare settings


OR

Use one file as a Standard...
compare against the other
the standards report will show what is different (not to standard)

[MSTG007]

I did not know you can export the layer state into excel. The two drawings have the same Named Layers but the colors - on - off are different.

[danallen]

Bluebeam has a PDF compare tool that will do color overlay of changes. Also will auto-cloud.

[mjfarrell]

I did not know you can export the layer state into excel. The two drawings have the same Named Layers but the colors - on - off are different.

Import Data...from TXT

the formatting is messy but it will import.


Upon thinking about it the Cad Standards checker is probably the better option
as it would allow comparing a >>> b

and b >>>>a

just to catch difference (changes) in either direction

[MSTG007]

Thanks man. I will check that out shortly!

[Krushert]

I do not know it this will help barbecue I think it just compares geometry but it might have something.

AutoCAD Architecture has Drawing Compare.  I played with it but not seriously put it work.  So I really can not give an opinion on it.

There is plug-in for regular AutoCAD

[Bethrine]

I do not know it this will help barbecue I think it just compares geometry but it might have something.

AutoCAD Architecture has Drawing Compare.  I played with it but not seriously put it work.  So I really can not give an opinion on it.

There is plug-in for regular AutoCAD

Either you are hungary or maybe your spell checker is out-dated? 

[Krushert]

I do not know it this will help barbecue I think it just compares geometry but it might have something.

AutoCAD Architecture has Drawing Compare.  I played with it but not seriously put it work.  So I really can not give an opinion on it.

There is plug-in for regular AutoCAD

Either you are hungary or maybe your spell checker is out-dated? 

No the spell checker is hungry not hungary!   

[Bethrine]

I do not know it this will help barbecue I think it just compares geometry but it might have something.

AutoCAD Architecture has Drawing Compare.  I played with it but not seriously put it work.  So I really can not give an opinion on it.

There is plug-in for regular AutoCAD

Either you are hungary or maybe your spell checker is out-dated? 

No the spell checker is hungry not hungary!   

     

[ronjonp]

And you could go the code route to compare the layers

Code - Auto/Visual Lisp: [Select]

1. (defun c:comparelayers (/ a adoc b doc dwg l lay lprops ll ll2 name odbx out props props2 v x)
2.   (vl-load-com)
3.   (setq adoc (vla-get-activedocument (setq doc (vlax-get-acad-object))))
4.   (setq lprops '("Color" "Freeze" "LayerOn" "Linetype" "Lineweight" "Lock"
5.                  ;; "PlotStyleName"
6.                  "Plottable")
7.   )
8.   (vlax-for x (vla-get-layers adoc)
9.     (if (not (wcmatch (vla-get-name x) "*|*"))
10.       (setq ll
11.              (cons
12.                (list (strcase (vla-get-name x)) (mapcar '(lambda (l) (cons l (vlax-get x l))) lprops))
13.                ll
14.              )
15.       )
16.     )
17.   )
18.   (cond
19.     ((or
20.        (null (setq dwg (getfiled "Select a drawing to compare layers:" (getvar 'dwgprefix) "dwg" 16))
21.        )
22.        (= dwg "")
23.      )
24.      (print "Bye..")
25.     )
26.     ((null (setq odbx (cond ((< (setq v (substr (getvar 'acadver) 1 2)) "16")
27.                              (vla-getinterfaceobject doc "ObjectDBX.AxDbDocument")
28.                             )
29.                             ((vla-getinterfaceobject doc (strcat "ObjectDBX.AxDbDocument." v)))
30.                       )
31.            )
32.      )
33.      (print "ObjectDBX.AxDbDocument could NOT be created!")
34.     )
35.     ((vl-catch-all-error-p (vl-catch-all-apply 'vla-open (list odbx dwg)))
36.      (print (strcase (strcat "*Error opening*: " dwg)))
37.     )
38.     ((vlax-for lay (vla-get-layers odbx)
39.        (setq name (strcase (vla-get-name lay)))
40.        (cond ((null (setq props (cadr (assoc name ll))))
41.               (print (strcat name " not in current drawing..."))
42.              )
43.              ((equal (setq props2 (mapcar '(lambda (x) (cons x (vlax-get lay x))) lprops)) props)
44.               (setq ll (vl-remove (list name props) ll))
45.               (print (strcat name " matches..."))
46.              )
47.              ((print (strcat name " different..."))
48.               (setq ll (vl-remove (list name props) ll))
49.               (mapcar '(lambda (a b)
50.                          (if (not (equal a b))
51.                            (print (strcat (vl-princ-to-string (car a))
52.                                           ": "
53.                                           (vl-princ-to-string (cdr a))
54.                                           " -> "
55.                                           (vl-princ-to-string (cdr b))
56.                                   )
57.                            )
58.                          )
59.                        )
60.                       props2
61.                       props
62.               )
63.              )
64.        )
65.      )
66.      (mapcar '(lambda (x) (print (strcat (car x) " not in other drawing..."))) ll)
67.      (vlax-release-object odbx)
68.     )
69.   )
70.   (princ)
71. )

[Jeff H]

I did not know you can export the layer state into excel. The two drawings have the same Named Layers but the colors - on - off are different.

Import Data...from TXT

the formatting is messy but it will import.


Upon thinking about it the Cad Standards checker is probably the better option
as it would allow comparing a >>> b

and b >>>>a

just to catch difference (changes) in either direction

Just go to layer palette and
Ctrl+A(select all)
Ctrl+C(copy)

Then open excel
Ctrl+V(paste)


Then delete all rows except name and whatever else you want.
Select all and format as table and then you filtering added easy and you can make two tables align by value to compare