« previous next »
Pages: [1] 2  All |   Go Down

Author Topic: Auto Arrange  (Read 9957 times)

0 Members and 1 Guest are viewing this topic.

liuhaixin88

  • Guest
Auto Arrange
« on: April 28, 2014, 10:52:18 AM »
Who has seen anything like it ?  lisp ,fas,vlx ?

Auto Arrange , minimal area . Choose arrange clearance & quantity.

[BTW:Authors blame I issued his pictures , SO I was delete it ]

« Last Edit: May 02, 2014, 03:27:00 AM by liuhaixin88 »
Logged

ChrisCarlson

  • Guest
Re: Auto Arrange
« Reply #1 on: April 28, 2014, 10:55:26 AM »
Arrange what?

Blocks?
Text?
Mleaders?

Logged

liuhaixin88

  • Guest
Re: Auto Arrange
« Reply #2 on: April 28, 2014, 11:03:38 AM »
Quote from: ChrisCarlson on April 28, 2014, 10:55:26 AM
Arrange what?

Blocks?
Text?
Mleaders?

I just upload the image.
Logged

BlackBox

  • King Gator
  • Posts: 3770
Re: Auto Arrange
« Reply #3 on: April 28, 2014, 11:30:28 AM »
A few Commands come to mind... Array, Measure, Divide, etc.
Logged
"How we think determines what we do, and what we do determines what we get."

liuhaixin88

  • Guest
Re: Auto Arrange
« Reply #4 on: April 28, 2014, 12:33:50 PM »
Quote from: BlackBox on April 28, 2014, 11:30:28 AM
A few Commands come to mind... Array, Measure, Divide, etc.

Hello ,BB

It's Not so easy, need related to the algorithm, Like the minimum bounding box.

First ,I don't know how to arrange for the smallest area.

Found a related demonstration：



« Last Edit: May 02, 2014, 03:27:49 AM by liuhaixin88 »
Logged

dgorsman

  • Water Moccasin
  • Posts: 2437
Re: Auto Arrange
« Reply #5 on: April 28, 2014, 02:09:13 PM »
Look for nesting algorithms.  Should be several threads here on the subject if memory serves.
Logged
If you are going to fly by the seat of your pants, expect friction burns.

try {GreatPower;}
   catch (notResponsible)
      {NextTime(PlanAhead);}
   finally
      {MasterBasics;}

ribarm

  • Gator
  • Posts: 3272
  • Marko Ribar, architect
Re: Auto Arrange
« Reply #6 on: April 28, 2014, 06:30:40 PM »
This is how I would arrange 23 3D entities in 3D... Like in 2D and in my version linear arrangement prevails - only in Z direction...

See attachment...
Logged
Marko Ribar, d.i.a. (graduated engineer of architecture)

:)

M.R. on Youtube

liuhaixin88

  • Guest
Re: Auto Arrange
« Reply #7 on: April 28, 2014, 10:52:27 PM »
Quote from: ribarm on April 28, 2014, 06:30:40 PM
This is how I would arrange 23 3D entities in 3D... Like in 2D and in my version linear arrangement prevails - only in Z direction...

See attachment...

Ribarm, I know you proficient algorithm.The first person.

Can you help me?

Logged

liuhaixin88

  • Guest
Re: Auto Arrange
« Reply #8 on: April 29, 2014, 10:19:08 PM »
Quote from: ribarm on April 28, 2014, 06:30:40 PM
This is how I would arrange 23 3D entities in 3D... Like in 2D and in my version linear arrangement prevails - only in Z direction...

See attachment...

Please,marko, I need your help. Any file formats all ok! (VLX ,FAS,ARX)
Logged

ChrisCarlson

  • Guest
Re: Auto Arrange
« Reply #9 on: April 30, 2014, 07:56:28 AM »
Download Nestlib Online from the Acad App exchange
Logged

ribarm

  • Gator
  • Posts: 3272
  • Marko Ribar, architect
Re: Auto Arrange
« Reply #10 on: April 30, 2014, 11:03:54 AM »
This is similar to your 11.gif... It uses rotate&copy, but not mirror... Tested on simple LWPOLYLINES like on posted 11.gif...

Code - Auto/Visual Lisp: [Select]
  1. (defun c:rotarrange ( / adoc msp LM:MinEncCircle LM:RemoveWithFuzz LM:GetInsideAngle LM:3PCircle mid LM:ConvexHull LM:Clockwise-p LM:LWPoly->List pl n ri vl c plc xl ip p ipl d dl dminv dminvl dmaxv dmaxvl dmax1 dmax2 ipp pp ippl tst dmaxl dmin dlst->dmin )
  2.  
  5.   (setq msp (vla-get-modelspace adoc))
  6.  
  7.   (defun LM:MinEncCircle ( lst / _sub )
  8.  
  9.       (defun _sub ( p1 p2 l1 / a1 a2 l2 p3 p4 )
  10.           (setq l2 (LM:RemoveWithFuzz (list p1 p2) l1 1e-8)
  11.                 p3 (car l2)
  12.                 a1 (LM:GetInsideAngle p1 p3 p2)
  13.           )
  14.           (foreach p4 (cdr l2)
  15.               (if (< (setq a2 (LM:GetInsideAngle p1 p4 p2)) a1)
  16.                   (setq p3 p4 a1 a2)
  17.               )
  18.           )
  19.           (cond
  20.               (   (<= (/ pi 2.0) a1)
  21.                   (list (mid p1 p2) (/ (distance p1 p2) 2.0))
  22.               )
  23.               (   (vl-some
  24.                       (function
  25.                           (lambda ( a b c )
  26.                               (if (< (/ pi 2.0) (LM:GetInsideAngle a b c)) (_sub a c l1))
  27.                           )
  28.                       )
  29.                       (list p1 p1 p2) (list p2 p3 p1) (list p3 p2 p3)
  30.                   )
  31.               )
  32.               (   (LM:3PCircle p1 p2 p3)   )
  33.           )
  34.       )
  35.  
  36.       ((lambda ( lst ) (_sub (car lst) (cadr lst) lst)) (LM:ConvexHull lst))
  37.   )
  38.  
  39.   ;; Remove With Fuzz  -  Lee Mac
  40.   ;; Removes items from a list which are equal to a supplied tolerance
  41.  
  42.   (defun LM:RemoveWithFuzz ( l1 l2 fz )
  43.       (vl-remove-if
  44.           (function
  45.               (lambda ( a )
  46.                   (vl-some
  47.                       (function (lambda ( b ) (equal a b fz)))
  48.                       l1
  49.                   )
  50.               )
  51.           )
  52.           l2
  53.       )
  54.   )
  55.  
  56.   ;; Get Inside Angle  -  Lee Mac
  57.   ;; Returns the smaller angle subtended by three points with vertex at p2
  58.  
  59.   (defun LM:GetInsideAngle ( p1 p2 p3 )
  60.       (   (lambda ( a ) (min a (- (+ pi pi) a)))
  61.           (rem (+ pi pi (- (angle p2 p1) (angle p2 p3))) (+ pi pi))
  62.       )
  63.   )
  64.  
  65.   ;; 3-Point Circle  -  Lee Mac
  66.   ;; Returns the Center and Radius of the Circle defined by
  67.   ;; the supplied three points.
  68.  
  69.   (defun LM:3PCircle ( p1 p2 p3 / cn m1 m2 )
  70.       (setq m1 (mid p1 p2)
  71.             m2 (mid p2 p3)
  72.       )
  73.       (list
  74.           (setq cn
  75.               (inters
  76.                   m1 (polar m1 (+ (angle p1 p2) (/ pi 2.)) 1.0)
  77.                   m2 (polar m2 (+ (angle p2 p3) (/ pi 2.)) 1.0)
  78.                   nil
  79.               )
  80.           )
  81.           (distance cn p1)
  82.       )
  83.   )
  84.  
  85.   ;; Midpoint - Lee Mac
  86.   ;; Returns the midpoint of two points
  87.  
  88.   (defun mid ( a b )
  89.       (mapcar (function (lambda ( a b ) (/ (+ a b) 2.0))) a b)
  90.   )
  91.  
  92.   ;; Convex Hull  -  Lee Mac
  93.   ;; Implements the Graham Scan Algorithm to determine the
  94.   ;; Convex Hull of a list of points.
  95.  
  96.   (defun LM:ConvexHull ( lst / hul p0 )
  97.       (cond
  98.           (   (< (length lst) 4)
  99.               lst
  100.           )
  101.           (   t
  102.               (setq p0 (car lst))
  103.               (foreach p1 (cdr lst)
  104.                   (if (or (< (cadr p1) (cadr p0))
  105.                           (and (= (cadr p1) (cadr p0)) (< (car p1) (car p0)))
  106.                       )
  107.                       (setq p0 p1)
  108.                   )
  109.               )
  110.               (setq lst
  111.                   (vl-sort lst
  112.                       (function
  113.                           (lambda ( a b / c d )
  114.                               (if (or (equal (setq c (angle p0 a)) (setq d (angle p0 b)) 1e-8) (and (or (equal c 0.0 1e-8) (equal c (* 2 pi) 1e-8)) (or (equal d 0.0 1e-8) (equal d (* 2 pi) 1e-8))))
  115.                                   (< (distance (list (car p0) (cadr p0)) a) (distance (list (car p0) (cadr p0)) b))
  116.                                   (< c d)
  117.                               )
  118.                           )
  119.                       )
  120.                   )
  121.               )
  122.               (setq hul (list (caddr lst) (cadr lst) (car lst)))
  123.               (foreach pt (cdddr lst)
  124.                   (setq hul (cons pt hul))
  125.                   (while (and (caddr hul) (LM:Clockwise-p (caddr hul) (cadr hul) pt))
  126.                       (setq hul (cons pt (cddr hul)))
  127.                   )
  128.               )
  129.               hul
  130.           )
  131.       )
  132.   )
  133.  
  134.   ;; Clockwise-p  -  Lee Mac
  135.   ;; Returns T if p1,p2,p3 are clockwise oriented or collinear
  136.                    
  137.   (defun LM:Clockwise-p ( p1 p2 p3 )
  138.       (<  (-  (* (- (car  p2) (car  p1)) (- (cadr p3) (cadr p1)))
  139.               (* (- (cadr p2) (cadr p1)) (- (car  p3) (car  p1)))
  140.           )
  141.           1e-8
  142.       )
  143.   )
  144.  
  145.   ;; LWPolyline to Point List  -  Lee Mac
  146.   ;; Returns a list of points describing the supplied LWPolyline
  147.  
  148.   (defun LM:LWPoly->List ( ent n / der di1 di2 inc lst par )
  149.       (setq par 0)
  150.       (repeat (cdr (assoc 90 (entget ent)))
  151.           (if (setq der (vlax-curve-getsecondderiv ent par))
  152.               (if (equal der '(0.0 0.0 0.0) 1e-8)
  153.                   (setq lst (cons (vlax-curve-getpointatparam ent par) lst))
  154.                   (if
  155.                       (setq di1 (vlax-curve-getdistatparam ent par)
  156.                             di2 (vlax-curve-getdistatparam ent (1+ par))
  157.                       )
  158.                       (progn
  159.                           (setq inc (/ (- di2 di1) n))
  160.                           (while (< di1 di2)
  161.                               (setq lst (cons (vlax-curve-getpointatdist ent di1) lst)
  162.                                     di1 (+ di1 inc)
  163.                               )
  164.                           )
  165.                           (if (equal (vlax-curve-getpointatdist ent di1) (vlax-curve-getendpoint ent) 1e-8)
  166.                               (setq lst (cons (vlax-curve-getendpoint ent) lst))
  167.                           )
  168.                       )
  169.                   )
  170.               )
  171.           )
  172.           (setq par (1+ par))
  173.       )
  174.       lst
  175.   )
  176.  
  177.   (while (or (not (setq pl (car (entsel "\nPick LWPOLYLINE shape")))) (not (eq (cdr (assoc 0 (entget pl))) "LWPOLYLINE"))))
  178.   (initget 7)
  179.   (setq n (getint "\nSpecify rotational derivation of full rotation - 360 degree / ? : "))
  180.   (setq ri (/ 360.0 n))
  181.   (setq ri (* (/ ri 180.0) pi))
  182.   (setq c (car (LM:MinEncCircle (LM:LWPoly->List pl 25))))
  183.   (repeat n
  184.     (if plc (entdel (vlax-vla-object->ename plc)))
  185.     (vla-rotate (vlax-ename->vla-object pl) (vlax-3d-point c) ri)
  186.     (setq vl (LM:LWPoly->List pl 36))
  187.     (foreach v vl
  188.       (setq xl (vla-addxline msp (vlax-3d-point v) (vlax-3d-point (mapcar '+ v '(1.0 0.0 0.0)))))
  189.       (setq ip (vlax-invoke xl 'intersectwith (vlax-ename->vla-object pl) acextendnone))
  190.       (if (/= (length ip) 3)
  191.         (progn
  192.           (repeat (/ (length ip) 3)
  193.             (setq p (list (car ip) (cadr ip) (caddr ip)))
  194.             (setq ip (cdddr ip))
  195.             (setq ipl (cons p ipl))
  196.           )
  197.           (foreach p ipl
  198.             (setq d (distance v p))
  199.             (setq dl (cons d dl))
  200.           )
  201.           (setq dminv (cadr (vl-sort dl '<)))
  202.           (setq dmaxv (apply 'max dl))
  203.           (if dminv (setq dminvl (cons dminv dminvl)))
  204.           (if dmaxv (setq dmaxvl (cons dmaxv dmaxvl)))
  205.           (setq ipl nil dl nil)
  206.         )
  207.       )
  208.       (entdel (vlax-vla-object->ename xl))
  209.     )
  210.     (setq dmax1 (apply 'max dminvl))
  211.     (setq dminvl nil)
  212.     (setq dmax2 (apply 'max dmaxvl))
  213.     (setq dmaxvl nil)
  214.     (setq plc (vla-copy (vlax-ename->vla-object pl)))
  215.     (vla-move plc (vlax-3d-point '(0.0 0.0 0.0)) (vlax-3d-point (list dmax1 0.0 0.0)))
  216.     (setq ipp (vlax-invoke plc 'intersectwith (vlax-ename->vla-object pl) acextendnone))
  217.     (repeat (/ (length ipp) 3)
  218.       (setq pp (list (car ipp) (cadr ipp) (caddr ipp)))
  219.       (setq ipp (cdddr ipp))
  220.       (setq ippl (cons pp ippl))
  221.     )
  222.     (foreach p ippl
  223.       (if (vl-some '(lambda ( x ) (equal x p 1e-8)) vl) (setq tst (cons t tst)) (setq tst (cons nil tst)))
  224.     )
  225.     (if (not (eval (cons 'and tst)))
  226.       (progn
  227.         (vla-move plc (vlax-3d-point '(0.0 0.0 0.0)) (vlax-3d-point (list (- dmax1) 0.0 0.0)))
  228.         (vla-move plc (vlax-3d-point '(0.0 0.0 0.0)) (vlax-3d-point (list dmax2 0.0 0.0)))
  229.         (setq dmaxl (cons dmax2 dmaxl))
  230.       )
  231.       (setq dmaxl (cons dmax1 dmaxl))
  232.     )
  233.     (setq tst nil ippl nil)
  234.     (vla-regen adoc 1)
  235.   )
  236.   (setq dmin (apply 'min dmaxl))
  237.   (setq dmaxl (reverse dmaxl))
  238.   (setq dlst->dmin (reverse (member dmin (reverse dmaxl))))
  239.   (foreach d dlst->dmin
  240.     (if plc (entdel (vlax-vla-object->ename plc)))
  241.     (vla-rotate (vlax-ename->vla-object pl) (vlax-3d-point c) ri)
  242.     (setq plc (vla-copy (vlax-ename->vla-object pl)))
  243.     (vla-move plc (vlax-3d-point '(0.0 0.0 0.0)) (vlax-3d-point (list d 0.0 0.0)))
  244.     (vla-regen adoc 1)
  245.   )
  246.   (princ)
  247. )
  248.  

HTH
« Last Edit: June 19, 2019, 12:57:07 AM by ribarm »
Logged
Marko Ribar, d.i.a. (graduated engineer of architecture)

:)

M.R. on Youtube

ribarm

  • Gator
  • Posts: 3272
  • Marko Ribar, architect
Re: Auto Arrange
« Reply #11 on: May 01, 2014, 02:56:08 AM »
Now, above posted code works and with more complex shapes, but only with LWPOLYLINE with straight segments (edges)...

M.R.
Logged
Marko Ribar, d.i.a. (graduated engineer of architecture)

:)

M.R. on Youtube

liuhaixin88

  • Guest
Re: Auto Arrange
« Reply #12 on: May 01, 2014, 08:48:47 PM »
Quote from: ribarm on May 01, 2014, 02:56:08 AM
Now, above posted code works and with more complex shapes, but only with LWPOLYLINE with straight segments (edges)...

M.R.

Marko, Thanks very much for your hard work.

Two objects  are rotated counterclockwise. I think , when rotated counterclockwise later, one objects rotated counterclockwise, one objects rotated clockwise.
Logged

Q1241274614

  • Guest
Re: Auto Arrange
« Reply #13 on: May 01, 2014, 11:30:03 PM »
After combination, such a minimum area.


http://www.theswamp.org/index.php?topic=46636.0

« Last Edit: May 01, 2014, 11:34:57 PM by Q1241274614 »
Logged

liuhaixin88

  • Guest
Re: Auto Arrange
« Reply #14 on: May 02, 2014, 12:40:17 AM »
Quote from: Q1241274614 on May 01, 2014, 11:30:03 PM
After combination, such a minimum area.


http://www.theswamp.org/index.php?topic=46636.0

Thanks for providing ideas.
« Last Edit: May 02, 2014, 03:31:38 AM by liuhaixin88 »
Logged
Pages: [1] 2  All |   Go Up
« previous next »