Topic: Can't change color for dynamic block

[Coder]

Hello

I have a dynamic block and I want to change the color of all inside objects to red but my code change the color in the main block and not in the drawing .

Also if there is other dynamic blocks it would be changed and not only my block name "Rect" 

I attached the dynamic block .

thanks in advance . 

Code: [Select]

(defun c:color-rect (/)
  (setq mydoct (vla-get-ActiveDocument (vlax-get-acad-object)))
 
 (setq mySel (ssget "_X" (list '(0 . "INSERT")
                                    (cons 2 (strcat "`*U*," "Rect"))))
            )
    (repeat (setq no (sslength mySel))
      (setq sname   (ssname s (setq no (1- no)))
            Blkname (vla-get-effectivename (vlax-ename->vla-object sname)
                      )
      )
      (vlax-for objs (vla-item (vla-get-blocks mydoct) Blkname)
        (vla-put-color objs Acred))
    )
  (command "regen")
)


[Lee Mac]

A few points:

• You are correctly retrieving the effectivename property of the dynamic block, however, will need to test whether the value of this property matches the name of the dynamic block you are looking to change, otherwise other anonymous or dynamic blocks could be modified.

• Since you are processing block references, there could be multiple references of the same block definition being processed; since a block definition only need be processed once, it would be more efficient to check whether a block definition has been processed before iterating over the objects contained therein.

• Since your ssget filter list contains only constant data (literal strings), the entire filter list may be quoted and the group 2 pair does not need to be constructed using cons/strcat. See this article for more information.

Consider the following example:

Code - Auto/Visual Lisp: [Select]

1. (defun c:redblock ( / ano blc bln doc idx lst obj sel )
2.     (while
3.         (not
4.             (or (= "" (setq blk (strcase (getstring t "\nSpecify block name: "))))
5.                 (tblsearch "block" blk)
6.             )
7.         )
8.         (princ (strcat "\nBlock \"" blk "\" not found."))
9.     )
10.     (if (and (/= "" blk) (setq sel (ssget "_X" (list '(0 . "INSERT") (cons 2 (strcat "`*U*," blk))))))
11.         (progn
12.             (setq doc (vla-get-activedocument (vlax-get-acad-object))
13.                   blc (vla-get-blocks doc)
14.             )
15.             (repeat (setq idx (sslength sel))
16.                 (setq obj (vlax-ename->vla-object (ssname sel (setq idx (1- idx))))
17.                       ano (strcase (vla-get-name obj))
18.                       bln (strcase (LM:blockname obj))
19.                 )
20.                 (if (and (= blk bln) (not (member ano lst)))
21.                     (progn
22.                         (vlax-for obj (vla-item blc ano)
23.                             (if (vlax-write-enabled-p obj)
24.                                 (vla-put-color obj acred)
25.                             )
26.                         )
27.                         (setq lst (cons ano lst))
28.                     )
29.                 )
30.             )
31.             (vla-regen doc acallviewports)
32.         )
33.     )
34.     (princ)
35. )
36.  
37. ;; Block Name  -  Lee Mac
38. ;; Returns the true (effective) name of a supplied block reference
39.                        
40. (defun LM:blockname ( obj )
41.     (if (vlax-property-available-p obj 'effectivename)
42.         (defun LM:blockname ( obj ) (vla-get-effectivename obj))
43.         (defun LM:blockname ( obj ) (vla-get-name obj))
44.     )
45.     (LM:blockname obj)
46. )
47. (vl-load-com) (princ)

[Coder]

Thank you for your help but I have one question please .

why did you add the name of the block (ano) to the list and not the effective name (bln) ?
is is the same result in this case or another thing I can not see ? 

Many thanks .

[Coder]

• Since your ssget filter list contains only constant data (literal strings), the entire filter list may be quoted and the group 2 pair does not need to be constructed using cons/strcat. See this article for more information.

That's also a very good point ( I got it ) , thanks a lot . 

[Lee Mac]

why did you add the name of the block (ano) to the list and not the effective name (bln) ?
is is the same result in this case or another thing I can not see ? 

Because the effective name will be the same for all references of the dynamic block, whereas the block name (usually anonymous) will be different for each set of references of the dynamic block holding different values for the dynamic block parameters.

If the effective name was added to the list, the program would only process references of the first anonymous block encountered, or only non-anonymous references.

[Lee Mac]

• Since your ssget filter list contains only constant data (literal strings), the entire filter list may be quoted and the group 2 pair does not need to be constructed using cons/strcat. See this article for more information.

That's also a very good point ( I got it ) , thanks a lot . 

Excellent - you're welcome! 

[Coder]

why did you add the name of the block (ano) to the list and not the effective name (bln) ?
is is the same result in this case or another thing I can not see ? 

Because the effective name will be the same for all references of the dynamic block, whereas the block name (usually anonymous) will be different for each set of references of the dynamic block holding different values for the dynamic block parameters.

If the effective name was added to the list, the program would only process references of the first anonymous block encountered, or only non-anonymous references.

Great , I have been struggling for almost two days now because of the effective name that I added to the lst variable and not the block name  :ugly:

now it is running as i need it because of your great help . 

Many many thanks .

[Lee Mac]

You're most welcome Coder - I'm delighted that you understand 

[Coder]

Hello Lee .

One small question please . 

If I change the ssget function to (ssget "_:L") this will change ONLY the color of the same block name in the drawing but if I keep it (ssget "_X") , it is changing all blocks and the Block definition
of the same name of the block .

is that normal  ?

Many thanks

[Lee Mac]

If I change the ssget function to (ssget "_:L") this will change ONLY the color of the same block name in the drawing but if I keep it (ssget "_X") , it is changing all blocks and the Block definition
of the same name of the block .

is that normal  ?

Yes, because not all of the anonymous block references are being processed, only those that the user has selected.

[Coder]

If I change the ssget function to (ssget "_:L") this will change ONLY the color of the same block name in the drawing but if I keep it (ssget "_X") , it is changing all blocks and the Block definition
of the same name of the block .

is that normal  ?

Yes, because not all of the anonymous block references are being processed, only those that the user has selected.

Thank you so much . 

Can I say that dynamic blocks definitions are similar to attributed blocks definitions somehow ? I am talking about  ( attributes ) in blocks .

Thanks .

[Lee Mac]

Thank you so much . 

 

Can I say that dynamic blocks definitions are similar to attributed blocks definitions somehow ? I am talking about  ( attributes ) in blocks .

I suppose they are similar on some levels in that the properties of the attribute references for a block reference can be modified independently of the block definition, though, note that where the attribute references are separate from the block definition for every reference of the block, the anonymous block definition generated when the dynamic block properties of a block reference are altered may reference multiple blocks - namely, all references of the dynamic block sharing the same dynamic block properties.

It may be better to think about it as each dynamic block reference which possesses a different set of dynamic block properties being a different block entirely, referencing its own [anonymous] block definition; all of these separate anonymous blocks are then tied to the main dynamic block using the effective name and identifiers stored in xdata.

[Jeff H]

Nothing new as Lee already gave a nice explanation,
but a BlockReference

• Pushes transformation matrixes on a stack in the graphics pipeline
• Draws the entities in the Block Definition
• Pops the transformations off.

So a BlockReference is nothing but a set of transformations to be applied to its definition as in scale, position, rotation, and other properties common to all entities like color, linetype, etc....
When it encounters a non-constant AttributeDefinition it creates a AttributeReference that is attached to the BlockReference.

A block definition can not have different states or vary between blockreferences that reference it since they just transform it as mentioned above.

A dynamic block just has parameters and the arguments passed in by a stretch or rotation grip or directly entered in properties palette, etc... are used to create another BlockDefinition(I think it searches first if one is already created with same values).

I and not familiar with AutoLisp but,  I do know how to steal it.
Did a quick search and first thing I found that was 4 lines or less was from Lee.
I made a minor adjustment which removes a "*" from the beginning of blocks name.
Now anonymous blocks will show up in the block editor.

If you want to see them insert some dynamic blocks and change some of the properties for each BlockReference.
Also add some tables and dimensions if you want to see that they are really just anonymous blocks.
Then run the code below. Would use only on a test drawing and not on any drawing you would want for future use.

Link to original code stolen from Lee.

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / name ) (vl-load-com)
2.     (vlax-for block (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
3.         (if (wcmatch (setq name (vla-get-name block)) "`**")
4.             (vl-catch-all-apply 'vla-put-name (list block (substr name 2))))
5.         )
6.     )
7.     (princ)
8.  

Tables are named T1, T2, T3
Dimensions are D1, D2, etc..
Dynamic Blocks create names U1, U2, U3, etc....

In case you were wondering
BlockReferences contain the properties BlockTableRecord , DynamicBlockTableRecord & AnonymousBlockTableRecord.

BlockTableRecord
Accesses the object ID of the BlockTableRecord referenced by the block reference.

DynamicBlockTableRecord
Returns the object ID of the dynamic block definition (a BlockTableRecord) if the block reference is a dynamic block.

AnonymousBlockTableRecord
Returns the anonymous block definition used to draw the dynamic block.

BlockTableRecord always points to its definition.

If it is not dynamic or no properties have been change to a dynamic block then

• DynamicBlockTableRecord & BlockTableRecord are the same
• AnonymousBlockTableRecord is null(nill)

If properties have been change to a dynamic block then

• DynamicBlockTableRecord  points to the dynamic block definition
• AnonymousBlockTableRecord & BlockTableRecord are the same

[Coder]

Thank you Jeff so much .

It is very kind of you to write all that for me to understand the differences between blocks , that is great .

Many thanks again . 

[Lee Mac]

Great supplement Jeff, thanks for your input