Topic: Missing in a sequence

[velasquez]

Can anyone tell me how to find the first value that is missing in a sequence from the list below?

Code: [Select]

'("1" "2" "3" "?" "7" "8")

Thanks,
velasquez

[ElpanovEvgeniy]

Code - Auto/Visual Lisp: [Select]

1. (setq l'("1" "2" "3" "?" "7" "8"))
2. (car(acad_strlsort l))

[velasquez]

Code - Auto/Visual Lisp: [Select]

1. (setq l'("1" "2" "3" "?" "7" "8"))
2. (car(acad_strlsort l))

Sorry ElpanovEvgeniy,

I used the symbol "?" wrongly.
What I need to figure out is the amount to complete the sequence.
For example "4"

Thanks

[ElpanovEvgeniy]

First I did not understand the task...

Code - Auto/Visual Lisp: [Select]

1. (defun test (l / f)
2.   ;; (test '("1" "2" "3" "?" "7" "8"))
3.   (defun f (a b)
4.     ;; test sequence function for '("1" "2" "3" "?" "7" "8")
5.     (if (/= (1+ (atoi a)) (atoi b))
6.       (itoa (1+ (atoi a)))
7.     )
8.   )
9.   (cond ((not (cdr l)) nil)
10.         ((f (car l) (cadr l)))
11.         ((test (cdr l)))
12.   )
13. )

[dgorsman]

First you need to identify if the sequence is regular or irregular.  The former can be distilled into a function for generating successive numbers.  The latter cannot so will require some sort of lookup table.  In your given example, the sequence is irregular since you only specify one missing entry.  For it to be regular there would have to be multiple missing entries and an identified function.

[Lee Mac]

Another couple:

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (vl-some '(lambda ( a b ) (if (/= (1+ (atoi a)) (atoi b)) (itoa (1+ (atoi a))))) l (cdr l))
3. )

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (setq l (mapcar 'atoi l))
3.     (vl-some '(lambda ( a b ) (if (/= a b) (itoa a))) (mapcar '1+ l) (cdr l))
4. )

Code - Auto/Visual Lisp: [Select]

1. _$ (f '("1" "2" "3" "?" "7" "8"))
2. "4"

And another way to write Evgeniy's:

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (if (cadr l)
3.         (if (= (1+ (atoi (car l))) (atoi (cadr l)))
4.             (f (cdr l))
5.             (itoa (1+ (atoi (car l))))
6.         )
7.     )
8. )

Or a generalised function:

Code - Auto/Visual Lisp: [Select]

1. (defun missing ( l f )
2.     (vl-some '(lambda ( a b / c ) (if (/= b (setq c (f a))) c)) l (cdr l))
3. )
4. (missing '("1" "2" "3" "?" "7" "8") (lambda ( x ) (itoa (1+ (atoi x)))))

[velasquez]

Many thanks for all the answers.