Topic: How to get max of repeated variable?

[HasanCAD]

I am coding a lisp with repeat

Code: [Select]

(repeat (- columnscount 1)
    (collectdata)
    (drft)
    )
(defun collectdata ( /  )
    (setq *W  (cond ( (getint (strcat "\nWhats is column  C" (itoa ColumnNo) "  Width <" (itoa (setq *w  (cond ( *w  ) ( 300 )))) ">: "))) ( *w  )))
    (setq *L  (cond ( (getint (strcat "\nWhats is column  C" (itoa ColumnNo) "  Length <" (itoa (setq *l  (cond ( *l  ) ( 600 )))) ">: "))) ( *l  )))
    )and there is a variable.
How to get the max of variable

Code: [Select]

(setq *L  (cond ( (getint (strcat "\nWhats is column  C" (itoa ColumnNo) "  Length <" (itoa (setq *l  (cond ( *l  ) ( 600 )))) ">: "))) ( *l  )))

[Kerry]

Please clarify ?

You have a quantity of "Columns"

You want to build a datalist of the column width and height for each column.


What is function (drft) for ?

I'm not sure of your real intention.
What is the MAX function meant to be applied to ??

Have a play:

Code - Auto/Visual Lisp: [Select]

1.  
2. (defun collectdata (ColumnNo / )
3.   (setq
4.     *W (cond
5.          ((getint (strcat "\nWhats is column  C"
6.                           (itoa ColumnNo)
7.                           "  Width <"
8.                           (itoa (setq *w (cond (*w)
9.                                                (300)
10.                                          )
11.                                 )
12.                           )
13.                           ">: "
14.                   )
15.           )
16.          )
17.          (*w)
18.        )
19.   )
20.   (setq
21.     *L (cond
22.          ((getint (strcat "\nWhats is column  C"
23.                           (itoa ColumnNo)
24.                           "  Length <"
25.                           (itoa (setq *l (cond (*l)
26.                                                (600)
27.                                          )
28.                                 )
29.                           )
30.                           ">: "
31.                   )
32.           )
33.          )
34.          (*l)
35.        )
36.   )
37.   (list *W *L)
38. )
39.  
40.  
41.  
42.  
43.  
44.  
45. (defun c:doit (/ add local variables)
46.   (setq columnCount 3
47.         ColumnData nil
48.         index 1
49.   )
50.   (while (<= index columnCount)
51.     (while (<= index columncount)
52.       (setq data (collectData index))
53.       (princ data)
54.       (setq columndata (cons data columndata))
55.       (setq index (1+ index))
56.     )
57.   )
58.   (setq columndata (reverse columndata))
59.   (princ "\n")
60.   (princ (vl-princ-to-string columndata))
61.   (princ)
62. )
63.  
64.  

Command:
Command: DOIT
Whats is column  C1  Width <300>: 100
Whats is column  C1  Length <350>: 150
(100 150)
Whats is column  C2  Width <100>: 200
Whats is column  C2  Length <150>: 250
(200 250)
Whats is column  C3  Width <200>: 300
Whats is column  C3  Length <250>: 350
(300 350)
((100 150) (200 250) (300 350))

[HasanCAD]

I am trying to draft column section

the next step is to copy all to make new row of columns
So I want to know the max column length to to avoid overlaping of objects

Code - Auto/Visual Lisp: [Select]

1. ;|----------- COLUMNSCHEDULE -------------------
2.             q_|_|| _\|| q_|| _\|               
3.                                                
4.   To Draw Column Section, vertical bars        
5.   and adding dimensions                        
6.                                                
7. ------------------------------------------------
8.   Author: Hasan M. Asous, 2014                 
9.         ALL RIGHT RESERVED TO ALL              
10.                                                
11.   Contact: HasanCAD @ TheSwamp.org,            
12.            asos2000 @ CADTutor.net             
13.            HasanCAD@gmail.com                  
14. ------------------------------------------------
15.   Version: 1      2014 07 20 1st version       
16. ________________________________________________
17.                                               |;
18.  
19.  
20.         ;     q_|_|| _\|| q_|| _\|     ;
21.         ;       Mainroutine Start      ;
22.  
23. (defun c:COLUMNSCHEDULE () (c:CSD))
24. (DEFUN c:CSD ( / cmd cvr cvr2 doc dym dyp i ix ixx iy osm spc)
25.  
26.   (vl-load-com)
27.   (setq *acad (cond (*acad) ((vlax-get-acad-object))))
28.   (setq doc (vla-get-ActiveDocument (setq *acad (vlax-get-Acad-Object)))
29.         spc (if (zerop (vla-get-activespace doc)) (if (= (vla-get-mspace doc) :vlax-true) (vla-get-modelspace doc) (vla-get-paperspace doc)) (vla-get-modelspace doc)))
30.   (setq uFlag (not (vla-StartUndoMark doc)))
31.  
32.   (makelay "S-OPEN"             3       "Continuous")           ; CREATE LAYERS
33.   (makelay "S-BARS"             4       "Continuous")
34.   (makelay "S-ANNO-TEXT"        3       "Continuous")
35.   (makelay "S-ANNO-LEGN1"       4       "Continuous")
36.   (makelay "S-BARS-SECT-VERT"   4       "Continuous")
37.   (makelay "S-STRP"             220     "Continuous")
38.   (makelay "S-ANNO-DIMS"        15      "Continuous")
39.   (_makefonts '(("SDC-TEXT" . "Arial.ttf")))                    ; CREATE TSTYLE
40.   (scaledel_create_scales '( ("1:25" "1:25") ))                 ; CREATE annotation
41.   (vl-cmdf "cannoscale" "1:25"  )
42.   (setq osm (getvar "osmode"    ))  
43.   (setq dym (getvar "dynmode"   ))      (setvar "dynmode" 1)
44.   (setq dyp (getvar "dynprompt" ))      (setvar "dynprompt" 1)
45.   (setq cmd (getvar "cmdecho"   ))      (setvar "cmdecho" 0)
46.   (Blk T)
47.   (setq cvr 25.0        )                                       ; column cover
48.   (setq cvr2 (* 2 cvr)  )
49.   (vl-cmdf "_.-insert" "R:/SDC_LIBRARIES/CAD_LIBRARY/BLOCKS/S/Stirrup.dwg" "0,0,0" "1" "1" "0")         ; inser stirrup block
50.   (vl-cmdf "_.erase" "last" "")
51.   (vl-cmdf "_.-purge" "blocks" "Stirrup" "n")
52.   (vl-cmdf "_.-DIMSTYLE" "Restore" "SDC_DIM")
53.  
54.   (setq ColumnsCount (getint "\nHow many column you want to draw?"))
55.   (setq ColumnCuts (getint "\nHow many cut in columns"))
56.   (setq ColumnNo 1)
57.  
58.   (collectdata)
59.   (setq i (getpoint "\n Pick insertion point") iX (nth 0 i) iXX (nth 0 i) iY (nth 1 i))
60.   (drft)
61.  
62.   (repeat (- columnscount 1)
63.     (setq ColumnNo (1+ ColumnNo))
64.     (setq iX (+ 1300 iX))
65.     (collectdata)
66.     (drft)
67.     )
68.   (makeline i (list (+ iX 1300) iY 0.0) "Continuous" "S-ANNO-LEGN1" )                                   ; CREATE LINES
69.   (makeline (list iXX (+ iY 500) 0.0) (list (+ iX 1300) (+ iY 500) 0.0) "Continuous" "S-ANNO-LEGN1" )
70.   (vl-cmdf "_.zoom" (list (- iXX 200) (- iY 200)) (list (+ (+ iX 650) (* 0.5 *w) 500 ) (+ iY 1500 *l)))
71.   (setq Lmax (max *Llst))
72.  
73.   (setvar "osmode"      osm     )
74.   (setvar "dynmode"     dym     )
75.   (setvar "dynprompt"   dyp     )
76.   (setvar "cmdecho"     cmd     )
77.   (setq uFlag (vla-EndUndoMark doc))
78.   )
79.    
80.         ;     q_|_|| _\|| q_|| _\|     ;
81.         ;       Mainroutine End        ;
82.  
83.  
84.         ;     q_|_|| _\|| q_|| _\|     ;
85.         ;       Subroutine Start       ;
86.  
87. (defun collectdata ( / *Llst )
88.     (setq *w  (cond ( (getint (strcat "\nWhats is column  C" (itoa ColumnNo) "  Width <"        (itoa (setq *w  (cond ( *w  ) ( 300 )))) ">: "))) ( *w  )))
89.     (setq *l  (cond ( (getint (strcat "\nWhats is column  C" (itoa ColumnNo) "  Length <"       (itoa (setq *l  (cond ( *l  ) ( 600 )))) ">: "))) ( *l  )))
90.     (setq *tb (cond ( (getint (strcat "\nHow many bar at top and bottom <"                      (itoa (setq *tb (cond ( *tb ) (   3 )))) ">? "))) ( *tb )))
91.     (setq *sd (cond ( (getint (strcat "\nHow many bar at side <"                                (itoa (setq *sd (cond ( *sd ) (   5 )))) ">? "))) ( *sd )))
92.     (setq *d  (cond ( (getint (strcat "\nWhats BARS dia <"                                      (itoa (setq *d  (cond ( *d  ) (  20 )))) ">? "))) ( *d  )))
93.     (setq vb  (- (* 2 (+ *tb *sd)) 4)) ; total number of BARS
94.     (setq *str (cond (*str) ("T10@200")))
95.     (setq *str (if (= "" (setq tmp (strcase (getstring (strcat "\nWhat is Stirrup Dia And repeatation? <" *str  ">: "))))) *str tmp))
96.   (setq *Llst (cons *l *Llst))
97.     )
98.  
99. (defun drft ( / )
100.     (setq p1a (list (+ (- (+ iX 650) (* 0.5 *w)) cvr2) (+ (+ iY 1000)    cvr2) 0.0 ))   ;POINTS FOR BARS
101.     (setq p2a (list (- (+ (+ iX 650) (* 0.5 *w)) cvr2) (+ (+ iY 1000)    cvr2) 0.0 ))
102.     (setq p3a (list (- (+ (+ iX 650) (* 0.5 *w)) cvr2) (- (+ iY 1000 *l) cvr2) 0.0 ))
103.     (setq p4a (list (+ (- (+ iX 650) (* 0.5 *w)) cvr2) (- (+ iY 1000 *l) cvr2) 0.0 ))
104.     (DVD p1a p2a *tb *d)
105.     (DVD p2a p3a *sd *d)
106.     (DVD p4a p3a *tb *d)
107.     (DVD p1a p4a *sd *d)
108.     (Insert p1a "SS" *d)
109.     (Insert p2a "SS" *d)
110.     (Insert p3a "SS" *d)
111.     (Insert p4a "SS" *d)
112.     (setq pts (list
113.                 (- (+ iX 650) (* 0.5 *w)) (+ iY 1000)   0.0
114.                 (+ (+ iX 650) (* 0.5 *w)) (+ iY 1000)   0.0
115.                 (+ (+ iX 650) (* 0.5 *w)) (+ iY 1000 *l)        0.0
116.                 (- (+ iX 650) (* 0.5 *w)) (+ iY 1000 *l)        0.0     ))                      ;POINTS FOR COLUMN AS LIST
117.  
118.     (vla-put-closed (vla-addPolyline Spc (setq pts (vlax-make-variant (vlax-safearray-fill (vlax-make-safearray vlax-vbdouble (cons 0 (1- (length pts)))) pts))))  :vlax-true)                  ; DRAW COLUMN
119.     (setq clm (vlax-ename->vla-object (entlast)))
120.     (vla-put-layer clm "S-OPEN")
121.     (vla-put-color clm 256)
122.  
123.     (setq p1 (list (+ (+ iX 650) (* 0.5 *w)) (+ iY 1000 *l) 0.0 ))
124.     (vl-catch-all-error-p (setq strp (vl-catch-all-apply (function vla-InsertBlock) (list spc (vlax-3D-point p1) "STRP-01" 1.0 1.0 1.0 0))))
125.     (vla-put-layer STRP "S-STRP")
126.     (LM:setdynprops STRP (list (cons "X Distance1" *w) (cons "Y Distance1" *l)))                ; MODIFY STIRRUP PROPERTIES TO BE MODIFIED AFTER
127.     (vl-cmdf "_.zoom" (list (- (+ iX 650) (* 0.5 *w)) (+ iY 750) 0.0 ) (list (+ (+ iX 650) (* 0.5 *w)) (+ iY 1250 *l) 0.0 ))
128.     (initget "Yes No")
129.     (setq *str2 (cond ( (getkword (strcat "\nDo you want to add additional stirrup [Yes/No] <" (setq *str2 (cond ( *str2 ) ( "Yes" )))  ">: "))) ( *str2 )))
130.     (if (= *str2 "Yes")
131.       (progn
132.         (setq *str-no (cond ( (getint (strcat "\nHow many addtional STIRRUP should be added  <" (itoa (setq *str-no (cond ( *str-no ) ( 2 )))) ">: "))) ( *str-no )))
133.         (setvar "osmode" 64)
134.         (repeat *str-no
135.           (setq ap1 (getpoint "\nPick First bar"))
136.           (setq ap2 (getpoint "\nPick Second bar"))
137.           (setq aap1 (list (max (nth 0 ap1) (nth 0 ap2)) (max (nth 1 ap1) (nth 1 ap2)) (max (nth 2 ap1) (nth 2 ap2))))
138.           (setq aap2 (list (min (nth 0 ap1) (nth 0 ap2)) (min (nth 1 ap1) (nth 1 ap2)) (min (nth 2 ap1) (nth 2 ap2))))
139.           (vl-catch-all-error-p (setq strp2 (vl-catch-all-apply (function vla-InsertBlock) (list spc (vlax-3D-point aap1) "STRP-02" 1.0 1.0 1.0 0))))
140.           (vla-put-layer STRP2 "S-STRP")
141.           (LM:setdynprops STRP2 (list (cons "X Distance1" (- (max (nth 0 ap1) (nth 0 ap2)) (min (nth 0 ap1) (nth 0 ap2)))) (cons "Y Distance1" (- (max (nth 1 ap1) (nth 1 ap2)) (min (nth 1 ap1) (nth 1 ap2))))))))
142.       (vl-cmdf "_.zoom" "Previous"))
143.      
144.   (MakeText (strcat "C" (itoa ColumnNo))                        4       (list (+ iX 650) (+ iY 250) 0.0 ) "S-ANNO-TEXT" 100  0 "SDC-TEXT" 1 2 T)                                ; CREATE TEXT
145.   (MakeText (strcat "(" (itoa (1+ *str-no)) " PER SET)")        256     (list (+ iX 650) (+ iY 650) 0.0 ) "S-ANNO-TEXT" 62.5 0 "SDC-TEXT" 1 2 T)
146.   (MakeText (strcat "WITH " *str " TIES")                       256     (list (+ iX 650) (+ iY 750) 0.0 ) "S-ANNO-TEXT" 62.5 0 "SDC-TEXT" 1 2 T)
147.   (MakeText (strcat (itoa vb) "T" (itoa *d) " VERTICAL BARS")   256     (list (+ iX 650) (+ iY 850) 0.0 ) "S-ANNO-TEXT" 62.5 0 "SDC-TEXT" 1 2 T)
148.  
149.   (setq pc1 (list (- (+ iX 650) (* 0.5 *w)) (+ iY 1000)         0.0))
150.   (setq pc2 (list (+ (+ iX 650) (* 0.5 *w)) (+ iY 1000)         0.0))
151.   (setq pc3 (list (+ (+ iX 650) (* 0.5 *w)) (+ iY 1000 *l)      0.0))
152.   (setq pc4 (list (- (+ iX 650) (* 0.5 *w)) (+ iY 1000 *l)      0.0))
153.  
154.   (apply (function vla-AddDimRotated) (append (list spc) (mapcar (function vlax-3D-point) (list pc3 pc4 (polar pc4 (angle (trans pc1 1 0) pc4) 250))) '(0.)))
155.   (vl-cmdf "CHPROP" "L" "" "Annotative" "Yes" "")
156.   (setq dim (vlax-ename->vla-object (entlast)))
157.   (vla-put-layer dim "S-ANNO-DIMS")
158.   (vla-put-color dim 256)
159.    
160.   (apply (function vla-AddDimRotated) (append (list spc) (mapcar (function vlax-3D-point) (list pc1 pc4 (polar pc1 (angle (trans pc1 1 0) pc1) -250))) (list (/ pi 2.))))
161.   (vl-cmdf "CHPROP" "L" "" "Annotative" "Yes" "")
162.   (setq dim (vlax-ename->vla-object (entlast)))
163.   (vla-put-layer dim "S-ANNO-DIMS")
164.   (vla-put-color dim 256)
165.   (vl-cmdf "cannoscale" "1:25"  )
166.   ;(setq cut (cons (+ 500 p3) cut)
167.   )
168.  
169.  
170.  
171. (defun *error* (msg) (and uFlag (vla-EndUndoMark doc)) (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*") (princ (strcat "\n** Error: " msg " **"))) (princ))
172.  
173. (defun Insert   (pt Nme scl) (entmakex (list (cons 0 "INSERT") (cons 2 Nme) (cons 8 "S-BARS-SECT-VERT") (cons 10 pt) (cons 41 scl) (cons 42 scl) (cons 43 scl))))
174.  
175. ;; Set Dynamic Block Properties  -  Lee Mac
176. ;; Modifies values of Dynamic Block properties using a supplied association list.
177. ;; blk - [vla] VLA Dynamic Block Reference object
178. ;; lst - [lst] Association list of ((<Property> . <Value>) ... )
179. ;; Returns: nil
180. (defun LM:setdynprops ( blk lst / itm ) (setq lst (mapcar '(lambda ( x ) (cons (strcase (car x)) (cdr x))) lst)) (foreach x (vlax-invoke blk 'getdynamicblockproperties) (if (setq itm (assoc (strcase (vla-get-propertyname x)) lst)) (vla-put-value x (vlax-make-variant (cdr itm) (vlax-variant-type (vla-get-value x)))))))
181.  
182. (defun DVD ( dp1 dp2 n sc / l dsd i o k la sc)  ;(DVD dp1 dp2 n sc)
183.   (setq la (getvar "CLayer"))
184.   (setvar "CLayer" "S-BARS-SECT-VERT")
185.   (command "_.Line" "_non" dp1 "_non" dp2 "")
186.   (setq o (entlast))
187.   (setq n (- n 1))
188.   (setq dsd (/ (distance dp1 dp2) n))
189.   (setq i dsd)
190.   (repeat n (entmake (append (list '(0 . "INSERT")'(2 . "SS")(cons 10 (vlax-curve-getpointatdist o i))) (mapcar '(lambda (k) (cons k sc)) (list 41 42 43)))) (setq i (+ dsd i)))
191.   (command "_.Erase" "last" "")
192.   (command "_.Erase" o "")
193.   (setvar "CLayer" la))
194.  
195. (defun Blk (ex / blks)
196.     (if (not (tblsearch "BLOCK" "SS"))
197.       (progn
198.         (entmake '((0 . "BLOCK") (100 . "AcDbEntity") (67 . 0) (8 . "0") (100 . "AcDbBlockReference") (2 . "SS") (10 0.0 0.0 0.0) (70 . 0)))
199.         (entmake '((0 . "HATCH") (100 . "AcDbEntity") (8 . "0") (100 . "AcDbHatch") (10 0.0 0.0 0.0) (210 0.0 0.0 1.0) (2 . "SOLID") (70 . 1) (71 . 0) (91 . 1) (92 . 7) (72 . 1) (73 . 1) (93 . 2) (10 0.5 0.0 0.0) (42 . 1.0) (10 -0.5 0.0 0.0) (42 . 1.) (97 . 0) (75 . 0) (76 . 1) (47 . 0.01) (98 . 1) (10 0.1 -0.1 0.0) (450 . 0) (451 . 0) (460 . 0.0) (461 . 0.0) (452 . 1) (462 . 1.0) (453 . 2) (463 . 0.0) (63 . 5) (421 . 255) (463 . 1.0) (63 . 7) (421 . 16777215) (470 . "LINEAR")))
200.         (entmake '((0 . "ENDBLK")       (100 . "AcDbBlockEnd")  (8 . "0")))))
201.   (if ex
202.     (progn
203.       (setq blks (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))
204.       (vla-put-explodable        (vla-item blks "SS") :vlax-false)
205.       (vla-put-BlockScaling      (vla-item blks "SS") acUniform)
206.       ))
207.     (princ)
208.   )
209.  
210. (defun makelay (LName LColor LType)    ; (makelay LName LColor LType)
211. ;  CAB
212. (vl-load-com)
213.   (if (not (tblsearch "LTYPE" LType)) (vla-load (vla-get-Linetypes (vla-get-ActiveDocument (vlax-get-acad-object))) LType "acadiso.lin"))
214.   (if (not(tblsearch "LAYER" LName))
215.     (entmake (list
216.                '(0 . "LAYER")
217.                '(100 . "AcDbSymbolTableRecord")
218.                '(100 . "AcDbLayerTableRecord")
219.                (cons 2  LName)       ;layer name
220.                (cons 6  (if (and ltype(tblobjname "ltype" ltype)) ltype  "Continuous")) ;linetype
221.                (cons 62  LColor) ;layer color
222.                '(70 . 0) ; on, unlocked, thawed
223.              ))))
224.  
225.   ;;by VovKa  http://www.theswamp.org/index.php?to...4927#msg384927
226. (defun _makefonts (listoffonts / doc font fntdir st)
227.   (vl-load-com)
228.   (setq doc    (vla-get-activedocument (vlax-get-acad-object))
229.         fntdir (strcat (getenv "windir") "\\Fonts\\"))
230.   (foreach f listoffonts
231.     (cond ((or (setq font (findfile (cdr f)))
232.                (and (setq font (findfile (strcat fntdir (cdr f)))) (findfile font)))
233.            (setq st (vla-add (vla-get-textstyles doc) (car f)))
234.            (vlax-put-property st 'fontfile font)
235.            (vlax-put-property st 'width 1.0)
236.            (vlax-put-property st 'height 0.0)))) (princ))
237. ;; Usage (_makefonts '(("SDC-TEXT" . "Arial.ttf")))
238.  
239. (defun MakeText (str c pt lyr ht ro TSyl G72 G73 an)
240.   (entmakex (list (cons 0 "TEXT")       ;***
241.                  (cons 1 str)           ;* (the string itself)
242.                  (cons 6 "BYLAYER")     ; Linetype name
243.                  (cons 7 TSyl)          ;* Text style name, defaults to STANDARD, not current
244.                  (cons 8 lyr)           ; layer
245.                  (cons 10 pt)           ;* First alignment point (in OCS)
246.                  (cons 11 pt)           ;* Second alignment point (in OCS)
247.                  (cons 39 0.0)          ; Thickness (optional; default = 0)
248.                  (cons 40 ht)           ;* Text height
249.                  (cons 41 1.0)          ; Relative X scale factor, Width Factor, defaults to 1.0
250.                  (cons 50 ro)           ; Text rotation angle
251.                  (cons 51 0.0)          ; Oblique angle
252.                  (cons 62 c)            ; color
253.                  (cons 71 0)            ; Text generation flags
254.                  (cons 72 G72)          ; Horizontal text justification type
255.                  (cons 73 G73)          ; Vertical text justification type
256.                  (cons 210 (list 0.0 0.0 1.0))))
257.   (if an (vl-cmdf "CHPROP" "L" "" "Annotative" "Yes" "")))
258. ;Group 73       | Group 72
259. ;               |   0       1                2              3               4             5    
260. ;3 (top)        | TLeft | TCenter       | TRight                                               
261. ;2 (middle)     | MLeft | MCenter       | MRight                                               
262. ;1 (bottom)     | BLeft | BCenter       | BRight                                               
263. ;0 (baseline)   | Left  | Center        | Right         | Aligned       | Middle        | Fit  
264.  
265. (defun makeline (str end Ltp lyr )
266.   (entmake (list (cons 0 "LINE")        ; ***
267.                (cons 6 Ltp)             ; Linetype name (present if not BYLAYER)
268.                (cons 8 lyr)             ; Layer
269.                (cons 10 str)            ; Start Point
270.                (cons 11 end)            ; End Point
271.                (cons 39 0.0)            ; Thickness (optional) default = 0
272.                (cons 62 256)            ; Color number (present if not BYLAYER);
273.                (cons 210 (list 0.0 0.0 1.0)))))
274.  
275. (defun scaledel_create_scales (SCALES / scale-list-all cmdecho)
276.   (setq scale-list-all (scaledel_get_scalelist)
277.         cmdecho (getvar "CMDECHO"))
278.   (setvar "CMDECHO" 0)
279.   (command "_.-SCALELISTEDIT")
280.   (foreach scale SCALES (if (not (member (strcase (car scale)) scale-list-all)) (command "_A" (car scale) (cadr scale))))
281.   (command "_E")
282.   (setvar "CMDECHO" cmdecho)) ; End scaledel_create_scales
283.  
284. (defun scaledel_get_scalelist (/ scale-list)
285.       (foreach item (dictsearch (namedobjdict) "ACAD_SCALELIST")
286.         (if (= 350 (car item))
287.           (setq scale-list (cons (strcase (cdr (assoc 300 (entget (cdr item))))) scale-list))))
288.       scale-list) ; End scaledel_get_scalelist
289.  
290. (princ)
291. (princ "\n      q_|_|| _\\|| q_|| _\\|")
292. (princ "\n  Type  CSD  to invoke the lisp")
293.  
294.         ;     q_|_|| _\|| q_|| _\|     ;
295.         ;        Subroutine End        ;

[Kerry]

I'm not interested in trying to read your code.
The code is your answer (which you are unhappy with) to the question'
I want to know the question.
Just explain what you want.

What is the MAX function meant to be applied to ??

[Kerry]

Code - Auto/Visual Lisp: [Select]

1. ;;;------------------------------------------------------------------
2. ;;;------------------------------------------------------------------
3. ;;;
4. ;;; min max X Y Z
5. (defun kdub:minx (pointlist)
6.   (apply (function min) (mapcar (function car) pointlist))
7. )
8. (defun kdub:miny (pointlist)
9.   (apply (function min) (mapcar (function cadr) pointlist))
10. )
11. (defun kdub:minz (pointlist)
12.   (apply (function min) (mapcar (function caddr) pointlist))
13. )
14.  
15. (defun kdub:maxx (pointlist)
16.   (apply (function max) (mapcar (function car) pointlist))
17. )
18. (defun kdub:maxy (pointlist)
19.   (apply (function max) (mapcar (function cadr) pointlist))
20. )
21. (defun kdub:maxz (pointlist)
22.   (apply (function max) (mapcar (function caddr) pointlist))
23. )
24.  
25. ;;; min XY max XY
26. (defun kdub:minxy (pointlist)
27.   (list (kdub:minx pointlist) (kdub:miny pointlist))
28. )
29. (defun kdub:maxxy (pointlist)
30.   (list (kdub:maxx pointlist) (kdub:maxy pointlist))
31. )
32.  
33. ;;; min XYZ max XYZ
34. (defun kdub:minxyz (pointlist)
35.   (list (kdub:minx pointlist) (kdub:miny pointlist) (kdub:minz pointlist))
36. )
37. (defun kdub:maxxyz (pointlist)
38.   (list (kdub:maxx pointlist) (kdub:maxy pointlist) (kdub:maxz pointlist))
39. )
40.  
41.  
42.  

( kdub:maxxy columndata)  ;;->> (300 350)

[HasanCAD]

the lisp create this view (right side) and want update the code to create new raw.
So I want to get maximum of column length to copy objects and avoiding overlaping of objects.

[Kerry]

In that case your original post is incorrect. You will need to collect all the data before trying to draw the sections.

Just pass the datalist :
(setq maxLength ( kdub:maxy columndata)  )  ;; returns the maximum Y value from the list of lists.