Topic: Testing for multiple conditions

[jbuzbee]

I'm having major mental blockage this afternoon.  I want to test for several condition with a layer and then add it to a list if it meets all the conditions.  I know the following isn't right but maybe it can spark some ideas:

Code: [Select]

(vlax-for i(vla-get-layers(vla-get-ActiveDocument(vlax-get-acad-object)))
  (cond((not(vl-string-search "|" (vla-get-name i)))
((=(vla-get-layeron i):vlax-true))
((=(vla-get-freeze i):vlax-false))
((setq llist(append llist (vla-get-name i))))
)
       )
  )
Thanks for any input!!

jb

[ronjonp]

Perhaps:

Code - Auto/Visual Lisp: [Select]

1. (vlax-for i (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
2.   (and (not (vl-string-search "|" (vla-get-name i)))
3.        (= (vla-get-layeron i) :vlax-true)
4.        (= (vla-get-freeze i) :vlax-false)
5.        (setq llist (cons (vla-get-name i) llist))
6.   )
7. ;;;  (cond ((not (vl-string-search "|" (vla-get-name i)))
8. ;;;         ((= (vla-get-layeron i) :vlax-true))
9. ;;;         ((= (vla-get-freeze i) :vlax-false))
10. ;;;         ((setq llist (append llist (vla-get-name i))))
11. ;;;        )
12. ;;;  )
13. )

[BlackBox]

I'm having major mental blockage this afternoon.  I want to test for several condition with a layer and then add it to a list if it meets all the conditions.  I know the following isn't right but maybe it can spark some ideas:

Code: [Select]

(vlax-for i(vla-get-layers(vla-get-ActiveDocument(vlax-get-acad-object)))
  (cond((not(vl-string-search "|" (vla-get-name i)))
((=(vla-get-layeron i):vlax-true))
((=(vla-get-freeze i):vlax-false))
((setq llist(append llist (vla-get-name i))))
)
       )
  )
Thanks for any input!!

Code - Auto/Visual Lisp: [Select]

1. (defun _GetUsedLayers ( / layerName)
2.   (vlax-for i (vla-get-layers
3.                 (vla-get-ActiveDocument (vlax-get-acad-object))
4.               )
5.     (if
6.       (and
7.         (not (vl-string-search "|" (setq layerName (vla-get-name i))))
8.         (= (vla-get-layeron i) :vlax-true)
9.         (= (vla-get-freeze i) :vlax-false)
10.       )
11.        (setq layers (cons layerName layers))
12.     )
13.   )
14.   (reverse layers)
15. )
16.  

[Edit] - Ninja wins. 

[jbuzbee]

Thanks RonjonP - that did it!

[Lee Mac]

The (not (vl-string-search ... )) could also be replaced with a single wcmatch test, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (vlax-for i (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
2.     (if (and (wcmatch (vla-get-name i) "~*|*")
3.              (= :vlax-true (vla-get-layeron i))
4.              (= :vlax-false (vla-get-freeze i))
5.         )
6.         (setq llist (cons (vla-get-name i) llist))
7.     )
8. )

[ronjonp]

Thanks RonjonP - that did it!

Glad to help out