Author Topic: help with a lisp (Read 10749 times)

pedroantonio · « **Reply #45 on:** April 01, 2014, 02:09:57 PM »

I know thats why i write

Quote

The comment 2 i thing need 3 options
T1>Area>T2
T1>Area
T2< Area

ymg · « **Reply #46 on:** April 01, 2014, 02:22:03 PM »

Kerry,

Here somethig I use quite often as a test condition:

Quote

1$ (< 2 5 7)
T
_1$ (< 2 1 7)
nil

Kerry · « **Reply #47 on:** April 01, 2014, 02:31:14 PM »

Please Test this in isolation :

Code - Auto/Visual Lisp: [Select]

 
(defun _PrintComments ()
  (setq T1 (- OLDARE ANOX))
  (setq T2 (+ OLDARE ANOX))
  (princ (strcat "\n ----------------"
                 (strcat "\n Area = " (rtos AREA 2 2) " sqm")
                 (strcat "\n Old Area = " (rtos oldare 2 2) " sqm")
                 (strcat "\n Anotation Area = ± " (rtos ANOX 2 2) " sqm")
                 "\n comments: "
         )
  )
  (cond
    ((<= T1 AREA T2)
     (princ (strcat "\n ----------------\n "
                    (strcat (rtos T1 2 2)
                            " sqm <= "
                            (rtos AREA 2 2)
                            " <= "
                            (rtos T2 2 2)
                            " sqm"
                    )
                    "\n comment1:"
            )
     )
    )
    ((> T1 AREA T2)
     (princ (strcat "\n ----------------\n "
                    (strcat (rtos T1 2 2)
                            " sqm > "
                            (rtos AREA 2 2)
                            " > "
                            (rtos T2 2 2)
                            " sqm"
                    )
                    "\n comment2:"
            )
     )
    )
    ((> T1 AREA)
     (princ
       (strcat "\n ----------------\n "
               (strcat (rtos T1 2 2) " sqm > " (rtos AREA 2 2) " sqm")
               "\n comment2:"
       )
     )
    )
    ((< T2 AREA)
     (princ
       (strcat "\n ----------------\n "
               (strcat (rtos T2 2 2) " sqm < " (rtos AREA 2 2) " sqm")
               "\n comment2:"
       )
     )
    )
    (t (princ "\n ----------------\n No suitable data."))
  )
  (princ "\n =======================\n")
  (princ)
)
 

With these tests
.... and I'd suggest you write some tests of your own as well.

Code - Auto/Visual Lisp: [Select]

 
;; TESTING CODE for (_PrintComments)
 
;; for option 1 (comment 1)
(setq area   8062
      oldare 8000
      anox   (* OLDARE 0.05)
      var    (_PrintComments)
)
;; for option 1 (comment 2)
(setq area   9500
      oldare 8000
      anox   (* OLDARE 0.05)
      var    (_PrintComments)
)
 
 
 
;; for option 2 (comment 1)
(setq area   7500
      oldare 8000
      anox   (* OLDARE 0.10)
      var    (_PrintComments)
)
;; for option 2 (comment 2)
(setq area   7100
      oldare 8000
      anox   (* OLDARE 0.10)
      var    (_PrintComments)
)
 
;; for option 2 (comment 2)
(setq area   8950
      oldare 8000
      anox   (* OLDARE 0.10)
      var    (_PrintComments)
)
 
 
 

My Results :

Quote

----------------
Area = 8062.00 sqm
Old Area = 8000.00 sqm
Anotation Area = ± 400.00 sqm
comments:
----------------
7600.00 sqm <= 8062.00 <= 8400.00 sqm
comment1:
=======================

----------------
Area = 9500.00 sqm
Old Area = 8000.00 sqm
Anotation Area = ± 400.00 sqm
comments:
----------------
8400.00 sqm < 9500.00 sqm
comment2:
=======================

----------------
Area = 7500.00 sqm
Old Area = 8000.00 sqm
Anotation Area = ± 800.00 sqm
comments:
----------------
7200.00 sqm <= 7500.00 <= 8800.00 sqm
comment1:
=======================

----------------
Area = 7100.00 sqm
Old Area = 8000.00 sqm
Anotation Area = ± 800.00 sqm
comments:
----------------
7200.00 sqm > 7100.00 sqm
comment2:
=======================

----------------
Area = 8950.00 sqm
Old Area = 8000.00 sqm
Anotation Area = ± 800.00 sqm
comments:
----------------
8800.00 sqm < 8950.00 sqm
comment2:
=======================

Then if you're happy try the combined code on real entitys.

Code - Auto/Visual Lisp: [Select]

 
(defun C:TEST (/         _PrintComments      _Option1  _Option2
               OLDARE    AREA      DXF       ENT       ANOX
               T1        T2
              )
  (defun _Option1 () (setq ANOX (* OLDARE 0.05)))
  (defun _Option2 () (setq ANOX (* OLDARE 0.10)))
  (defun _PrintComments ()
    (setq T1 (- OLDARE ANOX))
    (setq T2 (+ OLDARE ANOX))
    (princ
      (strcat "\n ----------------"
              (strcat "\n Area = " (rtos AREA 2 2) " sqm")
              (strcat "\n Old Area = " (rtos oldare 2 2) " sqm")
              (strcat "\n Anotation Area = ± " (rtos ANOX 2 2) " sqm")
              "\n comments: "
      )
    )
    (cond
      ((<= T1 AREA T2)
       (princ (strcat "\n ----------------\n "
                      (strcat (rtos T1 2 2)
                              " sqm <= "
                              (rtos AREA 2 2)
                              " <= "
                              (rtos T2 2 2)
                              " sqm"
                      )
                      "\n comment1:"
              )
       )
      )
      ((> T1 AREA T2)
       (princ (strcat "\n ----------------\n "
                      (strcat (rtos T1 2 2)
                              " sqm > "
                              (rtos AREA 2 2)
                              " > "
                              (rtos T2 2 2)
                              " sqm"
                      )
                      "\n comment2:"
              )
       )
      )
      ((> T1 AREA)
       (princ
         (strcat "\n ----------------\n "
                 (strcat (rtos T1 2 2) " sqm > " (rtos AREA 2 2) " sqm")
                 "\n comment2:"
         )
       )
      )
      ((< T2 AREA)
       (princ
         (strcat "\n ----------------\n "
                 (strcat (rtos T2 2 2) " sqm < " (rtos AREA 2 2) " sqm")
                 "\n comment2:"
         )
       )
      )
      (t (princ "\n ----------------\n No suitable data."))
    )
    (princ "\n =======================\n")
    (princ)
  )
  ;; Main -----
  (if
    (and (setq ENT (car (entsel "\nSelect a close polyline: ")))
         (wcmatch (cdr (assoc 0 (setq DXF (entget ENT)))) "*POLYLINE")
         (member (cdr (assoc 70 DXF)) '(1 129))
         (setq OLDARE (getreal "\ngive old area : "))
    )
     (progn
       (initget 7)
       (textpage)
       (prompt "\n text1  :
 
   1. option 1
   2. option 2
        "
       )
       (setq AREA   (vlax-curve-getarea ENT)
             OPTION (getint "choose 1 -->2: ")
       )
       (cond ((= OPTION 1) (_Option1))
             ((= OPTION 2) (_Option2))
             (t (alert "Select > 2 --> Auto select 2. ") (_Option2))
       )
       (_PrintComments)
     )
     (princ "\nError selection of polyline ...")
  )
  (princ)
)
 

pedroantonio · « **Reply #48 on:** April 01, 2014, 02:52:01 PM »

thank you kerry i will test it..

pedroantonio · « **Reply #49 on:** April 04, 2014, 03:48:29 AM »

Hello Kerry ..
I tried to add some comments on the results to the first code of this topic. The above method for showing me is difficult to use it because the Oprtion 2 and Option 3 have the same area 2000, but different comments. So I decided to add the comments in the code of each option. But something is written wrong but i don't know what.I don't know how to use (_PRINTCOMMENTS) .Could you help me with the code.
Thanks

Code - Auto/Visual Lisp: [Select]

(DEFUN
   C:DOMKAL (/ _PRINTCOMMENTS _OPTION1 _OPTION2 _OPTION3 _OPTION4 AREA
             DXF ENT SDAREA SKAREA
            )
  (DEFUN
     _OPTION1 ()
    (COND
      ((< AREA 200)
       (SETQ
         SDAREA AREA
         SKAREA
          (* AREA 0.7)
       )
       (PRINC
         (STRCAT
           "\n ---------------------\n "
           "\n bla bla bla bla."
           "\n bla bla bla bla."
           "\n bla bla bla bla."
           "\n bla bla bla bla."
          )
       )
      )
      ((< AREA 700)
       (SETQ
         SDAREA 240
         SKAREA
          (* AREA 0.6)
         (PRINC
           (STRCAT
             "\n ---------------------\n "
             "\n bla bla bla bla."
             "\n bla bla bla bla."
             "\n bla bla bla bla."
             "\n bla bla bla bla."
            )
         )
       )
       ((>= AREA 700)
         (SETQ
           SDAREA 400
           SKAREA
            (* AREA 0.6)
           (PRINC
             (STRCAT
               "\n ---------------------\n "
               "\n bla bla bla bla."
               "\n bla bla bla bla."
               "\n bla bla bla bla."
               "\n bla bla bla bla."
              )
           )
         )
       )
      )
      (DEFUN
       _OPTION2
       ()
       (COND
         ((<= AREA 2000)
          (SETQ
            SDAREA
             (* AREA 0.8)
            SKAREA
             (* AREA 0.6)
            (PRINC
              (STRCAT
                "\n ---------------------\n "
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
               )
            )
          )
          ((> AREA 2000)
            (SETQ
              SDAREA
               (+ 400 (* 0.05 (- AREA 2000)))
              SKAREA
               (* AREA 0.1)
              (PRINC
                (STRCAT
                  "\n ---------------------\n "
                  "\n bla bla bla bla."
                  "\n bla bla bla bla."
                  "\n bla bla bla bla."
                  "\n bla bla bla bla."
                 )
              )
            )
          )
         )
         (DEFUN
          _OPTION3
          ()
          (COND
            ((= AREA 750)
             (SETQ
               SDAREA 100
               SKAREA
                (* AREA 0.1)
               (PRINC
                 (STRCAT
                   "\n ---------------------\n "
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                  )
               )
             )
            )
            ((AND (> AREA 750) (<= AREA 1200))
             (SETQ
               SDAREA
                (+ 100 (/ (- AREA 750) 9))
               SKAREA
                (* AREA 0.1)
               (PRINC
                 (STRCAT
                   "\n ---------------------\n "
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                  )
               )
             )
            )
            ((AND (> AREA 1200) (<= AREA 2000))
             (SETQ
               SDAREA
                (+ 150 (/ (- AREA 1200) 16))
               SKAREA
                (* AREA 0.1)
               (PRINC
                 (STRCAT
                   "\n ---------------------\n "
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                   "\n bla bla bla bla."
                  )
               )
             )
            )
            ((AND (> AREA 2000) (< AREA 4000))
             (SETQ
               SDAREA 0
               SKAREA 0
               (PRINC
                 (STRCAT
                   "\n ---------------------\n "
               "\n bla bla bla bla."
                "\n bla bla bla bla."
               "\n bla bla bla bla."
                "\n bla bla bla bla."
             )
            )
          )
         )
         ((= AREA 4000)
          (SETQ
            SDAREA 200
            SKAREA
             (* AREA 0.1)
            (PRINC
              (STRCAT
                "\n ---------------------\n "
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
               )
            )
          )
         )
         ((AND (> AREA 4000) (<= AREA 8000))
          (SETQ
            SDAREA
             (+ 200 (* 0.02 (- AREA 4000)))
            SKAREA
             (* AREA 0.1)
            (PRINC
              (STRCAT
                "\n ---------------------\n "
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
               )
            )
          )
         )
         ((> AREA 8000)
          (SETQ
            SDAREA
             (+ 280 (* 0.01 (- AREA 8000)))
            SKAREA
             (* AREA 0.1)
            (PRINC
              (STRCAT
                "\n ---------------------\n "
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
               )
            )
          )
         )
       )
       (DEFUN
          _OPTION4 ()
         (INITGET 7)
         (SETQ SDAREA (* AREA (GETREAL "\n Give sd (example 1.2) : ")))
         (INITGET 7)
         (SETQ SKAREA (* AREA (GETREAL "\nGive sk (example 0.70) : ")))
       )
       (PRINC
         (STRCAT
           "\n Print Results"
           "\n -----------------------"
           (STRCAT "\n Selected Area = " (RTOS AREA 2 2) " sq.m")
           (STRCAT "\n D = " (RTOS SDAREA 2 2) " sq.m")
           (STRCAT "\n K = " (RTOS SKAREA 2 2) " sq.m")
           "\n"
           "\n comments: "
         )
         (PRINC
              (STRCAT
                "\n ---------------------\n "
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
                "\n bla bla bla bla."
               )
            )
      )
    )
    (T
      (PRINC
        "\n ---------------------\nNo valid polyline selected..."
      )
    )
  )
  (PRINC
    "\n ========================================================================\n"
  )
  (PRINC)
)
;; Main -----
(IF (AND
      (SETQ ENT (CAR (ENTSEL "\nSelect a close polyline: ")))
      (WCMATCH
        (CDR (ASSOC 0 (SETQ DXF (ENTGET ENT))))
        "*POLYLINE"
      )
      (MEMBER (CDR (ASSOC 70 DXF)) '(1 129))
    )
  (PROGN
    (INITGET 7)
    (TEXTPAGE)
    (PROMPT
      "\nChoose an option:
 
   1. Oprion 1
   2. Option 2
   3. Option 3
   4. Option 4
 
"   )
    (SETQ
      AREA   (VLAX-CURVE-GETAREA ENT)
      OPTION (GETINT "choose 1 -->4:  ")
    )
    (COND
      ((= OPTION 1) (_OPTION1))
      ((= OPTION 2) (_OPTION2))
      ((= OPTION 3) (_OPTION3))
      ((= OPTION 4) (_OPTION4))
      (T (ALERT "Select > 4 --> Auto select 4. ") (_OPTION4))
    )
    (_PRINTCOMMENTS)
  )
  (PRINC "\nError selection of polyline ...")
)
(PRINC)
)
;|«Visual LISP© Format Options»
(72 2 40 2 nil "end of " 60 2 2 2 1 nil nil nil T)
;*** DO NOT add text below the comment! ***|;
 
 

Kerry · « **Reply #50 on:** April 04, 2014, 04:06:18 AM »

I don't have time to play.

Break the problem down to about half a page of code so you understand what is happening.

Kerry · « **Reply #51 on:** April 04, 2014, 04:47:02 AM »

This is probably the best advice I can offer.

pedroantonio · « **Reply #52 on:** April 04, 2014, 09:31:42 AM »

show me one example from Option 1 and i will try the others

snownut2 · « **Reply #53 on:** April 04, 2014, 05:30:35 PM »

Quote from: Topographer on April 04, 2014, 09:31:42 AM

show me one example from Option 1 and i will try the others

Really Pedro, did you not understand Kerry's GRAPH.

Kerry · « **Reply #54 on:** April 04, 2014, 07:41:42 PM »

It seems to me that because of your the changed logic, the (_PRINTCOMMENTS) is no longer required. .. or perhaps you do .. I no longer understand what you want.

Perhaps something like this structure would suit better

Code - Auto/Visual Lisp: [Select]

 
 
(defun c:MyRoutine ( / Routine_Functions Routine_variables)
  
  (defun *error* () (princ))
  (defun _SelectBoundary () (princ))
  (defun _PromptForOption () (princ))
  (defun _PromptForOldArea () (princ))
  (defun _OptionController () (princ))
  (defun _ProcessOption1 () (princ))
  (defun _ProcessOption2 () (princ))
  (defun _ProcessOption3 () (princ))
  (defun _ProcessOption4 () (princ))
  (defun _CalculateAndPrintArea () (princ))
  ;;
  ;;-- Main
  (if
    (not (and (_SelectBoundary)
              (_PromptForOption)
              (_PromptForOldArea)))
     (exit)
  )
  (_OptionController)
  (princ)
)
 
 

Just for giggles: If you renamed these variables to something that had obvious meaning, what would the new names be ?

ANOX
T1
T2
AREA <-- is not a good name because it duplicates an AutoCAD command name.
OLDARE
SDAREA
SKAREA

How does the user know which option to choose.

Kerry · « **Reply #55 on:** April 04, 2014, 08:10:48 PM »

Then fill out the logic flow functionality.

Code - Auto/Visual Lisp: [Select]

 
(defun c:MyRoutine ()
  (defun *error* () (princ))
  (defun _SelectBoundary () (princ))
  (defun _PromptForOption () (princ))
  (defun _PromptForOldArea () (princ))
  (defun _OptionController ()
    ;; Calculate BoundaryArea
    (cond ((= OPTION 1) (_ProcessOption1))
          ((= OPTION 2) (_ProcessOption2))
          ((= OPTION 3) (_ProcessOption3))
          ((= OPTION 4) (_ProcessOption4))
          (t (alert "Select > 4 --> Auto select 4. ") (_ProcessOption4))
    )
    (princ)
  )
  (defun _ProcessOption1 ()
    (cond ((< AREA 200)
           ;; Calculate area related values
           ;; Print option comments
          )
          ((< AREA 700)
           ;; Calculate area related values
           ;; Print option comments
          )
          ((>= AREA 700)
           ;; Calculate area related values
           ;; Print option comments
          )
    )
    (princ)
  )
  (defun _ProcessOption2 ()
    (cond ((<= AREA 2000)
           ;; Calculate area related values
           ;; Print option comments
          )
          ((> AREA 2000)
           ;; Calculate area related values
           ;; Print option comments
          )
    )
    (princ)
  )
  (defun _ProcessOption3 ()
    (cond ((and (> AREA 750) (<= AREA 1200))
           ;; Calculate area related values
           ;; Print option comments
          )
          ((and (> AREA 1200) (<= AREA 2000))
           ;; Calculate area related values
           ;; Print option comments
          )
          ((and (> AREA 2000) (< AREA 4000))
           ;; Calculate area related values
           ;; Print option comments
          )
          ((= AREA 4000)
           ;; Calculate area related values
           ;; Print option comments
          )
          ((and (> AREA 4000) (<= AREA 8000))
           ;; Calculate area related values
           ;; Print option comments
          )
          ((> AREA 8000)
           ;; Calculate area related values
           ;; Print option comments
          )
    )
    (princ)
  )
  (defun _ProcessOption4 ()
    ;; Prompt for criteria
    ;; Calculate area related values
    ;; Print option comments
    (princ)
  )
  (defun _CalculateAndPrintComments ()
    ;; Similar to old  (_PrintComments)
    (princ)
  )
  ;;
  ;;-- Main
  ;;
  (if
    (not (and (_SelectBoundary) (_PromptForOption) (_PromptForOldArea)))
     (exit)
  )
  (_OptionController)
  (_CalculateAndPrintComments)
  (princ)
)
 

Print this because it is your roadmap.
If you change the logic, change this first.

Save and rename this then continue filling in functionality.

pedroantonio · « **Reply #56 on:** April 05, 2014, 12:28:24 PM »

i fix it thanks

News:

Author Topic: help with a lisp (Read 10749 times)

pedroantonio

Re: help with a lisp

ymg

Re: help with a lisp

Kerry

Re: help with a lisp

pedroantonio

Re: help with a lisp

pedroantonio

Re: help with a lisp

Kerry

Re: help with a lisp

Kerry

Re: help with a lisp

pedroantonio

Re: help with a lisp

snownut2

Re: help with a lisp

Kerry

Re: help with a lisp

Kerry

Re: help with a lisp

pedroantonio

Re: help with a lisp