Topic: =={ Challenge }== Decompress String

[ElpanovEvgeniy]

recursion:

Code - Auto/Visual Lisp: [Select]

1. (defun f (s a / b)
2.   (cond ((= s "") a)
3.         ((= (atoi s) 0) (f (substr s 2) (strcat a (substr s 1 1))))
4.         ((f (substr s 2) (progn (setq b "") (repeat (atoi (substr s 1 1)) (setq b (strcat a b))))))
5.   )
6. )

test:

Code: [Select]

(f "ab2c3" "")
"ababcababcababc"
(f "ab4c3d2" "")
"ababababcababababcababababcdababababcababababcababababcd"
(f "a23" "")
"aaaaaa"

[Jeff H]

Just starting to mess with AutoLisp so total noob here
 

Code - Auto/Visual Lisp: [Select]

1. (defun Decompress (string)
2.  (recursiveDecompress "" string)
3. )
4.  
5. (defun recursiveDecompress (string1 string2 / str3)
6.  (setq str3 "")
7.  (cond
8.    ((equal "" string2) string1)
9.    ((repeat (atoi string2) (setq str3 (strcat str3 string1)))
10.       (recursiveDecompress str3 (substr string2 2)))
11.    (T (recursiveDecompress (strcat string1 (substr string2 1 1)) (substr string2 2)))
12.   )
13. )
14.  
15.  

[Jeff H]

That's what I get for being noob  this might be correct depending on if this is correct

Code: [Select]

_$ (Decompress "a23")
"aaaaaa"

Does (Decompress "a23") =  "aaaaaa" or "aaa"?
 
 
 

Code - Auto/Visual Lisp: [Select]

1. (defun recursiveDecompress (string1 string2 / str3)
2.  (setq str3 "")
3.  (cond
4.    ((equal "" string2) string1)
5.    ((repeat (atoi (substr string2 1 1)) (setq str3 (strcat str3 string1)))
6.       (recursiveDecompress str3 (substr string2 2)))
7.    (T (recursiveDecompress (strcat string1 (substr string2 1 1)) (substr string2 2)))
8.   )
9. )
10.  
11.  

[Kerry]

That's what I get for being noob  this might be correct depending on if this is correct

Code: [Select]

_$ (Decompress "a23")
"aaaaaa"

Does (Decompress "a23") =  "aaaaaa" or "aaa"?
 
 

Yes.

[ElpanovEvgeniy]

hi Jeff H!
We have written the same code  :coolsmiley:

[CAB]

Ahhh, I see you've changed the 'specs' to clarify ...

That's how it works in real life. The specs have a way of evolving to accommodate the unforeseen. It helps to have several perspectives. 

[Kerry]

Ahhh, I see you've changed the 'specs' to clarify ...

That's how it works in real life. The specs have a way of evolving to accommodate the unforeseen. It helps to have several perspectives. 

My argument has always been that we need to learn how to ask questions as much as we need to learn to solve problems.

[ElpanovEvgeniy]

My argument has always been that we need to learn how to ask questions as much as we need to learn to solve problems.

good words! 

[Kerry]

Thank you Sir!

[irneb]

My argument has always been that we need to learn how to ask questions as much as we need to learn to solve problems.

+1 I agree with you on this, unfortunately I didn't foresee the possibilities. In my mind some of them didn't matter - seeing as they didn't apply to the results (only to the implementation).

My thought on changing the original was that instead of someone having to read all the following posts - the queries asked later were to be incorporated. At least those where I felt I failed to mention in the OP. Sorry guys.

[Jeff H]

hi Jeff H!
We have written the same code  :coolsmiley:

Either I got lucky or you screwed up.
 

[Jeff H]

hi Jeff H!
We have written the same code  :coolsmiley:

Hi Elpanov,

I do not have much experience with Lisp but can most problems be solved in Lisp  with

Code: [Select]

   (DEFUN <RECURSIVE-FUNCTION> (<PARAM1> ... <PARAMN>)
       (COND (<TERMINATING-CONDITION1> <RESULT1>)
.
.
             (<TERMINATING-CONDITIONN> <RESULTN>)
             (<RECURSIVE-CONDITION1> <RECURSIVE-CALL1>)
.
.
             (<RECURSIVE-CONDITIONM> <RECURSIVE-CALLM>)))

[irneb]

I do not have much experience with Lisp but can most problems be solved in Lisp  with

Yes "most" ... though unlike some other Lisps (e.g. Scheme) AutoLisp doesn't have tail-call-elimination, thus recursion would cause stack overflows if the call stack becomes too deep. So generally be careful when you're processing something like a list longer than around 10k to 20k.

Actually if you program in something like Scheme / Clojure you're encouraged to use recursion instead of iterative loops. But that's not always the case, e.g. Common Lisp tends to make use of iterative looping instead.

[roy_043]

Two more from me.

Roy_Decompress_3 is similar to Roy_Decompress_2 but probably faster because it relies less on string operations.
Roy_Decompress_4 is my version with recursion.

Code - Auto/Visual Lisp: [Select]

1. (defun Roy_Decompress_3 (str / out tmp)
2.   (foreach int (vl-string->list str)
3.     (cond
4.       ((<= 50 int 57) ; 2-9
5.         (setq tmp out)
6.         (repeat (- int 49)
7.           (setq out (append tmp out))
8.         )
9.       )
10.       ((= int 48) ; 0
11.         (setq out nil)
12.       )
13.       ((/= int 49) ; 1
14.         (setq out (append out (list int)))
15.       )
16.     )
17.   )
18.   (vl-list->string out)
19. )

Code - Auto/Visual Lisp: [Select]

1. (defun Roy_Decompress_4 (str / N_Decode)
2.   (defun N_Decode (lst / out tmp)
3.     (cond
4.       ((not lst)
5.         nil
6.       )
7.       ((= (car lst) 48) ; 0
8.         nil
9.       )
10.       ((<= 49 (car lst) 57) ; 1-9
11.         (setq tmp (N_Decode (cdr lst)))
12.         (repeat (- (car lst) 48)
13.           (setq out (append tmp out))
14.         )
15.       )
16.       (T
17.         (cons (car lst) (N_Decode (cdr lst)))
18.       )
19.     )
20.   )
21.   (vl-list->string (reverse (N_Decode (reverse (vl-string->list str)))))
22. )

[Lee Mac]

Without looking at anything already posted:

Code - Auto/Visual Lisp: [Select]

1. (defun decompress ( s / f )
2.     (defun f ( s x r )
3.         (cond
4.             (   (= "" s) x)
5.             (   (wcmatch s "#*")
6.                 (if (< 0 (atoi s))
7.                     (f (strcat (itoa (1- (atoi s))) (substr s 2)) x (strcat r x))
8.                     (f (substr s 2) r "")
9.                 )
10.             )
11.             (   (f (substr s 2) (strcat x (substr s 1 1)) r))
12.         )
13.     )
14.     (f s "" "")
15. )