Topic: Help with lisp for automatically saving multiple paperspace viewport layerstates

[Pad]

Hi

I often receive drawings now where the model space has every drawing sheet layer turned on and it is very difficult to isolate the information I require.
I have to go into the particular paperspace layout which has the information I require, make the viewport active and then save the layerstate.  I can then go into model space and apply this layerstate.
Is there a lisp already or could somebody run through the steps I would need to do to automate this process please?
I would like the current model space layerstate saved and then each paperspace layout viewport layerstate saved using the layout name.   I hope that makes sense.

Thanks
Pads

[CAB]

Did you check to see if the previous user is using Express Tools Layer States?
That is what I use. 

[CAB]

This will get the layer states in a VP.
http://www.theswamp.org/index.php?topic=4002.0

[Pad]

Hi Cab.

Yeah it looks like they must delete them before passing the drawing on.  There are not normally any layerstates saved either by cmd line 'layerstates'  or via the layer states manager.
It looks like express tools has removed LMAN, but 2009 (which I am on) will detect LMAN express tools layerstates and convert them to autocad layerstates.

LMAN
--------------------------------------------------------------------------------

Layer Properties Manager Dialog BoxLMAN, -LMAN, LMANMODE, and -LMANMODE are no longer part of the Express Tools. Use the Layer States Manager dialog box in AutoCAD to achieve the functionality of these commands. For more information about the Layer States Manager dialog box, see the AutoCAD Help system. Also see LAYERSTATE command in the Command Reference.
Note: The LMAN command now invokes the LAYERSTATE command.


Thanks for the link, I've given them a go, but havent been able to figure anything out!
Cheers
P

[CAB]

I threw this together quickly and borrowed some code from Kerry & Ronjonp.
It should work, did with my short test. Let me know.

Code - Auto/Visual Lisp: [Select]

1. ;;  CAB 07.02.2014
2. ;;  Create layer states from each viewport
3. ;;  Ignore VP with no frozen layers
4.  
5. (defun c:vp2ls() (c:vp2layerStates))
6. (defun c:vp2layerStates (/ a b c tab ll ln ss layerlist layerdict ls_manager
7.                          clayname obj newlsn lsn nam)
8.  
9.   ;;  unlock and thaw all layers
10.   (defun layerprep (doc / lays lay)
11.     (setq lays (vla-get-layers doc))
12.     (vlax-for lay lays
13.       (if (eq (vla-get-lock lay) :vlax-true)
14.         (vla-put-lock lay :vlax-false) )
15.       (if (eq (vla-get-freeze lay) :vlax-true)
16.         (vla-put-freeze lay :vlax-false))
17.     )
18.   )
19.  
20.   ;;  freeze a list of layers
21.   (defun freezelayers (ll doc / lays lay)
22.     (setq lays (vla-get-layers doc))
23.     (vlax-for lay lays
24.       (if (vl-position (vla-get-name lay) ll)
25.         (vla-put-freeze lay :vlax-true)))
26.   )
27.  
28.  
29.   ;;  save a layer state from current layers
30.   (defun ls_save (name lsm)
31.     (vl-catch-all-error-p (vl-catch-all-apply 'vla-delete (list lsm name))) ; delete the LayerState if it exist
32.     ;; Save the Named LayerState
33.     (if (vl-catch-all-error-p (vl-catch-all-apply 'vla-save (list lsm name 511))) ; << acLsAll replaced with 511 kwb
34.       (strcat "Error:" name)
35.       name
36.     )
37.   )
38.  
39.   (defun LayerMake (LName LColor LType)
40.     (if (not(tblsearch "LAYER" LName))
41.       (entmakex (list
42.                  '(0 . "LAYER")
43.                  '(100 . "AcDbSymbolTableRecord")
44.                  '(100 . "AcDbLayerTableRecord")
45.                  (cons 2  LName) ;layer name
46.                  (cons 6  (if (tblobjname "ltype" ltype) ltype  "Continuous")) ;linetype
47.                  (cons 62  LColor) ;layer color
48.                  '(70 . 0) ; on, unlocked, thawed
49.                 )
50.       )
51.     )
52.   )
53.  
54.  
55.   (defun getstatenames ( doc / nams dict obj)
56.     (setq dict (vla-getextensiondictionary (vla-get-layers doc)))
57.     (if (not (vl-catch-all-error-p
58.             (setq obj (vl-catch-all-apply
59.                         (function (lambda () (vla-item dict "ACAD_LAYERSTATES")))))))
60.       (vlax-for n obj
61.         (setq nams (cons (strcase (vla-get-name n)) nams)))
62.     )
63.     (setq dict nil)
64.     nams
65.   )
66.  
67.  
68.   (setq *acadapp   (vlax-get-acad-object)
69.         *activedoc (vla-get-activedocument *acadapp)
70.         layerdict  (vla-getextensiondictionary (vla-get-layers *activedoc))
71.         ls_manager (vla-getinterfaceobject *acadapp
72.                      (strcat "AutoCAD.AcadLayerStateManager." (substr (getvar "acadver") 1 2)))
73.   )
74.   (vla-setdatabase ls_manager (vla-get-database *activedoc))
75.  
76.  
77.   (setq clayname  (getvar "clayer"))
78.   (LayerMake "Tmp9z1x" 1 "x") ; temp layer to make current
79.   (setvar "clayer" "Tmp9z1x")
80.  
81.   (setvar "ctab" "Model")
82.   (ls_save "CurrentStateFound" ls_manager) ; save current state
83.  
84.   (if (setq ss (ssget "x" '((0 . "VIEWPORT"))))
85.     (foreach tab (mapcar 'cadr (ssnamex ss))
86.       (setq a         (cdr (assoc 330 (entget tab)))
87.             b         (cdr (assoc 340 (entget a)))
88.             c         (cdr (assoc 331 (entget b)))
89.             ln        (cdr (assoc 410 (entget tab))) ; Layout Name
90.             layerlist nil
91.             lsn       (strcat ln "-vp" (itoa (cdr (assoc 69 (entget tab)))))
92.       )
93.  
94.       (if (and (not (equal c tab)) (not (vl-position lsn newlsn)))
95.         (progn
96.           (layerprep *activedoc) ; thaw all
97.           (foreach i (entget tab)
98.             (if (and (= (type (setq ll (cdr i))) 'ename)
99.                      (setq ll (entget ll))
100.                      (= (cdr (assoc 0 ll)) "LAYER")
101.                 )
102.               (setq layerlist (cons (cdr (assoc 2 ll)) layerlist))
103.             )
104.           )
105.           (if layerlist
106.             (progn
107.               (freezelayers layerlist *activedoc)
108.               (setq newlsn
109.                      (cons (strcat (ls_save lsn ls_manager) "  " (itoa (length layerList)))
110.                            newlsn))
111.             )
112.           )
113.         )
114.       )
115.  
116.     ) ; end foreach
117.   )
118.  
119.  
120.   (if (vl-position (setq nam (strcase "CurrentStateFound")) (getstatenames *activedoc))
121.     (progn
122.       (vl-catch-all-apply 'vla-restore (list ls_manager nam))
123.       ;; (vl-catch-all-apply 'vla-delete (list ls_manager nam)) ; in case you want to delete the temp state
124.       (vl-cmdf "_.regenall")
125.     )
126.   )
127.   (setvar "clayer" clayname)
128.   (if (setq obj (vla-item (vla-get-layers *activedoc) "Tmp9z1x"))
129.     (vla-delete obj)
130.   )
131.   (princ "\n Layer States")
132.   (if newlsn (mapcar 'print newlsn))
133.   (princ)
134. )

[Pad]

That works brilliantly, thank you very much.

Not sure why this is an error though:
Command: VP2LS
no function definition: VP2LAYERSTATES
as the command 'vp2layerStates' works fine, it's a bit strange.

I have added:
(Command "tilemode" "1")
(COMMAND "-LAYER" "A" "S" "metrixmodel" "" "" "")
to the top of the lisp to save the layerstate of the modelspace tab.  It seems to do the trick.

This is great and will save me a lot of messing around, especially with the clients never ending revisions..

Cheers
P

[tombu]

If you remove the "C:" from line 6 vp2layerStates should be a function.  On the command line you could use either vp2ls or (vp2layerStates).  (vp2layerStates) could also be called from another lisp.

[Pad]

of course, thanks!

[CAB]

Oops should read

Code: [Select]

(defun c:vp2ls() (c:vp2layerStates))
(defun c:vp2layerStates (/ a b c tab ll ln ss layerlist layerdict ls_manager
                         clayname obj newlsn lsn)So you can call it from the command line with both names.

Thanks

[Pad]

Thats it.

Thanks CAB.

Do you think there is any improvement I should make to this bit I added:
(Command "tilemode" "1")
(COMMAND "-LAYER" "A" "S" "00-metrixmodel" "" "" "")
Should I add a check to make sure the layerstate doesn't already exist or anything like that?
Thanks again.

[CAB]

In the code line 90 saves the current model space layer state as

"TEMPstate"

but line 131 restores it and 132 deletes it

You can use your own name and comment out lines 129-135

[Pad]

Thanks CAB.  I'll look into that.

P

[CAB]

Updated the code. It saves the current layer state & restores it but does not delete the new state.

[Pad]

Ah nice one! Thank you.