Topic: Verify the number from user's input

[Lee Mac]

Sorry, I should give more details. Here is the portion of my code:

(getreal "\nEnter the number: ")

This means that the user can enter an integer or a real nember.
I don't want to give the user to choose the type of input by using both "getreal" and "getini" in the code.

I believe the confusion in this thread arises because ℤ ⊂ ℝ, that is the set of integers is contained in the set of real numbers - hence by prompting the user for a real number, they are also permitted to enter an integer.

I'm also unsure what you are trying to achieve, but here is my offering for darts game:

Code - Auto/Visual Lisp: [Select]

1. (defun getreal-or-int ( msg / dim num )
2.     (if (setq num (getreal msg))
3.         (progn
4.             (setq dim (getvar 'dimzin))
5.             (setvar 'dimzin 8)
6.             (setq num (read (rtos num 2 15)))
7.             (setvar 'dimzin dim)
8.         )
9.     )
10.     num
11. )

Code - Auto/Visual Lisp: [Select]

1. Command: (getreal-or-int "\nEnter a number: ")
2. Enter a number: 2
3. 2
4.  
5. Command: (getreal-or-int "\nEnter a number: ")
6. Enter a number: 2.0
7. 2
8.  
9. Command: (getreal-or-int "\nEnter a number: ")
10. Enter a number: 2.5
11. 2.5

Hopefully I'll hit the treble-20 

[GP]

darts game 2.0   

Code: [Select]

(if (zerop (- num (fix num))) (atoi (rtos num)) num)

2    ->  2
2.0  ->  2
2.5  ->  2.5

[Lee Mac]

@GP, you might need to use (atoi (rtos num 2)) 

[gile]

Hi,

No need to convert to string and convert back:

Code - Auto/Visual Lisp: [Select]

1. (defun getRealOrInt (msg / num int)
2.   (if (setq num (getreal msg))
3.     (if (= (setq int (fix num)) num)
4.       int
5.       num
6.     )
7.   )
8. )

[Kerry]

Hi,

No need to convert to string and convert back:

Code - Auto/Visual Lisp: [Select]

1. (defun getRealOrInt (msg / num int)
2.   (if (setq num (getreal msg))
3.     (if (= (setq int (fix num)) num)
4.       int
5.       num
6.     )
7.   )
8. )

Very elegant gile.

[gile]

Thanks Kerry, but it wasn't so difficult 

[GP]

@GP, you might need to use (atoi (rtos num 2)) 

No need to convert to string and convert back:

True...
thanks. 

[MeasureUp]

WOW! It's amazing. I just come back from a buzy time.
Thanks to everyone.

This is my proposal:

(setq UserInput (getreal "\nEnter the number: "))

(if (UserInput is an integer)
    (Option 1 ...)
   (progn (Get_Number_of_Decimal) ;;; if the input is a real"
         (Option 2 ...)
   )
)

Kerry, hope your football term wins next time.
NICK_VNV & CAD, your codes are simple and straightforward.

(setq a (getreal "\nEnter the number: "))
(if (> (rem a 1) 0)
  (setq typ "REAL")
  (setq typ "INT")
)
(princ (strcat "\nEntered type is " typ))
(princ)

;; get precision of a decimal number string including trailing zeros
  (defun getPrec (str)
    (if (vl-string-search "." str)
      (- (strlen str)(vl-string-search "." str) 1)
      0
    )
  )

gile, your are so smart!
Lee, you always think something different from others.

You did not waste your time. I can learn from your ideas.
Thanks to swamp people. 

[Peter2]

Hi,

No need to convert to string and convert back:

Code - Auto/Visual Lisp: [Select]

1. (defun getRealOrInt (msg / num int)
2.   (if (setq num (getreal msg))
3.     (if (= (setq int (fix num)) num)
4.       int
5.       num
6.     )
7.   )
8. )

Hi

maybe I missed something, but using this code I get:

Code - Auto/Visual Lisp: [Select]

1. Befehl: (getrealorint "2.0")
2. 2
3. nil

It seems that "getreal" needs a "real user input" and not only a value??

[CAB]

Here using 2006ACAD I get 2
It will accept 2 or 2.0

[Peter2]

Here using 2006ACAD I get 2
It will accept 2 or 2.0

You mean "2" or "2.0", right?

[Lee Mac]

Here using 2006ACAD I get 2
It will accept 2 or 2.0

You mean "2" or "2.0", right?

Note that the argument passed to gile's function is the prompt string to be displayed to the user for the getreal function, not the value to be interpreted.

[Peter2]

Note that the argument passed to gile's function is the prompt string to be displayed to the user for the getreal function, not the value to be interpreted.

Ooh - I see. Thank you.