Topic: How to distinguish between Chinese English？

[Q1241274614]

How to distinguish between Chinese English？

“china”  “中国”

[Marc'Antonio Alessi]

I do not know the answer, this my first try:

Comando: (eq "中" (chr (ascii "中")))
nil

Comando: (eq "C" (chr (ascii "C")))
T

[snownut2]

How about this;

Code: [Select]

(getvar 'locale)


[CAB]

Command: (ver)
"Visual LISP 2006 (en)"

[Lee Mac]

Also:

Code: [Select]

(getvar 'syscodepage)

[chlh_jd]

I don't know what you want .
If you want to get local computer use language , you can use Snownut2's suggest , If you want to split chinese and english , you must use other method . A Chinese characters require two bytes to store, and one letter only one byte, so you can't get a CHS Char by function ascii . However you can use the function vl-string->list , e.g.

Code: [Select]

(vl-string->list "中") --> (214 208)


[Q1241274614]

"2014中国的bell"-->"2"  "1"  "0" "4"  "中"  "国"  "的" "b"  "e"  "l"  "l"

[Lee Mac]

This?

Code - Auto/Visual Lisp: [Select]

1. (defun f ( s )
2.     (if (/= "" s)
3.         (if (= 0 (vl-string-search "\\U+" s))
4.             (cons (substr s 1 7) (f (substr s 8)))
5.             (cons (substr s 1 1) (f (substr s 2)))
6.         )
7.     )
8. )

Code: [Select]

(f "2014中国的bell")
("2" "0" "1" "4" "中" "国" "的" "b" "e" "l" "l")

[chlh_jd]

my version

Code: [Select]

(defun f  (str / l a b r)
  (setq l (vl-string->list str))
  (while l
    (setq a (car l)
  l (cdr l))
    (if (< 128 a 255)
      (setq b (list a (car l))
    l (cdr l))
      (setq b (list a)))
    (setq r (cons b r)))
  (reverse (mapcar (function vl-list->string) r)))


[chlh_jd]

Nice code Lee Mac 
However , yours use Unicode to find Bigfont , it must used in ACAD2007 or Higher version .

[Lee Mac]

Nice code Lee Mac 
However , yours use Unicode to find Bigfont , it must used in ACAD2007 or Higher version .

Thanks chlh_jd - I wasn't aware of this restriction.

[chlh_jd]

You're welcome , Lee 

In ACAD2011 help page "在国际范围内共享图形文件"  -- Share Graphic file  at the international level (I translated) form say it .

When I convert the shx font into sharp by old soft , I found it can't not be compiled by ACAD2011's command 'complie' ;
And a  dwg in ACAD2011 save as ACAD2006 , Special symbols defined with \U+####  can not recognized, even though both have the same shx font files .
I think this is the reason .