Topic: Multileader

[Fabricio28]

Hi all,

I'm looking for a lisp to increment numbers of the multileader.

e.g
prefix: BLS-
I wanna increment the multileader's numbers keeping the prefix.
BLS-1; BLS-2 so on...

Could you help me out, please?

Thank in advance

[ronjonp]

Give this a whirl 

Code - Auto/Visual Lisp: [Select]

1. (defun c:number (/ _entsel e n o p)
2.   (defun _entsel (msg / picked return)
3.     (setvar "ErrNo" 0)
4.     (while
5.       (not (cond ((and (null (setq picked (entsel (strcat "\n" msg)))) (/= 52 (getvar 'errno)))
6.                   (prompt "\nNothing Picked...")
7.                  )
8.                  ((null picked) t)
9.                  ((setq return picked))
10.            )
11.       )
12.     )
13.     return
14.   )
15.   (vl-load-com)
16.   (if (and (setq p (getstring "\nEnter Prefix:")) (setq n (getint "\nEnter Starting Number:")))
17.     (while (setq e (car (_entsel "Pick item to number: ")))
18.       (setq o (vlax-ename->vla-object e))
19.       (if (vlax-property-available-p o 'textstring)
20.         (progn (vla-put-textstring o (strcat p (itoa n))) (setq n (1+ n)))
21.       )
22.     )
23.   )
24.   (princ)
25. )

[Fabricio28]

Just Amazing! ronjonb

I saved my life and my time!!!

Thank you very much.
 

[ronjonp]

Glad to help