Topic: vl-some function

[Coder]

Hello guys .

I hope someone of you experts can explain this function ( vl-some ) to me because I saw this function used a lot and I read about it in the Help document but can not understand it correctly .

Can you give examples please ?

Thanks in advance . 

[Lee Mac]

The vl-some function will evaluate a predicate function on every item in a given list (or lists) with a syntax similar to mapcar, however, vl-some will cease evaluation when the predicate function returns a non-nil value - at which point vl-some will return this value, e.g.:

Iterate over a list until an item is equal to 3:

Code - Auto/Visual Lisp: [Select]

1. _$ (vl-some '(lambda ( x ) (= x 3)) '(0 1 2 3 4 5))
2. T

Adding a print expression to demonstrate the function evaluation:

Code - Auto/Visual Lisp: [Select]

1. _$ (vl-some '(lambda ( x ) (print x) (= x 3)) '(0 1 2 3 4 5))
2.  
3. 0
4. 1
5. 2
6. 3 T

Iterating over two lists until the items in the same position in both lists are equal to 5:

Code - Auto/Visual Lisp: [Select]

1. _$ (vl-some '(lambda ( a b ) (print a) (princ b) (= 5 a b)) '(0 1 2 5 2 6) '(2 1 4 5 2 1))
2.  
3. 0 2
4. 1 1
5. 2 4
6. 5 5T

Or, as a simplified example, testing whether two lists contain equal items at the same index:

Code - Auto/Visual Lisp: [Select]

1. _$ (vl-some '= '(0 1 4 3 6) '(7 2 5 3 2))
2. T

Returning the item itself to demonstrate that vl-some returns the value of the predicate function:

Code - Auto/Visual Lisp: [Select]

1. _$ (vl-some '(lambda ( x ) (if (= (cdr x) "c") x)) '((1 . "a") (2 . "b") (3 . "c") (4 . "d")))
2. (3 . "c")

Finally, here is the formal documentation for vl-some:

http://exchange.autodesk.com/autocad/enu/online-help/browse#WS1a9193826455f5ff1a32d8d10ebc6b7ccc-6882.htm

[Coder]

Waw too much examples  thank you Lee .

Can I say that it's a Boolean function somehow ? there must be at least one non-nil value to return T otherwise it will return nil .

Many thanks

[Lee Mac]

Waw too much examples  thank you Lee .

You're welcome Coder 

Can I say that it's a Boolean function somehow ? there must be at least one non-nil value to return T otherwise it will return nil .

Not really - since vl-some will return the first non-nil value returned by the supplied function, which will not necessarily always be T
(as shown in my last example).

[Lee Mac]

To aid your understanding of the evaluation of vl-some, here is an equivalent version of vl-some written as a recursive function:

Code - Auto/Visual Lisp: [Select]

1. (defun _vl-some ( prd lst )
2.     (cond
3.         ((null lst) nil)
4.         (((eval prd) (car lst)))
5.         ((_vl-some prd (cdr lst)))
6.     )
7. )

Or, iteratively using while:

Code - Auto/Visual Lisp: [Select]

1. (defun _vl-some ( prd lst / itm rtn )
2.     (setq prd (eval prd))
3.     (while
4.         (and
5.             (setq itm (car lst))
6.             (not (setq rtn (prd itm)))
7.         )
8.         (setq lst (cdr lst))
9.     )
10.     rtn
11. )

Code - Auto/Visual Lisp: [Select]

1. _$ (_vl-some '(lambda ( x ) (if (= (cdr x) "c") x)) '((1 . "a") (2 . "b") (3 . "c") (4 . "d")))
2. (3 . "c")

[Coder]

non-nil value does not equal to T ?

[Lee Mac]

non-nil value does not equal to T ?

Not necessarily, a non-nil value could be any value which is not equal to nil, be it a non-empty list, string, integer, real...

[Coder]

You did a great job Lee . thank you so much . 

The last two routines explained it very well . 

[CAB]

Surprised vl-every did not come up.

[Coder]

Surprised vl-every did not come up.

Hi CAB .

I didn't get what you wanted to tell 

[Lee Mac]

You did a great job Lee . thank you so much . 

The last two routines explained it very well . 

Excellent - I'm glad my explanations were clear 

Surprised vl-every did not come up.

I didn't get what you wanted to tell 

CAB's post refers to the fact that vl-every is the AND to vl-some's OR
They are complementary functions 

[Lee Mac]

I also found an older explanation of mine here. 

[Coder]

I also found an older explanation of mine here. 

That is helpful too 

vl-every is a function that checks every element in the list and it returns T if all elements matched the criteria , is that correct ?

Thank you so much for your time and beautiful explanations 

[kruuger]

vl-every is a function that checks every element in the list and it returns T if all elements matched the criteria , is that correct ?

yep,

Code: [Select]

(vl-every
 '(lambda (%)
   (= (type %) 'STR)
  )
  (list "a" "b" "c" 1)
)
return nil

Code: [Select]

(vl-every
 '(lambda (%)
   (= (type %) 'STR)
  )
  (list "a" "b" "c")
)return T. similar to:

Code: [Select]

(apply 'and
  (mapcar
   '(lambda (%)
      (= (type %) 'STR)
    )
    (list "a" "b" "c")
  )
)k.

[Coder]

Thank you so much kruuger for that nice work