Topic: Determining coordinates of a point arrow mulileader

[Lupo76]

I tried google but I only found examples to create a multileader.
I would, however, find the coordinates of the point of the arrow.

In the list of properties obtained with (vlax-dump-object) I do not see this property.
In the list (entget) I see coordinates below a list 10 but there are many lists 10, how I can only differentiate the correct one?

Any suggestions?

[ronjonp]

Look into vla-GetLeaderLineVertices

Code - Auto/Visual Lisp: [Select]

1. (setq o (vlax-ename->vla-object (car (entsel "\nPick an mleader: "))))
2. (vla-getleaderlinevertices o 0)
3. ;; Returns #<variant XXXX ...>
4. (vlax-invoke o 'getleaderlinevertices 0)
5. ;; Vlax-invoke bypasses the need to convert a variant value
6. ;; Returns (2.70946e+006 1.31026e+006 0.0 2.70951e+006 1.31027e+006 0.0)

[Lee Mac]

If you did want to go the 'Vanilla' route:

Code - Auto/Visual Lisp: [Select]

1. (defun mleaderarrowpoint ( ent )
2.     (cdr (assoc 10 (cdr (member '(304 . "LEADER_LINE{") (entget ent)))))
3. )

[Lupo76]

Look into vla-GetLeaderLineVertices

Code - Auto/Visual Lisp: [Select]

1. (setq o (vlax-ename->vla-object (car (entsel "\nPick an mleader: "))))
2. (vla-getleaderlinevertices o 0)
3. ;; Returns #<variant XXXX ...>
4. (vlax-invoke o 'getleaderlinevertices 0)
5. ;; Vlax-invoke bypasses the need to convert a variant value
6. ;; Returns (2.70946e+006 1.31026e+006 0.0 2.70951e+006 1.31027e+006 0.0)

Thank You!
I solved!

Trivia: There is a document or a guide with a list of functions (eg. Vla-getleaderlinevertices) broken down by type of entity to which they are applicable?

[ronjonp]

Use this to get properties:

Code - Auto/Visual Lisp: [Select]

1. (defun c:vlaxprop (/ o)
2.   (if (setq o (car (entsel "\nSelect object to show data: ")))
3.     (vlax-dump-object (vlax-ename->vla-object o) t)
4.   )
5.   (textscr)
6. )

[Lupo76]

Use this to get properties:

Code - Auto/Visual Lisp: [Select]

1. (defun c:vlaxprop (/ o)
2.   (if (setq o (car (entsel "\nSelect object to show data: ")))
3.     (vlax-dump-object (vlax-ename->vla-object o) t)
4.   )
5.   (textscr)
6. )

You're right!
I already know this code.

I asked this because I had not seen 'Vla-getleaderlinevertices' list. Sorry

[Lupo76]

If you did want to go the 'Vanilla' route:

Code - Auto/Visual Lisp: [Select]

1. (defun mleaderarrowpoint ( ent )
2.     (cdr (assoc 10 (cdr (member '(304 . "LEADER_LINE{") (entget ent)))))
3. )

Hello Lee,
I found the following code:

Code: [Select]

(setq listcoord (vl-remove-if-not '(lambda (x)(equal (car x) 10))(entget ent1)))
to determine the list of the coordinates.
Now I would like to use (entmod) to replace them with other coordinates.
How can I do? Whereas all the coordinates belong to the group with the same name 10.  ?

[ronjonp]

Are you just trying to modify the endpoint of the mleader?

Code - Auto/Visual Lisp: [Select]

1. (setq o (vlax-ename->vla-object (car (entsel "\nPick an mleader: "))))
2. (setq l (vlax-invoke o 'getleaderlinevertices 0))
3. ;; Vlax-invoke bypasses the need to convert a variant value
4. ;; Returns (2.70946e+006 1.31026e+006 0.0 2.70951e+006 1.31027e+006 0.0)
5. (setq p (getpoint "\nPick a point: "))
6. ;; Change leader endpoint to picked point
7. (vlax-invoke o 'setleaderlinevertices 0 (append p (cdddr l)))

[Lupo76]

Are you just trying to modify the endpoint of the mleader?

Code - Auto/Visual Lisp: [Select]

1. (setq o (vlax-ename->vla-object (car (entsel "\nPick an mleader: "))))
2. (setq l (vlax-invoke o 'getleaderlinevertices 0))
3. ;; Vlax-invoke bypasses the need to convert a variant value
4. ;; Returns (2.70946e+006 1.31026e+006 0.0 2.70951e+006 1.31027e+006 0.0)
5. (setq p (getpoint "\nPick a point: "))
6. ;; Change leader endpoint to picked point
7. (vlax-invoke o 'setleaderlinevertices 0 (append p (cdddr l)))

Sorry I forgot to write.
I can not use setleaderlinevertices, because there is a bug in BricsCAD.
This bug will be fixed in the next version, but I would like my application to be backwards compatible.
So I must use (entmod).

Any suggestions?
There is a function to change the first or the second or the third pair pointed with code 10?

[roy_043]

If you did want to go the 'Vanilla' route:

Code - Auto/Visual Lisp: [Select]

1. (defun mleaderarrowpoint ( ent )
2.     (cdr (assoc 10 (cdr (member '(304 . "LEADER_LINE{") (entget ent)))))
3. )

Hello Lee,
I found the following code:

Code: [Select]

(setq listcoord (vl-remove-if-not '(lambda (x)(equal (car x) 10))(entget ent1)))
to determine the list of the coordinates.
Now I would like to use (entmod) to replace them with other coordinates.
How can I do? Whereas all the coordinates belong to the group with the same name 10.  ?

@ Lupo: Your code will return more group 10 subs than there are arrows.

Following Lee's example you will need something like this:

Code: [Select]

(defun MleaderCoordsGet (ename / elist return)
  (setq elist (entget ename))
  (while (setq elist (cdr (member '(304 . "LEADER_LINE{") elist)))
    (setq return (cons (cdr (assoc 10 elist)) return))
  )
  (reverse return)
)

[roy_043]

Any suggestions?
There is a function to change the first or the second or the third pair pointed with code 10?

Perhaps this?:

Code: [Select]

; (MleaderCoordsSetSingle (car (entsel)) 0 '(20.0 10.0 0.0))
(defun MleaderCoordsSetSingle (ename idx pt / cnt doneP)
  (setq cnt -1)
  (entmod
    (mapcar
      '(lambda (sub)
        (cond
          (doneP
            sub
          )
          ((equal sub '(304 . "LEADER_LINE{"))
            (setq cnt (1+ cnt))
            sub
          )
          ((and (= idx cnt) (= 10 (car sub)))
            (setq doneP T)
            (cons 10 pt)
          )
          (T
            sub
          )
        )
      )
      (entget ename)
    )
  )
)
Edit: Added doneP variable to avoid changing gc 10 items after the final arrow coordinates.

[ronjonp]

Here's one to entmod all leader points:

Code - Auto/Visual Lisp: [Select]

1. (defun _mleaderset (ename point / i el)
2.   (setq i -1)
3.   (if (and (= (type ename) 'ename) (= (type point) 'list))
4.     (entmod (mapcar '(lambda (x)
5.                        (setq i (1+ i))
6.                        (if (and (= (car x) 10) (equal (nth (1- i) el) '(304 . "LEADER_LINE{")))
7.                          (cons 10 point)
8.                          x
9.                        )
10.                      )
11.                     (setq el (entget ename))
12.             )
13.     )
14.   )
15. )
16. (_mleaderset (car (entsel)) (getpoint))