Topic: Help List

[velasquez]

I need help for a problem with lists:

I have:
list1: ->

Code: [Select]

(setq list1 (list '("1" "testA") '("2" "testB") '("3" "testC")))and
list2: ->

Code: [Select]

(setq list2 (list '("testA" "nononno") '("testB" "vcvcvcv") '("testC" "nmnmnmn") '("nonono" "xccxcxc") '("xxxxxx" "jhjhjhjj")))I need to get list3 ->

Code: [Select]

'(("1" "teste
A" "aaaaaa") ("2" "testB" "vcvcvcv") ("3" "testC" "nmnmnmn") ("" "nonono" "xccxcxc") ("" "xxxxxx" "jhjhjhjj"))
Can anyone help me?

Thanks

[Lee Mac]

Quick one:

Code - Auto/Visual Lisp: [Select]

1. (defun foo ( l1 l2 )
2.     (setq l1 (mapcar 'reverse l1))
3.     (mapcar '(lambda ( x / a ) (if (setq a (assoc (car x) l1)) (reverse (cons (cadr x) a)) (cons "" x))) l2)
4. )

Code - Auto/Visual Lisp: [Select]

1. _$ (foo list1 list2)
2. (("1" "testA" "nononno") ("2" "testB" "vcvcvcv") ("3" "testC" "nmnmnmn") ("" "nonono" "xccxcxc") ("" "xxxxxx" "jhjhjhjj"))

Actually, this is slightly shorter:

Code - Auto/Visual Lisp: [Select]

1. (defun foo ( l1 l2 )
2.     (setq l1 (mapcar 'reverse l1))
3.     (mapcar '(lambda ( x / a ) (if (setq a (assoc (car x) l1)) (cons (cadr a) x) (cons "" x))) l2)
4. )

[velasquez]

Thank you Lee
Your help was very important again.

[Lee Mac]

You're welcome velasquez 

[Lee Mac]

Another, recursive variation (slow):

Code - Auto/Visual Lisp: [Select]

1. (defun foo ( a b )
2.     (if b (cons (bar (car b) a) (foo a (cdr b))))
3. )
4. (defun bar ( x l )
5.     (cond
6.         (   (null l) (cons "" x))
7.         (   (= (cadar l) (car x)) (cons (caar l) x))
8.         (   (bar x (cdr l)))
9.     )
10. )

Code - Auto/Visual Lisp: [Select]

1. _$ (foo list1 list2)
2. (("1" "testA" "nononno") ("2" "testB" "vcvcvcv") ("3" "testC" "nmnmnmn") ("" "nonono" "xccxcxc") ("" "xxxxxx" "jhjhjhjj"))

[David Bethel]

or a little simpler way would:

Code - Auto/Visual Lisp: [Select]

1. (setq list3 nil)
2. (foreach a list1
3.   (setq list3 (cons (list (car a)
4.                           (cadr a)
5.                           (cadr (assoc (cadr a) list2))) list3)))
6. (setq list3 (reverse list3))
7.  

No error checking though which I would recommend  -David

[Lee Mac]

or a little simpler way would:

Code - Auto/Visual Lisp: [Select]

1. (setq list3 nil)
2. (foreach a list1
3.   (setq list3 (cons (list (car a)
4.                           (cadr a)
5.                           (cadr (assoc (cadr a) list2))) list3)))
6. (setq list3 (reverse list3))
7.  

What about these items David:

Code - Auto/Visual Lisp: [Select]

1. ("" "nonono" "xccxcxc") ("" "xxxxxx" "jhjhjhjj")

[David Bethel]

What about these items David:

Code - Auto/Visual Lisp: [Select]

1. ("" "nonono" "xccxcxc") ("" "xxxxxx" "jhjhjhjj")

Like I said  it needs error checking.  I don't believe there would be any correct answer to your scenario.  My $0.02  -David

[Lee Mac]

What about these items David:

Code - Auto/Visual Lisp: [Select]

1. ("" "nonono" "xccxcxc") ("" "xxxxxx" "jhjhjhjj")

Like I said  it needs error checking.  I don't believe there would be any correct answer to your scenario.  My $0.02  -David

I'm just going by the result requested by the OP.

[irneb]

Just a question: Are the 2 lists always in the same order? If so a slightly faster version:

Code - Auto/Visual Lisp: [Select]

1. (defun combine (L1 L2 / L3)
2.   (setq L3 L2)
3.   (append (mapcar '(lambda (a b) (setq L3 (cdr L3)) (cons (car a) b))) L1 L2)
4.           (mapcar '(lambda (c) (cons "" c)) L3)))

Else you'll need the assoc to extract the correct item from either L1 or L2 (as the others' are doing).

BTW, is the 2nd list always longer (or same length) as the first or could the 1st list be longer? If so how should the result then look?

[velasquez]

You're welcome velasquez 

Hi Lee,
I modified your function foo and got the list3 as follows:

Code: [Select]

(defun LM:foo+ (l1 l2)
  (setq l1 (mapcar 'reverse l1))
  (mapcar '(lambda (x / a)
             (if (setq a (assoc (car x) l1))
               (subst (cadr a) (car x) x)
               (subst "" (car x) x)
             ) ;_ fim de if
           ) ;_ fim de lambda
          l2
  ) ;_ fim de mapcar
) ;_ fim de defun


Code: [Select]

(setq list1 '(("1" "SG_1_TBLUTOP_D90_L2000") ("2" "SG_3_CP90FB-BLUTOP10PECB_D90") ("3" "SG_1_CC90B-BLUTOPPECB_D90")))
(setq list2 '(("SG_1_CC90B-BLUTOPPECB_D90" "CC90B-BLUTOPPECB;Curva 90° com bolsas JE - Sistema Blutop;90;0;0;0") ("SG_3_CP90FB-BLUTOP10PECB_D90" "CP90FB-BLUTOP10/16PECB;Curva 90° com pé, bolsa e flange JE - Sistema Blutop;80;80;10;0") ("SG_1_TBLUTOP_D90_L2000" "TBLUTOP;Tubo ponta e bolsa JE - Sistema Blutop;90;0;0;2000") ("SG_1_KB-BLUTOPPECB_D90" "KB-BLUTOPPECB;Cap JE - Sistema Blutop;90;0;0;0") ("SG_1_KB-BLUTOPTIPECB_D160" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0")))
 I got the list3 with this order:

Code: [Select]

_$ (setq list3 (LM:FOO+ list1 list2))
(("3" "CC90B-BLUTOPPECB;Curva 90° com bolsas JE - Sistema Blutop;90;0;0;0") ("2" "CP90FB-BLUTOP10/16PECB;Curva 90° com pé, bolsa e flange JE - Sistema Blutop;80;80;10;0") ("1" "TBLUTOP;Tubo ponta e bolsa JE - Sistema Blutop;90;0;0;2000") ("" "KB-BLUTOPPECB;Cap JE - Sistema Blutop;90;0;0;0") ("" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0"))
_$
You can help me sort the list as list4:?

Code: [Select]

'(("1" "TBLUTOP;Tubo ponta e bolsa JE - Sistema Blutop;90;0;0;2000")
  ("2" "CP90FB-BLUTOP10/16PECB;Curva 90° com pé, bolsa e flange JE - Sistema Blutop;80;80;10;0")
  ("3" "CC90B-BLUTOPPECB;Curva 90° com bolsas JE - Sistema Blutop;90;0;0;0")
  ("" "KB-BLUTOPPECB;Cap JE - Sistema Blutop;90;0;0;0")
  ("" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0"))

Thanks for the time and the help of all.

[Lee Mac]

Quick one:

Code - Auto/Visual Lisp: [Select]

1. (setq l
2.    '(
3.         ("3" "CC90B-BLUTOPPECB;Curva 90° com bolsas JE - Sistema Blutop;90;0;0;0")
4.         ("2" "CP90FB-BLUTOP10/16PECB;Curva 90° com pé, bolsa e flange JE - Sistema Blutop;80;80;10;0")
5.         ("1" "TBLUTOP;Tubo ponta e bolsa JE - Sistema Blutop;90;0;0;2000")
6.         ("" "KB-BLUTOPPECB;Cap JE - Sistema Blutop;90;0;0;0")
7.         ("" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0")
8.     )
9. )
10.  
11. (vl-sort l '(lambda ( a b ) (if (and (/= "" (car a)) (/= "" (car b))) (< (atoi (car a)) (atoi (car b))))))

[velasquez]

Quick one:

Code - Auto/Visual Lisp: [Select]

1. (setq l
2.    '(
3.         ("3" "CC90B-BLUTOPPECB;Curva 90° com bolsas JE - Sistema Blutop;90;0;0;0")
4.         ("2" "CP90FB-BLUTOP10/16PECB;Curva 90° com pé, bolsa e flange JE - Sistema Blutop;80;80;10;0")
5.         ("1" "TBLUTOP;Tubo ponta e bolsa JE - Sistema Blutop;90;0;0;2000")
6.         ("" "KB-BLUTOPPECB;Cap JE - Sistema Blutop;90;0;0;0")
7.         ("" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0")
8.     )
9. )
10.  
11. (vl-sort l '(lambda ( a b ) (if (and (/= "" (car a)) (/= "" (car b))) (< (atoi (car a)) (atoi (car b))))))

Perfect Lee.
Thanks

[velasquez]

I'm trying to better understand the mapcar and lambda functions.
I got a result with foreach but I can not say with mapcar.

Code: [Select]

;;;MyList -> (<Entity name: 7ffffc08530> <Entity name: 7ffffc05960> <Entity name: 7ffffc05440> ...)
(foreach JoyItem MyList
  (if (setq JoyTemp (dxf 1000 (JoyGetXdata (vlax-ename->vla-object JoyItem) "DuctilCAD_2D")))
    (setq JoyData (cons (list (dxf 2 (entget JoyItem)) JoyTemp) JoyData))
  ) ;_ fim de if
) ;_ fim de foreach

;;;returned list -> '(("SG_1_TNATJGS_D80_#D80" "TNATJGS;Tê com bolsas e junta elástica JGS - Linha Natural;80;80;0;0")
  ("SG_1_KB-BLUTOPTIPECB_D160" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0")
  ("SG_1_TNATJGS_D80_#D80" "TNATJGS;Tê com bolsas e junta elástica JGS - Linha Natural;80;80;0;0")
  ("SG_1_KB-BLUTOPTIPECB_D160" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0")
)
My question in this case is better to work with foreach?
I need to learn more about mapcar.

Thanks

[irneb]

I'm trying to better understand the mapcar and lambda functions.

Perhaps these threads can help:

• http://www.theswamp.org/index.php?topic=41830.5
• http://www.cadtutor.net/forum/showthread.php?80672-lambda-function-mapcar-apply-foreach-explained

[velasquez]

Quick one:

Code - Auto/Visual Lisp: [Select]

1. (setq l
2.    '(
3.         ("3" "CC90B-BLUTOPPECB;Curva 90° com bolsas JE - Sistema Blutop;90;0;0;0")
4.         ("2" "CP90FB-BLUTOP10/16PECB;Curva 90° com pé, bolsa e flange JE - Sistema Blutop;80;80;10;0")
5.         ("1" "TBLUTOP;Tubo ponta e bolsa JE - Sistema Blutop;90;0;0;2000")
6.         ("" "KB-BLUTOPPECB;Cap JE - Sistema Blutop;90;0;0;0")
7.         ("" "KB-BLUTOPTIPECB;Cap JTI - Sistema Blutop;160;0;0;0")
8.     )
9. )
10.  
11. (vl-sort l '(lambda ( a b ) (if (and (/= "" (car a)) (/= "" (car b))) (< (atoi (car a)) (atoi (car b))))))

I'm trying to sort a list by its second element.
The first element is always variable.
Laboring with the result vl-sort not working.
Lee Please can you tell me what is wrong?

Code: [Select]

(setq l '(
          ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
          ("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
          ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
          ("C" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
          ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0")
          ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
          ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000")
          ("5" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
          ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
         ) ;_ fim de list
)
(vl-sort l '(lambda (a b) (eq (cadr a) (cadr b))))


[ronjonp]

Try this:

Code: [Select]

(vl-sort l '(lambda (a b) (< (cadr a) (cadr b))))

[velasquez]

Try this:

Code: [Select]

(vl-sort l '(lambda (a b) (< (cadr a) (cadr b))))

Thanks ronjonp I used your suggestion in a function to count the items in a list.
Can you tell me how I can improve my way?

Code: [Select]

(defun JoyFinalizaLista (lst / n ent wrt)
  (while (> (length lst) 0)
    (setq ent (car lst)
          n   0
    ) ;_ fim de setq
    (while (and (car lst)
                (eq (cadr (car lst)) (cadr ent))
           ) ;_ fim de and
      (setq n (1+ n))
      (setq lst (cdr lst))
    ) ;_ fim de while
    (setq wrt (cons (append ent (list n)) wrt))
  ) ;_ fim de while
  wrt
)

;;;Result -> '(("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0" 3) ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0" 2) ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000" 1) ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0" 1) ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0" 1) ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0" 1))



[CAB]

Did you try this as suggested by Ron?

Code: [Select]

(defun JoyFinalizaLista (l)
  (vl-sort l '(lambda (a b) (< (cadr a) (cadr b))))
)

[velasquez]

Did you try this as suggested by Ron?

Code: [Select]

(defun JoyFinalizaLista (l)
  (vl-sort l '(lambda (a b) (< (cadr a) (cadr b))))
)

Hello CAB,
Ron's suggestion worked perfectly.
I failed my goal when I showed her.
My question is the way that I showed to count the elements in the list can be improved.
I corrected my code.

Code: [Select]

(setq l '(
          ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
          ("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
          ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
          ("C" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
          ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0")
          ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000")
          ("5" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
          ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
          ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
         ) ;_ fim de list
)
;;;
(defun JoyFinalizaLista (lst / lst n ent wrt)
;;;BY RONJONP
(setq lst (vl-sort lst '(lambda (a b) (< (cadr a) (cadr b)))))
;;;
  (while (> (length lst) 0)
    (setq ent (car lst)
          n   0
    ) ;_ fim de setq
    (while (and (car lst)
                (eq (cadr (car lst)) (cadr ent))
           ) ;_ fim de and
      (setq n (1+ n))
      (setq lst (cdr lst))
    ) ;_ fim de while
    (setq wrt (cons (append ent (list n)) wrt))
  ) ;_ fim de while
  wrt
)
;;;TEST
_$ (JoyFinalizaLista l)
(("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0" 3) ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0" 2) ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000" 1) ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0" 1) ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0" 1) ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0" 1))
_$



[CAB]

I don't understand what you are counting?

[velasquez]

I don't understand what you are counting?

I'm counting the second item of each list (cadr ..) and adding the value at the end of the list.
I used the idea of ​​Ron to sort the list.
Please exeucte my code and observe the returned list.

[ronjonp]

Give this a try:

Code: [Select]

(setq
  l '(("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
      ("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
      ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
      ("C" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
      ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0")
      ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
      ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000")
      ("5" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
      ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
     ) ;_ fim de list
)

(mapcar
  (function
    (lambda (x)
      (append
x
(list (length (vl-remove-if-not (function (lambda (txt) (= (cadr x) txt))) (mapcar 'cadr l)))
)
      )
    )
  )
  l
)

[velasquez]

Give this a try:

Code: [Select]

(setq
  l '(("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
      ("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
      ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0")
      ("C" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
      ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0")
      ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
      ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000")
      ("5" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0")
      ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0")
     ) ;_ fim de list
)

(mapcar
  (function
    (lambda (x)
      (append
x
(list (length (vl-remove-if-not (function (lambda (txt) (= (cadr x) txt))) (mapcar 'cadr l)))
)
      )
    )
  )
  l
)

Hi Ron,
Your code did the count I need.
But the list of return must be in the format below.
I'll study it.
Thank you very much.

Code: [Select]

(finalList '(("-" "VBFWCV10" "Válvula borboleta com flanges e volante na posição 1" "200" "0" "10" "0" 3) ("-" "TNATJGS" "Tê com bolsas e junta elástica JGS - Linha Natural" "80" "80" "0" "0" 2) ("-" "TBLUTOP" "Tubo ponta e bolsa JE - Sistema Blutop" "90" "0" "0" "2000" 1) ("-" "KB-BLUTOPTIPECB" "Cap JTI - Sistema Blutop" "160" "0" "0" "0" 1) ("-" "CC90B-BLUTOPPECB" "Curva 90° com bolsas JE - Sistema Blutop" "90" "0" "0" "0" 1) ("-" "CC22B-BLUTOPPECB" "Curva 22°30' com bolsas JE - Sistema Blutop" "90" "0" "0" "0" 1)))


[ronjonp]

Give this a whirl:

Code: [Select]

(while (setq line (car l))
  (setq tmp (vl-remove-if-not (function (lambda (x) (= (cadr line) (cadr x)))) l))
  (setq result (cons (append line (list (length tmp))) result))
  (mapcar (function (lambda (x) (setq l (vl-remove x l)))) tmp)
)
(setq result (vl-sort result '(lambda (a b) (< (cadr a) (cadr b)))))

[Lee Mac]

Another variation:

Code - Auto/Visual Lisp: [Select]

1. (defun foo ( l / a r )
2.     (foreach x l
3.         (if (setq a (assoc (cadr x) r))
4.             (setq r (subst (subst (1+ (last a)) (last a) a) a r))
5.             (setq r (cons  (append (cons (cadr x) x) '(1)) r))
6.         )
7.     )
8.     (vl-sort (mapcar 'cdr r) '(lambda (a b) (> (cadr a) (cadr b))))
9. )

[Lee Mac]

And another:

Code - Auto/Visual Lisp: [Select]

1. (defun foo ( l / n r x )
2.     (while l
3.         (setq x (car l)
4.               n (length l)
5.               l (vl-remove-if '(lambda ( y ) (= (cadr x) (cadr y))) (cdr l))
6.               r (cons (append x (list (- n (length l)))) r)
7.         )
8.     )
9.     (vl-sort r '(lambda (a b) (> (cadr a) (cadr b))))
10. )

[velasquez]

Again your help was very important.
Thanks for the time you dedicated to my problems.