Topic: Loop through layers and blocks to search for tags

[Floris]

Hi all,

I'm new to lisp programming so I was searching the internet for some examples for a project that I'm working on.
However I could not find anything related to this but found this awesome forum luckily

I'm looking for a code snippet that helps me with the following:

I have drawings that needs to have specific (meta) tags in them for document control purposes.
However, these can be located in multiple layers and in multiple blocks.
So the thing I am looking for is a function that would do:
- Loop trough all the layers & blocks
- Within the blocks search for a predefined list of tag names.

When done, it should display:
- A list of tags that were found together with it's value and layername
- A list of tags that were not found within the drawing.

It would be a bonus if it could write this to an external textfile (CSV or similar).. but I would already be more than happy if I would have something to start with.

Hope that someone can help me out and point me into the right direction.

Thank you in advance,
Greetings,
Floris.

[irneb]

A few questions:

• By the layer, do you mean the tag itself is on a Layer inside the block, or are you referring to the layer on which the block is inserted
• What type of metadata? Is this only attributes, or things like XData as well?
• Do you have a list of tag names / identifying codes which can be searched through? Or should all found simply form part of the output?
• Is there only some layers (i.e. a list of them) or should any layer be used?
• How do you wish your output data to be formatted? Each column showing the tag name as heading, or should several tag names be combined into one column? If the later, what should happen if there's 2 tags with the to-be-combined tag names?

For points 3 & 4, it might be easier to have Excel filter these for you. It's reasonably easy to save out to a CSV file from AutoLisp - about the same as printing to the text screen. So it's then quite easy in Excel to convert it to a table, from which you can sort/filter on any columns. With a bit more programming you could even export directly to Excel if you so wish, but note there are some issues between 32bit & 64bit installations when you try to do this.

You "might" be able to use the built-in DataExtract tool to accomplish this. I'd first attempt to use it than create a full on addon. Only if I find it cannot do exactly what I want would I start writing the code.

[Floris]

Hi Irneb,

Sorry for being to vague in my description.

The value I am looking for is a certain ATTRIBUTE TAG within a BLOCK
No XData required here...

So it could have better written it as:
- Loop through all blocks
- Check against a predefined list of tags if present in block

So to come back at your questions:
(1) If attribute tag is found, add attribute to reported list of found attributes (with layer name) or write to cvs or other ascii file.
(2) Just attributes.. no XData stuff.
(3) Both ways would work for me.. but I have a list of tag-names available which should be present.
(4) ANY layer should be used.
(5) If written to file, then all tag names could be in same column. So in column format it would look something such as:
<TagName>,<Present_True/False>,<LayerName>

For me it would already help to see where to start.
Personally I am more used to VB.NET.. so I would already learn a lot by having such an example.
For instance, how to do multiple FOR EACH loops in lisp.
Probably when having some nice examples, then I'll write a quick lisp designer to make life easier for myself

Thank you very much in advance,
greetings,
Floris.

[irneb]

Seeing as you're used to VBA, then going with the ActiveX stuff might be familiar:

Quickly, written ... untested

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. ;; Edit this list with your tag names
4. (setq *MyAttribList* (mapcar 'strcase '("TagName1" "TagName2" "TagName3")))
5.  
6. ;; Export a single block reference's tags to the file
7. (defun ExportBlockToCSV  (block csvFile / layer)
8.   (setq layer (vlax-get block 'Layer)) ;Get the block insert's layer
9.   (foreach attribute  (vlax-get block 'Attributes) ;Step through all attributes of the block
10.     (if (member (strcase (vlax-get attribute 'TagString)) *MyAttribList*) ;Check attribute in list to export
11.       (princ ;Then print to the file
12.         ;; Concatenate the following strings
13.         (strcat "\n\"" ;New line & start double quote to force string
14.                 (vlax-get attribute 'TagString) ;Tag name
15.                 "\",\"" ;End double quote, add comma and start double quote to force string
16.                 (vlax-get attribute 'TextString) ;Tag value
17.                 "\",\"" ;End double quote, add comma and start double quote to force string
18.                 ;; Check if attribute is on layer 0
19.                 (cond ((eq (vlax-get attribute 'Layer) "0") layer) ;If so, use block's layer
20.                       (t (vlax-get attribute 'Layer))) ;Else use attribute's layer
21.                 "\"") ;End with double quote
22.         csvFile)))) ;Sent the print to the file
23.  
24. ;; Create the SaveTagsToCSV command
25. (defun c:SaveTagsToCSV (/ fname file)
26.   (if (and (setq fname (getfiled "Select a new CSV file" "" "csv" (+ 1 4))) ;Let user choose file
27.            (setq file (open fname "w"))) ;Open the file
28.     (progn ;Group the following statements into the if's then clause
29.       (princ "\"TagName\",\"TagValue\",\"Layer\"" file) ;Write th title row in the file
30.       ;; Step through all blok definitions including Model- & PaperSpace(s) to get even nested stuff
31.       (vlax-for block-definition (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object)))
32.         (vlax-for entity block-definition ;Step through everying inside the block definition
33.           (if (eq (vla-get-ObjectName entity) "AcDbBlockReference") ;Check if current entity is a block insert
34.             (ExportBlockToCSV entity file)))) ;Save it to the file
35.       (close file)))
36.   (princ)) ;Clean exit the command

Edit: forgot to close the file 

[Floris]

Hi Irneb,

Unfortunately I'm getting an "null function :error#9".
Probably because I'm using lisp in an IntelliCAD based program.
Let me check if there is a tool available to convert to regular lisp..

Greetings,
Floris.

[irneb]

It might be that the IntelliCAD product doesn't include the VisualLisp functions (those beginning with vl/vla/vlax). If this is the case, then you have to do this through the old methods (i.e. using the DXF data lists instead of ActiveX object properties/methods). There are a few threads showing something similar:

• http://www.theswamp.org/index.php?topic=43255.0
• http://forums.augi.com/showthread.php?119880-attributes-in-nested-blocks&p=1078628&viewfull=1#post1078628