Topic: Draw circles from coordinates in selected text file

[chvnprasad]

I Need a lisp to draw circles from coordinates in selected text file


Text file:

9485142.9518559594,5166531.8181330599
9484362.5073601492,5166805.4889352201
9484285.1593047995,5166818.7789066397
9484230.7121146191,5166825.8073841901
9484159.8337314799,5166836.7660814496

[reltro]

hey cvnp...

Im not sure how u want to draw a circle just out of coordinates, without radius or somethig similar...

diameter?
radius?
2 Points?
3 Points?


But, to read coordiantes form a file, this may help:

Code - Auto/Visual Lisp: [Select]

1. (defun foo (/ f l lst)
2.     (setq f (open "D:\\Circles.txt" "r")) ;;change the Path to point ur file!
3.     (while (setq l (read-line f))
4.         (setq lst (cons (read (strcat "(" (vl-string-translate "," " " l) ")")) lst))
5.     )
6.     (close f)
7.     (reverse lst)
8. )
9.  

greets reltro

[ChrisCarlson]

Does the text file change or is this a one time scenario ?

[chvnprasad]

Text file content is changinh regularly, but path file location and name is constant and circle radius need to be constant (ex; 10).

[reltro]

Text file content is changinh regularly, but path file location and name is constant and circle radius need to be constant (ex; 10).

If the file has changed u need to update the allready drawn circles?

[ChrisCarlson]

Code - Auto/Visual Lisp: [Select]

1. Code includes lines from http://www.cadtutor.net/forum/showthread.php?44768-Entmake-Functions
2.  
3. (defun c:ccoord (/ _ readfile pt01)
4. (initget (+ 1 64))
5. (setq rad (getdist "\nSpecify Radius: "))
6.  (defun _readfile (filename / circles file result line)
7.     (cond ((and (eq 'str (type filename)) (setq file (open filename "r")))
8.            (while (setq line (read-line file)) (setq result (cons line result)))
9.            (close file)
10.            (reverse result)
11.           )
12.     )
13.   )
14.         (if (setq lst (_readfile "C:/Circles.txt"))
15.                 (progn (vl-load-com)
16.                         (foreach cen lst       
17.                                 (entmakex
18.                                         (list
19.                                                 (cons 0 "CIRCLE")
20.                                                 (cons 10 cen)
21.                                                 (cons 40 rad)
22.                                         ) ;end list                    
23.                                 ); end entmakex
24.                         ) ; end foreach
25.                 ); end progn
26.                 (alert "FILE NOT FOUND!")
27.         ); end if      
28.   (princ)
29. ); end function

[Lee Mac]

Another:

Code - Auto/Visual Lisp: [Select]

1. (defun c:txt2cir ( / c f r )
2.     (setq r '(40 . 10.0)) ;; Circle radius
3.     (if (and (setq f (getfiled "" "" "txt" 16)) (setq f (open f "r")))
4.         (progn
5.             (while (setq c (read-line f))
6.                 (setq c (read (strcat "(10 " (vl-string-translate "," " " c) ")")))
7.                 (if (and (vl-every 'numberp c) (< 2 (length c) 5))
8.                     (entmake (list '(0 . "CIRCLE") c r))
9.                 )
10.             )
11.             (close f)
12.         )
13.     )
14.     (princ)
15. )

For a static filename, change:

Code - Auto/Visual Lisp: [Select]

1. (setq f (getfiled "" "" "txt" 16))

To:

Code - Auto/Visual Lisp: [Select]

1. (setq f "C:\\YourFilename.txt")

[ronjonp]

Nice Lee 

Code - Auto/Visual Lisp: [Select]

1. (setq c (read (strcat "(10 " (vl-string-translate "," " " c) ")")))

[Lee Mac]

Cheers Ron - though reltro did suggest something similar earlier in the thread, so I can't take all the credit 

[ChrisCarlson]

Suppose I should have tested mine before....it's entering in a bad DXF code.