Topic: Move Active Layout Tab to End

[cmwade77]

I have found a lot of very complicated code for moving layout tabs, but I can't seem to find anything simple that shows me how to move the currently active layout tab to the end of the layout tabs. Can anyone help me out here? At least point me in the right direction with some simple code examples?

[ymg]

cmwade77,

How about copy current layout, followed by a delete
then a set and finally a rename.

All this with the layout command,

ymg

[Rod]

This seems to work. You will need to add in error checking to make sure the user is not in model space

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun C:putmelast ()
3.   (setq acadObj (vlax-get-acad-object))
4.   (setq doc (vla-get-ActiveDocument acadObj))
5.   (setq layouts (vla-get-Layouts doc))
6.   (setq ActiveLayout (vla-item layouts (getvar "CTAB")))
7.   (vla-put-taborder activelayout (1- (vla-get-count layouts)))
8. )

[ymg]

I came up with this, but Ausrod solution is cleaner.

Code - Auto/Visual Lisp: [Select]

1. (defun movctab ( )
2.    
3.    (setq    ctab (getvar "ctab")
4.             layl (append (vl-remove ctab (layoutlist)) (list ctab))
5.          layouts (vla-get-Layouts (vla-get-activedocument (vlax-get-acad-object)))
6.    )
7.    (vlax-for tab layouts
8.      (if (/= (setq name (vla-get-name tab)) "Model")
9.         (vla-put-taborder tab (+ (vl-position (vla-get-name tab) layl) 1))
10.      )
11.    )  
12. )
13.  
14.  

Ausrod's solution is essentially two lines:

Code - Auto/Visual Lisp: [Select]

1. (defun c:putmelast ( / layouts)  
2.    (setq layouts (vla-get-Layouts (vla-get-activedocument (vlax-get-acad-object))))
3.    (vla-put-taborder (vla-item layouts (getvar "CTAB")) (1- (vla-get-count layouts)))
4. )
5.  

[Tharwat]

Try this .

Code - Auto/Visual Lisp: [Select]

1. (defun c:GoLast (/ l)
2.   ;;    Tharwat 16.Dec.2014     ;;
3.   (if (and (< 2
4.               (vla-get-count
5.                 (setq l (vla-get-Layouts
6.                           (vla-get-ActiveDocument (vlax-get-acad-object))
7.                         )
8.                 )
9.               )
10.            )
11.            (eq 0 (getvar 'TILEMODE))
12.       )
13.     (vla-put-taborder
14.       (vla-item l (getvar 'CTAB))
15.       (1- (vla-get-count l))
16.     )
17.     (princ "\n ** Commnad is not allowed in Model Space **")
18.   )
19.   (princ)
20. )(vl-load-com)
21.  

[Patrick_35]

Hi

And my example

Code: [Select]

(defun c:test(/ doc)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-startundomark doc)
  (vl-catch-all-apply 'vla-put-taborder (list (vla-get-activelayout doc) (1- (vla-get-count (vla-get-layouts doc)))))
  (vla-endundomark doc)
  (princ)
)
@+

[Tharwat]

@ Patrick
Try your codes while you are in Model space .

[Patrick_35]

@ Patrick
Try your codes while you are in Model space .

Oh yes, but as we asked for the active layout
The code is modified according to your point