Topic: Need fresh eyes to check this part of code

[HasanCAD]

I want to place all Xrefs on layer 0
Ehy is this not working

Code: [Select]

(setq XrefTrgtLyr "0")
(vlax-for blk (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
  (if (= :vlax-true (vla-get-isxref blk))
    (progn
      (setq blkLyr (vla-get-layer blk))
      (if (= :vlax-true (vla-get-lock blkLyr))
(progn
  (vla-put-lock blkLyr :vlax-false)
  (vla-put-layer blk XrefTrgtLyr)
  (vla-put-lock blkLyr :vlax-true)
  )
(vla-put-layer blk XrefTrgtLyr)
)
      )
    )
  )

[ronjonp]

One issue 'blkLyr' is a string and you're checking if it's locked?

Code: [Select]

(= :vlax-true (vla-get-lock blkLyr))

[Tharwat]

Assuming that your Xrefs are in Model Space .

Code - Auto/Visual Lisp: [Select]

1. (defun _move:xref:to:zero:layer (/ _d l)
2.   ;;    Tharwat 23.12.2014      ;;
3.   (vlax-for x (vla-get-modelspace (setq _d (vla-get-ActiveDocument (vlax-get-acad-object))))
4.     (if (and (eq (vla-get-objectname x) "AcDbBlockReference")
5.              (vlax-property-available-p x 'Path)
6.         )
7.       (if
8.         (eq :vlax-true
9.             (vla-get-lock
10.               (setq l (vla-item (vla-get-layers _d) (vla-get-layer x)))
11.             )
12.         )
13.          (progn
14.            (vla-put-lock l :vlax-false)
15.            (vla-put-layer x "0")
16.            (vla-put-lock l :vlax-true)
17.          )
18.          (vla-put-layer x "0")
19.       )
20.     )
21.   )
22.   (princ)
23. )(vl-load-com)
24.  

[HasanCAD]

Thanks ronjonp
Thanks Tharwat

[Tharwat]

Thanks Tharwat

You are welcome .
Hope you got it working as you've been looking for .

[HasanCAD]

Thanks Tharwat

You are welcome .
Hope you got it working as you've been looking for .

Thanks for your effort. But I want to know whats wrong.
I have xrefs in both model and layouts

Code - Auto/Visual Lisp: [Select]

1. (vlax-for x (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
2.   (if (= :vlax-true (vla-get-isxref x))
3.     (progn
4.       (if (eq :vlax-true
5.               (vla-get-lock
6.                 (setq blkLyr (vla-item (vla-get-layers doc) (vla-get-layer x)))))
7.         (progn
8.           (vla-put-lock blkLyr :vlax-false)
9.           (vla-put-layer x XrefTrgtLyr)
10.           (vla-put-lock blkLyr :vlax-true)
11.           )
12.         (vla-put-layer x XrefTrgtLyr)
13.         )
14.       )
15.     )
16.   )

This code gives error

Code: [Select]

; error: ActiveX Server returned the error: unknown name: Layer


[Tharwat]

Thanks Tharwat

You are welcome .
Hope you got it working as you've been looking for .

Thanks for your effort. But I want to know whats wrong.
I have xrefs in both model and layouts

Code - Auto/Visual Lisp: [Select]

1. (vlax-for x (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
2.   (if (= :vlax-true (vla-get-isxref x))
3.     (progn
4.       (if (eq :vlax-true
5.               (vla-get-lock
6.                 (setq blkLyr (vla-item (vla-get-layers doc) (vla-get-layer x)))))
7.         (progn
8.           (vla-put-lock blkLyr :vlax-false)
9.           (vla-put-layer x XrefTrgtLyr)
10.           (vla-put-lock blkLyr :vlax-true)
11.           )
12.         (vla-put-layer x XrefTrgtLyr)
13.         )
14.       )
15.     )
16.   )

This code gives error

Code: [Select]

; error: ActiveX Server returned the error: unknown name: Layer


Because you are iterating though Blocks table , so you can not put it on any layer

Try the following which runs across all layouts including Model Space :

Code - Auto/Visual Lisp: [Select]

1. (defun _move:xref:to:layer (layer / _d l)
2.   ;;    Tharwat 23.12.2014      ;;
3.   (if (tblsearch "LAYER" layer)
4.     (vlax-for y
5.                 (vla-get-layouts
6.                   (setq
7.                     _d (vla-get-ActiveDocument (vlax-get-acad-object))
8.                   )
9.                 )
10.       (vlax-for x (vla-get-block y)
11.         (if (and (eq (vla-get-objectname x) "AcDbBlockReference")
12.                  (vlax-property-available-p x 'Path)
13.             )
14.           (if
15.             (eq :vlax-true
16.                 (vla-get-lock
17.                   (setq
18.                     l (vla-item (vla-get-layers _d) (vla-get-layer x))
19.                   )
20.                 )
21.             )
22.              (progn
23.                (vla-put-lock l :vlax-false)
24.                (vla-put-layer x layer)
25.                (vla-put-lock l :vlax-true)
26.              )
27.              (vla-put-layer x layer)
28.           )
29.         )
30.       )
31.     )
32.     (alert (strcat "Layer name : "
33.                    layer
34.                    " is not found in drawing "
35.            )
36.     )
37.   )
38.   (princ)
39. )(vl-load-com)