Author Topic: How to replace the duplicate items in the list (Read 2001 times)

xiaxiang · « **on:** January 15, 2015, 01:48:22 AM »

Inheritted from this topic
How to find the duplicate items in the list
http://www.theswamp.org/index.php?topic=48646
**********************************************************************************
Just grouping duplicate items is the trick what has been done by you masters.
Then I want to replace them According to the regulation I'll talk about.
1.
Says the original list as follow:

Code: [Select]

(foo '(1.0 1.1 1.19 1.2 1.2 1.21 1.22 1.23 1.25 1.3 )0.05)
;0.05 is fuzz

then we get the duplicate grouped list as follow:

Code: [Select]

((1.19 1.2 1.2 1.21 1.22 1.23 1.25))

and

Code: [Select]

if (1.19 1.2 1.2 1.21 1.22 1.23 1.25)
;;1.2 is the one which Appeared two times at least and Most times then others.
then replace the list
-->(1.2 1.2 1.2 1.2 1.2 1.2 1.2)

So the integral function as follow:

Code: [Select]

(foo '(1.0 1.1 1.19 1.2 1.2 1.21 1.22 1.23 1.25 1.3 )0.05)
;0.05 is fuzz
-->(1.0 1.1 1.2 1.2 1.2 1.2 1.2 1.2 1.2 1.3 )

2.
Another original list as follow:

Code: [Select]

(foo '(1.0 1.1 1.19 1.2 1.21 1.22 1.23 1.25 1.3 )-->0.05)
;0.05 is fuzz

then we get the duplicate grouped list as follow:

Code: [Select]

((1.19 1.2 1.21 1.22 1.23 1.25))

And

Code: [Select]

if (1.19 1.2 1.21 1.22 1.23 1.25)
;;Nothing Appear more then two times.
then replace the list
-->(1.2167 1.2167 1.2167 1.2167 1.2167 1.2167)
;;1.2167 is the average value of the list.

So the integral function as follow:

Code: [Select]

(foo '(1.0 1.1 1.19 1.2 1.21 1.22 1.23 1.25 1.3 )0.05)
;0.05 is fuzz
-->(1.0 1.1 1.2167 1.2167 1.2167 1.2167 1.2167 1.2167 1.3 )

The reason for doing that is I want to Calibrate the Coordinates of the Irregular table.
Maybe my method is useful.Every suggestion is welcome.
I think that will be a real Challenge.
Thanks!

xiaxiang · « **Reply #1 on:** January 19, 2015, 10:15:29 PM »

Do the trick?

Code - Auto/Visual Lisp: [Select]

(defun Replace_Duplist(lst  fuzz / DuplicatesEq CountItems replace tmplst a b lst1)
   ;;Find and group the duolicate items(with nth) in the given list
   ;;Original by irneb 
   (defun DuplicatesEq  (LST fuzz / L n item group1 group2 result1 result2)  
        (setq L (vl-sort LST '<=) n -1)  
        (while (setq item (car L))    
        (setq L (cdr L) n (1+ n))   
        (while (and L (equal item (car L) fuzz))   
                (setq   group1 (cons item group1)
                        group2 (cons n group2)
                        n (1+ n)
                        item  (car L)           
                        L     (cdr L)
                )
        ) 
        (if group1    
        (setq result1 (cons (reverse (cons item group1)) result1)
                 result2 (cons (reverse (cons n group2)) result2)
                group1  nil
                group2  nil
        )
        )
        )  
        (list(reverse result1)(reverse result2))
     )
  ;; Count Items  -  Lee Mac
  ;; Returns a list of dotted pairs detailing the number of
  ;; occurrences of each item in a supplied list.
  (defun CountItems (l / c l r x)
        (while l
          (setq x (car l)
                c (length l)
                l (vl-remove-if (function (lambda (e)(equal e x 1e-5))) (cdr l))
                r (cons (cons x (- c (length l))) r)
          )
        )
        (reverse r)
  )
  ;;Replace_nth  -  Lee Mac
  (defun replace ( alist position newitem / i )
        (setq i -1)
        (mapcar '(lambda ( x ) (if (= position (setq i (1+ i))) newitem x)) alist)
  )
  ;*****************************************************************
   (setq tmplst(DuplicatesEq lst fuzz)
        a(car tmplst)
        b(cadr tmplst)
        lst1 (vl-sort lst '<=)
   )
  ;(princ tmplst)
  
  (if a
          (progn
                  (mapcar
                        '(lambda (x y / tmplst1 tmplst2 v)
                                (setq tmplst1
                                        (vl-remove-if
                                                (function (lambda (e)(= (cdr e) 1)))
                                                (CountItems x)
                                        )
                                )
                           (setq  tmplst2
                                        (vl-sort-i  tmplst1
                                                (function (lambda (e1 e2)(> (cdr e1) (cdr e2))))
                                        )
                                )
                                (setq v
                                        (if     tmplst1
                                                (car (nth (nth 0 tmplst2) tmplst1))
                                                (/(apply '+ x)(length x))
                                        )
                                )
                                (mapcar '(lambda(i) (setq lst1(replace lst1 i v)))y)
                        )
                        a b
                  )
                  lst1
          )
          lst
  )
)[/pre]

Code: [Select]

(Replace_Duplist '(1.0 1.1 1.19 1.2 1.2 1.21 1.22 1.23 1.25 1.3 2.0 2.1 2.19 2.2 2.2 2.21 2.22 2.23 2.25 2.31)0.05)
-->(1.0 1.1 1.2 1.2 1.2 1.2 1.2 1.2 1.2 1.3 2.0 2.1 2.2 2.2 2.2 2.2 2.2 2.2 2.2 2.31)

Code: [Select]

(Replace_Duplist '(1.0 1.1 1.19 1.2  1.21 1.22 1.23 1.25 1.3 2.0 2.1 2.19 2.2  2.21 2.22 2.23 2.25 2.31)0.05)
-->(1.0 1.1 1.21667 1.21667 1.21667 1.21667 1.21667 1.21667 1.3 2.0 2.1 2.21667 2.21667 2.21667 2.21667 2.21667 2.21667 2.31)

News:

Author Topic: How to replace the duplicate items in the list (Read 2001 times)

xiaxiang

How to replace the duplicate items in the list

xiaxiang

Re: {Challenge}How to replace the duplicate items in the list