Topic: open drawings list box

[pedroantonio]

is it possible to manage open drawings with a lost box lisp? if i have 10 open drawings in my autocad i have to go to window menu and select which drawing i want to use.Is it possible to display the names of the open drawings in a list box with an OK button and sellect any time the drawings i whant to use ?

Sorry for my bad English

Thanks ....

[Kerry]

On the Main menu Bar ; Select window. ( between Modify and Help on my menu)
If the file you want is not in the list, select More Windows ...

or Alt+W+M

[Lee Mac]

Or use the various window controls located on the User Interface panel of the View tab:

[ronjonp]

Or cycle with ctrl+tab.

[CAB]

I cycle 
Program the mouse side buttons for forward & back one drawing.

[pedroantonio]

Thanks

[dgorsman]

2015 has extra tabs, similar to layouts, but for drawing files.

[pedroantonio]

i am using Autocad 2010

[V-Man]

Try....

http://autodesk.blogs.com/between_the_lines/2009/04/autocad-free-bonus-tool-drawing-tabs-mditabs.html

[kraz]

Maybe, You want this one...
since acad 2012? or 2013, autocad has filetab function.

I had used bellow arx tool and is very nice...

download and rename the file name:: "iDwgTab2.0.0.6.renameTozip -> iDwgTab2.0.0.6.zip"

http://pds25.egloos.com/pds/201405/16/51/iDwgTab2.0.0.6.renameTozip

[CAB]

KRAZ
Bad link for me, I get
403 - Forbidden

[kraz]

KRAZ
Bad link for me, I get
403 - Forbidden

hmm...
attached the file...
this arx from http://arx119.egloos.com/

[Tharwat]

Had few minutes today to write this routine and saved it to my Toolbox . 

Code - Auto/Visual Lisp: [Select]

1. (defun c:dwgs (/ *error* f id lst v dlg nm i obj cn w)
2.   ;;    Tharwat 16.June.2014            ;;
3.   ;; Cycle through drawings             ;;
4.   (defun *error* (msg)
5.     (if (and dlg (setq dlg (findfile dlg)))
6.       (vl-file-delete dlg)
7.     )
8.     (if (wcmatch (strcase msg) "*BREAK*,*CANCEL*,*EXIT*")
9.       (princ msg)
10.       (princ (strcat "\n ** Error : " msg " **"))
11.     )
12.   )
13.   (setq cn
14.          (vla-get-fullname
15.            (vla-get-activedocument (setq obj (vlax-get-acad-object)))
16.          )
17.   )
18.   (vlax-for dwg (vla-get-documents obj)
19.     (if (and (/= "" (setq nm (vla-get-fullname dwg)))
20.              (not (eq cn nm))
21.         )
22.       (setq lst (cons nm lst))
23.     )
24.   )
25.   (if lst
26.     (progn
27.       (setq w (apply 'max (mapcar '(lambda (x) (strlen x)) lst)))
28.       (if (and (setq dlg (vl-filename-mktemp nil nil ".dcl"))
29.                (setq f (open dlg "w"))
30.           )
31.         (progn
32.           (write-line
33.             (strcat
34.               "test : dialog { label = \"All opened drawings\"; width ="
35.               (if (> w 90)
36.                 "90"
37.                 (itoa (+ 2 w))
38.               )
39.               ";"
40.               ": list_box { label = \"Opened drawings\"; key = \"dwgs\"; height = 16;}"
41.               ": row { alignment = centered; fixed_width = true;"
42.               ": button { label = \"Okay\"; key = \"oki\"; is_default = true; width = 10;}"
43.               ": button { label = \"Exit\"; key = \"esc\"; is_cancel = true; width = 10; }}}"
44.             )
45.             f
46.           )
47.           (close f)
48.         )
49.         (alert "Can't load the temporary file <!>")
50.       )
51.       (if (not (new_dialog
52.                  "test"
53.                  (setq id (load_dialog dlg))
54.                  ""
55.                )
56.           )
57.         (progn (if (>= id 0)
58.                  (unload_dialog id)
59.                )
60.                (if (and dlg (setq dlg (findfile dlg)))
61.                  (vl-file-delete dlg)
62.                )
63.         )
64.         (progn
65.           (start_list "dwgs")
66.           (mapcar 'add_list lst)
67.           (end_list)
68.           (set_tile "dwgs" "0")
69.           (action_tile
70.             "oki"
71.             "(setq i (atoi (get_tile \"dwgs\")))(done_dialog)"
72.           )
73.           (action_tile "esc" "(done_dialog)")
74.           (start_dialog)
75.           (unload_dialog id)
76.           (vl-file-delete dlg)
77.         )
78.       )
79.       (if i
80.         (vlax-for x (vla-get-documents obj)
81.           (if (eq (vla-get-fullname x) (nth i lst))
82.             (vla-put-windowstate x acMax)
83.             (vla-put-windowstate x acMin)
84.           )
85.         )
86.       )
87.     )
88.     (alert "No opened named drawings to cycle through !!")
89.   )
90.   (princ)
91. )
92. (vl-load-com)
93.  

[GDF]

Nice one Tharwat. This one by:

;;; Written By Peter Jamtgaard Copyright April 2003
;;; Activate drawing dialog control program that uses a tree structure for
;;; display of the filenames

I like the tree structure. I will need to get permission to post his routine. The routine uses Visual Basic which is no longer installed with AutoCAD.

[Tharwat]

Nice one Tharwat.

Thank you for the feed back GDF and I am happy that you like it