Topic: RemoveNth ...

[MP]

If anyone is mildy interested I did some tests today and found both versions of the removenth function that use vl-remove-if were approx. 2x faster than the vanilla version, using lists with 1,000 to 1,000,000 items (using a representative spread of 'n' positions).

Having said that, that isn't terrible performance for vanilla lisp.

Challenge extended -- writer a faster variant in either vanilla or visual lisp. Hint - recursive will look prettier but ...

[CAB]

That is interesting, thanks.
Sorry I've been too busy to participate but here are some more variations for your speed test.
Not sure if you had run across them before.

http://www.theswamp.org/index.php?topic=635.0
http://www.theswamp.org/index.php?topic=754.0

<edit: repair broken links>

[daron]

Let's not forget about this one

[MP]

Holy chyt, wish I'd been here for all those threads; good stuff!

[daron]

You should've followed Cadaver over here sooner. You would've been here for them.

[MP]

Came over the first time I saw him reference the place. Of course, I've never been called 'Captain Observant'.

[MP]

PS: If I'm not mistaken this one will remove every instance of an item from a list; not the same as removing the nth item.

[daron]

True. That was the point of that challenge. I just like how simply effective it was.

[taner]

Code: [Select]

(defun removenth (n lst / j)       
  (setq j -1)
  (vl-remove-if '(lambda (x)
   (= n (setq j (1+ j)))
) lst
  )
)

[gile]

Code: [Select]

(defun remove-i (ind lst)
  (if (or (zerop ind) (null lst))
    (cdr lst)
    (cons (car lst) (remove-i (1- ind) (cdr lst)))
  )
)

[ElpanovEvgeniy]

not recursive

Code: [Select]

(defun remove-nth (l n / a)
 ;;(remove-nth l 20)
 (while (and l (> n 0))
  (setq a (cons (car l) a)
        l (cdr l)
        n (1- n)
  ) ;_  setq
 ) ;_  while
 (append (reverse a) (cdr l))
)

[CAB]

Code: [Select]

  ;;  CAB 11.16.07 rev. 12.23.08
  ;;  Remove based on pointer list
  (defun RemoveNlst (nlst lst)
    (setq i -1)
    (vl-remove-if '(lambda (x) (vl-position (setq i (1+ i)) nlst)) lst)
  ) 
 

Code: [Select]

  (setq result (RemoveNlst '(1 4) '(0 "A" 2 3 "B" 5 6 7 8 9)))
  ;;  removes A & B

[CAB]

I see the links in my previous post were broken.
Here are the new links:

http://www.theswamp.org/index.php?topic=635.0
http://www.theswamp.org/index.php?topic=754.0

[zoltan]

Here is something similar I wrote a long time ago to be able to set or remove an atom from in a list.  It's a lot more "brute force" and the speed of it will depend on the position of the element that we are trying to remove. also, there is a lot of overhead from the double reverse of the Add function.

Code: [Select]

(Defun Add ( ATM LST )
 (Reverse (Cons ATM (Reverse LST)) )
)

(Defun SetNth ( IDX LST ITM / cnt return )
 (SetQ cnt 0 )
 (While (< cnt IDX)
  (SetQ return (Add (Car LST) return)
        LST    (Cdr LST)
        cnt    (1+ cnt)
  )
 )
 (SetQ return (Append (Add ITM return) (Cdr LST)) )


 return
)

(Defun RemoveNth ( IDX LST / cnt return )
 (SetQ cnt 0 )
 (While (< cnt IDX)
  (SetQ return (Add (Car LST) return)
        LST    (Cdr LST)
        cnt    (1+ cnt)
  )
 )
 (SetQ return (Append return (Cdr LST)) )

 return
)

It's very similar to ElpanovEvgeniy's solution, but he managed to get around the double reverse!

[highflyingbird]

Here is my code.

Code: [Select]

(defun remove-n (n lst / a b)
  (setq a lst)
  (repeat n
    (setq b (cons (car a) b)
          a (cdr a)
    )
  )
  (setq a (cdr a))
  (foreach i b
    (setq a (cons i a))
  )
  a
)By the way, I posted a function  that insert an element in nth position of  a list.

Code: [Select]

(defun insert-n (n element lst / a b)
  (setq a lst)
  (repeat n
    (setq b (cons (car a) b)
          a (cdr a)
    )
  )
  (setq a (cons element a))
  (foreach i b
    (setq a (cons i a))
  )
  a
)It's very similar as the function "remove-nth".