Topic: Why this is not working

[Zykl0]

I'm working a script that find layer in the drawing by keyword and send everything on this layer to another one. This is not working at all and i don't know why. please help!

Code: [Select]

(defun C:ACUTEST (/ lay )

  (setq !lay (ssget "x" '((8 . "*Ala*"))))
  (command "_.CHPROP" !lay "" "LA" "Alarm" "")
 
  (setq !lay (ssget "x" '((8 . "*Ax*"))))
  (command "_.CHPROP" !lay "" "LA" "Axis" "")
 
  (setq !lay (ssget "x" '((8 . "*Back*"))))
  (command "_.CHPROP" !lay "" "LA" "Background" "")
 
  (setq !lay (ssget "x" '((8 . "*Be*"))))
  (command "_.CHPROP" !lay "" "LA" "Beam" "")
 
  (setq !lay (ssget "x" '((8 . "*Buil*"))))
  (command "_.CHPROP" !lay "" "LA" "Building" "")
  (princ)
)

[Matt__W]

Do all of the layers exist?

[tombu]

You need to attach the drawing for us to test.

[MP]

Quick & dirty for your consideration, coded blind:

Code: [Select]

(defun C:AcuTest ( / foo )

    (defun foo ( filter layer / ss )
        (if (null (setq ss (ssget "x" (list (cons 8 filter)))))
            (princ (strcat "\nNo entites found for filter <" filter ">."))
            (progn
                (if (null (tblsearch "layer" layer ))
                    (vl-cmdf ".layer" "_new" layer "")
                )
                (vl-cmdf ".chprop" ss "" "_layer" layer "")
                (princ
                    (strcat
                        "\n"
                        (itoa (sslength ss))
                        " object(s) moved to layer <" layer ">."
                    )
                )
            )
        )
        (princ)
    )

    (foreach pair
       '(   
            ("*Ala*"  "Alarm")
            ("*Ax*"   "Axis")
            ("*Back*" "Background")
            ("*Be*"   "Beam")
            ("*Buil*" "Building")
        )
        (apply 'foo pair)
    )

    (princ)

)

[ronjonp]

And another

Code - Auto/Visual Lisp: [Select]

1. (defun c:acutest (/ ss)
2.   (foreach lay '(("*Ala*" "Alarm")
3.                  ("*Ax*" "Axis")
4.                  ("*Back*" "Background")
5.                  ("*Be*" "Beam")
6.                  ("*Buil*" "Building")
7.                 )
8.     (if (null (tblobjname "layer" (cadr lay)))
9.       (vl-cmdf ".layer" "_new" (cadr lay) "")
10.     )
11.     (if (setq ss (ssget "_x" (list (cons 8 (car lay)))))
12.       (command "_.CHPROP" ss "" "Layer" (cadr lay) "")
13.     )
14.   )
15.   (princ)
16. )

[Zykl0]

Wow this is amazing guys!

keep up to good work.