Topic: when error, I want Restore the "textstyle"

[liuhaixin88]

This code is restore the layer

Code: [Select]

(defun c:xxx(/ *error* cl  )

Code: [Select]

(defun *error* (msg)
    (redraw)
    (if cl
      (setvar 'clayer cl)
    )
    (if (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
      (princ msg)
      (princ (strcat "\n** Error: " msg " **"))
    )
  )
I want restore the layer and textstyle together, how to modify?

[ronjonp]

Try something like this:

Code: [Select]

(setq vars (mapcar '(lambda (x) (cons x (getvar x))) '("clayer" "textstyle")))
(defun *error* (msg)
  ;; Reset variables
  (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
  (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
    (princ (strcat "\nError: " msg))
  )
  (princ)
)

[liuhaixin88]

Modify it like this ? ok?

Code: [Select]

(defun c:xxx(/ *error* cl ts )

Code: [Select]

(defun *error* (msg)
    (redraw)
    (if cl
      (setvar 'clayer cl)
    )
    (if ts
      (setvar 'TEXTSTYLE ts)
    )
    (if (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
      (princ msg)
      (princ (strcat "\n** Error: " msg " **"))
    )
  )

[liuhaixin88]

Try something like this:

Code: [Select]

(setq vars (mapcar '(lambda (x) (cons x (getvar x))) '("clayer" "textstyle")))
(defun *error* (msg)
  ;; Reset variables
  (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
  (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
    (princ (strcat "\nError: " msg))
  )
  (princ)
)

Hi, ronjonp ,
Thank you
At the end of  routine(normal finish) ,how to restore ?

[ronjonp]

(mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)

[liuhaixin88]

(mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)

OK! is good ! thank you!

[liuhaixin88]

Try something like this:

Code: [Select]

(setq vars (mapcar '(lambda (x) (cons x (getvar x))) '("clayer" "textstyle")))
(defun *error* (msg)
  ;; Reset variables
  (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
  (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
    (princ (strcat "\nError: " msg))
  )
  (princ)
)

Hi ,ronjonp,
Your routine is good , can add in "osmode" ?

Lee's rountine

Code: [Select]

(defun c:test ( / *error* osm )
 
    (defun *error* ( msg )
        (if osm (setvar 'osmode osm))
        (if (not (member msg '("Function cancelled" "quit / exit abort")))
            (princ (strcat "\nError: " msg))
        )
        (princ)
    )

    (setq osm (getvar 'osmode))
    (setvar 'osmode 0)

    (rtos (getreal "\nPress Esc to exit, press Enter to force an error ..."))

    (setvar 'osmode osm)
    (princ)
)

[ronjonp]

You can add whatever other variables you want to this portion of the code:


'("clayer" "textstyle")


That's the beauty of it

[liuhaixin88]

You can add whatever other variables you want to this portion of the code:


'("clayer" "textstyle")


That's the beauty of it

This ?

Code: [Select]

(setq vars (mapcar '(lambda (x) (cons x (getvar x))) '("clayer" "textstyle" "osmode")))
(defun *error* (msg)
  ;; Reset variables
  (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
  (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
    (princ (strcat "\nError: " msg))
  )
  (princ)
)

[ronjonp]

Yes

[gile]

Hi,

To set and restore system variables, you can also the ai_sysvar function.
This function is available in AutoCAD since a while.
It's defined in acaddoc20XX.lsp (ai_utils.lsp or acad.mnl in older versions), so it's automatically loaded in each document.

;;; --- ai_sysvar ------------------------------------------
;;; Change system variable settings and save current settings
;;; (Note: used by *merr* to restore system settings on error.)
;;;
;;; The <vars> argument is used to...
;;;   restore previous settings (ai_sysvar NIL)
;;;   set a single sys'var (ai_sysvar  '("cmdecho" . 0))
;;;   set multiple sys'vars (ai_sysvar '(("cmdecho" . 0)("gridmode" . 0)))
;;;
;;; defun-q is needed by Visual Lisp for functions which redefine themselves.
;;; it is aliased to defun for seamless use with AutoLISP.

Anywhere in the code, you can call ai_sysvar to save the current value of one or more sysvar and set it a new value (or not).

Example:

Code - Auto/Visual Lisp: [Select]

1. ;; save and set "osmode" to 0
2. (ai_sysvar '("osmode" . 0))
3. ...
4. ;; save and set "orthomode" to 1 and only save "autosnap"
5. (ai_sysvar '(("orthomode" . 1) ("autosnap" . nil)))
6. ...
7. ;; restor all sysvars
8. (ai_sysvar nil)

<EDIT> I forgot to say, the implementation of ai_sysvar is quite interesting with the use of defun-q which allows to store the list of var names ans values within the function.

[liuhaixin88]

Hi,

To set and restore system variables, you can also the ai_sysvar function.
This function is available in AutoCAD since a while.
It's defined in acaddoc20XX.lsp (ai_utils.lsp or acad.mnl in older versions), so it's automatically loaded in each document.

;;; --- ai_sysvar ------------------------------------------
;;; Change system variable settings and save current settings
;;; (Note: used by *merr* to restore system settings on error.)
;;;
;;; The <vars> argument is used to...
;;;   restore previous settings (ai_sysvar NIL)
;;;   set a single sys'var (ai_sysvar  '("cmdecho" . 0))
;;;   set multiple sys'vars (ai_sysvar '(("cmdecho" . 0)("gridmode" . 0)))
;;;
;;; defun-q is needed by Visual Lisp for functions which redefine themselves.
;;; it is aliased to defun for seamless use with AutoLISP.

Anywhere in the code, you can call ai_sysvar to save the current value of one or more sysvar and set it a new value (or not).

Example:

Code - Auto/Visual Lisp: [Select]

1. ;; save and set "osmode" to 0
2. (ai_sysvar '("osmode" . 0))
3. ...
4. ;; save and set "orthomode" to 1 and only save "autosnap"
5. (ai_sysvar '(("orthomode" . 1) ("autosnap" . nil)))
6. ...
7. ;; restor all sysvars
8. (ai_sysvar nil)

<EDIT> I forgot to say, the implementation of ai_sysvar is quite interesting with the use of defun-q which allows to store the list of var names ans values within the function.

Thanks  gile, I can't understand. Can you give me a routine ? like ronjonp.

[liuhaixin88]

Yes

Hi, ronjonp , How are you!

If I want add "(command ".undo" "e")"  and "DIMSTYLE" to your function, how to do?

Code: [Select]

(setq vars (mapcar '(lambda (x) (cons x (getvar x))) '("clayer" "textstyle" "osmode")))
(defun *error* (msg)
  ;; Reset variables
  (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
  (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
    (princ (strcat "\nError: " msg))
  )
  (princ)
)

Code: [Select]

;;start;(command "_.undo" "be")
(defun _StartUndo (*DOC*)
  (_EndUndo *DOC*)
  (vla-StartUndoMark *DOC*)
)
;;end;(if (= 8 (logand (getvar "undoctl") 8)) (command "_.undo" "_e"))
(defun _EndUndo (*DOC*)
  (if (= 8 (logand 8 (getvar 'UNDOCTL)))
    (vla-EndUndoMark *DOC*)
  )
)

[reltro]

Hey People...

This is what I use, includes also a mechanism to undo all stuff done...

*error*-functions can also be nested

Code - Auto/Visual Lisp: [Select]

1. ;Note:
2. ;    *error* should not be localized!!!
3.  
4.  
5. (defun ini*error* (name sysvars / *doc*)
6.     (vla-startundomark (setq *doc* (vla-get-activedocument (vlax-get-acad-object))))
7.     (eval
8.         (list 'defun '*error* '(msg / )
9.             (list
10.                 (lambda (name prevErrorHandler SysVars *doc* currentcmdecho / )
11.                     (mapcar
12.                         'setvar
13.                         (mapcar 'car SysVars)
14.                         (mapcar 'cdr SysVars)
15.                     )
16.                     (vla-endundomark *doc*)
17.                     (setq *error* prevErrorHandler)
18.                     (if msg
19.                         (progn
20.                             (setvar 'cmdecho 0)
21.                             (command-s "_.undo" 1 "")
22.                             (setvar 'cmdecho currentcmdecho)
23.                            
24.                             (if (not (wcmatch msg "*EXIT*,*BREAK*,*CANCEL*"))
25.                                 (progn
26.                                     (princ "\n*** error ***\n")
27.                                     (princ (strcat "\t" name ": " (vl-princ-to-string msg) "\n"))
28.                                    
29.                                     (*error* msg)
30.                                     (princ)
31.                                 )
32.                             )
33.                         )
34.                     )
35.                 )
36.                 (vl-princ-to-string name)
37.                 *error*
38.                 (list 'quote
39.                     (mapcar
40.                         '(lambda (a / ) (cons a (getvar a)))
41.                         sysvars
42.                     )
43.                 )
44.                 *doc*
45.                 (getvar 'cmdecho)
46.             )
47.         )
48.     )    
49. )
50.    
51. (ini*error* ;initialize error-handler
52.     "String to display if an error occurs to identify wich function fails: "
53.     '("CLAYER" "OSMODE" "CMDECHO" "DIMZIN") ;LIST of Sysvars to save/restore; String or Sym
54. )
55.  
56. ;other stuff to do....
57.  
58. (*error* nil) ;restore Sys-Vars, and a previous-error-handler

reltro

[roy_043]

@ Reltro:
Interesting code. I have a question about this portion:

Code: [Select]

(if (not (wcmatch msg "*EXIT*,*BREAK*,*CANCEL*"))
  (progn
    (princ "\n*** error ***\n")
    (princ (strcat "\t" name ": " (vl-princ-to-string msg) "\n"))

    (*error* msg)
    (princ)
  )
)
If an EXIT/BREAK/CANCEL error occurs the restored *error* function is not called meaning only a single level is undone.

If a different error occurs the restored *error* function is called meaning all levels are undone. And there will also be a superfluous call to the 'default' *error* function.

I may be missing something but this does not seem logical.

[reltro]

@ Reltro:
Interesting code. I have a question about this portion:

Code: [Select]

(if (not (wcmatch msg "*EXIT*,*BREAK*,*CANCEL*"))
  (progn
    (princ "\n*** error ***\n")
    (princ (strcat "\t" name ": " (vl-princ-to-string msg) "\n"))

    (*error* msg)
    (princ)
  )
)
If an EXIT/BREAK/CANCEL error occurs the restored *error* function is not called meaning only a single level is undone.

If a different error occurs the restored *error* function is called meaning all levels are undone. And there will also be a superfluous call to the 'default' *error* function.

I may be missing something but this does not seem logical.

Oh shit...
roy_043 u r totally right... this is a mistake...

Found an other issue...
should be (wcmatch (strcase msg) ...)

corrected version

Code - Auto/Visual Lisp: [Select]

1. ;Note:
2. ;    *error* should not be localized!!!
3.  
4.  
5. (defun ini*error* (name sysvars / *doc*)
6.     (vla-startundomark (setq *doc* (vla-get-activedocument (vlax-get-acad-object))))
7.     (eval
8.         (list 'defun '*error* '(msg / )
9.             (list
10.                 (lambda (name prevErrorHandler SysVars *doc* currentcmdecho / )
11.                     (mapcar
12.                         'setvar
13.                         (mapcar 'car SysVars)
14.                         (mapcar 'cdr SysVars)
15.                     )
16.                     (vla-endundomark *doc*)
17.                     (setq *error* prevErrorHandler)
18.                     (if msg
19.                         (progn
20.                             (setvar 'cmdecho 0)
21.                             (command-s "_.undo" 1 "")
22.                             (setvar 'cmdecho currentcmdecho)
23.  
24.                             (if (not (wcmatch (strcase msg) "*EXIT*,*BREAK*,*CANCEL*"))
25.                                 (progn
26.                                     (princ "\n*** error ***\n")
27.                                     (princ (strcat "\t" name ": " (vl-princ-to-string msg) "\n"))
28.  
29.                                     (princ)
30.                                 )
31.                             )
32.                                                        
33.                             (*error* msg)
34.                         )
35.                     )
36.                 )
37.                 (vl-princ-to-string name)
38.                 *error*
39.                 (list 'quote
40.                     (mapcar
41.                         '(lambda (a / ) (cons a (getvar a)))
42.                         sysvars
43.                     )
44.                 )
45.                 *doc*
46.                 (getvar 'cmdecho)
47.             )
48.         )
49.     )    
50. )
51.  
52. (ini*error* ;initialize error-handler
53.     "String to display if an error occurs to identify wich function fails: "
54.     '("CLAYER" "OSMODE" "CMDECHO" "DIMZIN") ;LIST of Sysvars to save/restore; String or Sym
55. )
56.  
57. ;other stuff to do....
58.  
59. (*error* nil) ;restore Sys-Vars, and a previous-error-handler
60.  

reltro

[reltro]

DOES NOT WORK

Code - Auto/Visual Lisp: [Select]

1. (defun initializeError (name /  *doc*)
2.     (vla-startundomark (setq *doc* (vla-get-activedocument (vlax-get-acad-object))))
3.    
4.     (eval
5.         (list 'defun-q '*error* '(msg / )
6.             (list 'setq 'setvar setvar)
7.             nil
8.             (list
9.                 (lambda (name *doc* prevErr / )
10.                     (vla-endundomark *doc*)
11.                    
12.                     (setq *error* prevErr)
13.                    
14.                     (if msg
15.                         (progn
16.                             (setvar 'cmdecho 0)
17.                             (command-s "_.undo" 1 "")
18.                             (setvar 'cmdecho currentcmdecho)
19.  
20.                             (if (not (wcmatch (strcase msg) "*EXIT*,*BREAK*,*CANCEL*"))
21.                                 (progn
22.                                     (princ "\n*** error ***\n")
23.                                     (princ (strcat "\t" name ": " msg "\n"))
24.  
25.                                     (princ)
26.                                 )
27.                             )
28.                            
29.                             (*error* msg)
30.                         )
31.                     )
32.                 )
33.                 (vl-princ-to-string name)
34.                 *doc*
35.                 (list 'quote *error*)
36.             )
37.         )
38.     )
39.    
40.     (eval
41.         (list 'defun 'setvar '(n v / )
42.             (list
43.                 (lambda (S store / )
44.                     (eval
45.                         (vl-list*
46.                             'defun-q '*error* '(msg / )
47.                             (cadr *error*)
48.                             (list 'setvar (vl-princ-to-string n) store)
49.                             (cddr *error*)
50.                         )
51.                     )
52.                     (S n v)
53.                 )
54.                 setvar
55.                 (list getvar 'n)
56.             )
57.         )
58.     )
59. )
60.  

This one would be nice too, I think, but overwriting 'setvar does not work... 

reltro

[liuhaixin88]

Thanks ,reltro

[reltro]

I'm not sure if this is good stuff or not...
Im overwriting setvar to catch all changes and restore changed sysvars if an error occurs or the errorHandler is called with nil...

Code - Auto/Visual Lisp: [Select]

1. (defun INIerror (name /  *doc*)
2.     (vla-startundomark (setq *doc* (vla-get-activedocument (vlax-get-acad-object))))
3.  
4.     (eval
5.         (list 'defun-q '*error* '(msg / )
6.             (list
7.                 (lambda (s / )
8.                     (pragma '((unprotect-assign setvar)))
9.                     (setq setvar s)
10.                     (pragma '((protect-assign setvar)))
11.                 )
12.                 setvar
13.             )
14.             (list
15.                 (lambda (store / )
16.                     (mapcar
17.                         '(lambda (a / )
18.                             (setvar (car a) (cdr a))
19.                         )
20.                         store
21.                     )
22.                 )
23.                 nil
24.             )
25.             (list
26.                 (lambda (name *doc* prevErr  / currentcmdecho)
27.                     (vla-endundomark *doc*)
28.                     (setq *error* prevErr)
29.  
30.                     (if msg
31.                         (progn
32.                             (setq currentcmdecho (getvar 'cmdecho))
33.                             (setvar 'cmdecho 0)
34.                             (command-s "_.undo" 1 "")
35.                             (setvar 'cmdecho currentcmdecho)
36.  
37.                             (if (not (wcmatch (strcase msg) "*EXIT*,*BREAK*,*CANCEL*"))
38.                                 (progn
39.                                     (princ "\n*** error ***\n")
40.                                     (princ (strcat "\t" name ": " msg "\n"))
41.  
42.                                     (princ)
43.                                 )
44.                             )
45.  
46.                             (*error* msg)
47.                         )
48.                     )
49.                 )
50.                 (vl-princ-to-string name)
51.                 *doc*
52.                 (list 'quote *error*)
53.             )
54.         )
55.     )
56.  
57.     (pragma '((unprotect-assign setvar)))
58.    
59.     (eval
60.         (list 'defun 'setvar '(n v / )
61.             (list
62.                 (lambda (S store / )
63.                     (setq n (strcase (vl-princ-to-string n)))
64.                     (eval
65.                         (vl-list*
66.                             'defun-q '*error* '(msg / )
67.                             (cadr *error*)
68.                             (    (lambda (values / )
69.                                     (if (assoc n (eval (cadr values)))
70.                                         values
71.                                         (list
72.                                             (car values)
73.                                             (list 'quote (cons (cons n store) (eval (cadr values))))
74.                                         )
75.                                     )
76.                                 )
77.                                 (caddr *error*)
78.                             )
79.                             (cddr *error*)
80.                         )
81.                     )
82.                     (S n v)
83.                 )
84.                 setvar
85.                 (list getvar 'n)
86.             )
87.         )
88.     )
89.    
90.     (pragma '((protect-assign setvar)))
91. )
92.  

USAGE:

Code: [Select]

(INIerror "This is a function ...")

(setvar "osmode" 0)
(setvar "cmdecho 0)

.
.
.
.

(*error* nil)

reltro

[liuhaixin88]

I'm not sure if this is good stuff or not...
Im overwriting setvar to catch all changes and restore changed sysvars if an error occurs or the errorHandler is called with nil...

Code - Auto/Visual Lisp: [Select]

1. (defun INIerror (name /  *doc*)
2.     (vla-startundomark (setq *doc* (vla-get-activedocument (vlax-get-acad-object))))
3.  
4.     (eval
5.         (list 'defun-q '*error* '(msg / )
6.             (list
7.                 (lambda (s / )
8.                     (pragma '((unprotect-assign setvar)))
9.                     (setq setvar s)
10.                     (pragma '((protect-assign setvar)))
11.                 )
12.                 setvar
13.             )
14.             (list
15.                 (lambda (store / )
16.                     (mapcar
17.                         '(lambda (a / )
18.                             (setvar (car a) (cdr a))
19.                         )
20.                         store
21.                     )
22.                 )
23.                 nil
24.             )
25.             (list
26.                 (lambda (name *doc* prevErr  / currentcmdecho)
27.                     (vla-endundomark *doc*)
28.                     (setq *error* prevErr)
29.  
30.                     (if msg
31.                         (progn
32.                             (setq currentcmdecho (getvar 'cmdecho))
33.                             (setvar 'cmdecho 0)
34.                             (command-s "_.undo" 1 "")
35.                             (setvar 'cmdecho currentcmdecho)
36.  
37.                             (if (not (wcmatch (strcase msg) "*EXIT*,*BREAK*,*CANCEL*"))
38.                                 (progn
39.                                     (princ "\n*** error ***\n")
40.                                     (princ (strcat "\t" name ": " msg "\n"))
41.  
42.                                     (princ)
43.                                 )
44.                             )
45.  
46.                             (*error* msg)
47.                         )
48.                     )
49.                 )
50.                 (vl-princ-to-string name)
51.                 *doc*
52.                 (list 'quote *error*)
53.             )
54.         )
55.     )
56.  
57.     (pragma '((unprotect-assign setvar)))
58.    
59.     (eval
60.         (list 'defun 'setvar '(n v / )
61.             (list
62.                 (lambda (S store / )
63.                     (setq n (strcase (vl-princ-to-string n)))
64.                     (eval
65.                         (vl-list*
66.                             'defun-q '*error* '(msg / )
67.                             (cadr *error*)
68.                             (    (lambda (values / )
69.                                     (if (assoc n (eval (cadr values)))
70.                                         values
71.                                         (list
72.                                             (car values)
73.                                             (list 'quote (cons (cons n store) (eval (cadr values))))
74.                                         )
75.                                     )
76.                                 )
77.                                 (caddr *error*)
78.                             )
79.                             (cddr *error*)
80.                         )
81.                     )
82.                     (S n v)
83.                 )
84.                 setvar
85.                 (list getvar 'n)
86.             )
87.         )
88.     )
89.    
90.     (pragma '((protect-assign setvar)))
91. )
92.  

USAGE:

Code: [Select]

(INIerror "This is a function ...")

(setvar "osmode" 0)
(setvar "cmdecho 0)

.
.
.
.

(*error* nil)

reltro

Thanks  reltro, you are great !
your routine  is complex. I can't understand completely.

When errors happen, this routine can do what ?

[Kerry]

My experience has shown that the *error* function is best defined as local to the main application function.

eg

(defun c:test ( / *error* ... )
 
    (defun *error* ( msg )
        ;; stuff here
    )
    ;; stuff here

    ; force a clean-up
    (*error* nil )
    (princ)
)

If you define *error as global it will stay in memory and be re-used for any following errors. ... something that may not be required if you are making specific restorations or changes to the environment.

A general guideline is "Leave the environment as you found it". I've seen cases where a user defined global *error* routine has caused real debugging problems in other routines.