Topic: Trimm extend between civil3D objects

[cadplayer]

Hello!

I have a question to my problem with civil3d objects. I want create a closed Polyline between terrass- and ground-sectioObject. That means I have done a sectionview in Civil3d that haves 2 objects (look picture "before"). Object 1 have this properties:

((-1 . <Entity name: 7ffff861530>) (0 . "AECC_SECTION") (330 . <Entity name: 7ffff8139f0>) (5 . "11565B") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "SEKTION") (100 . "AeccDbEntity") (100 . "AeccDbGeo_aec") (100 . "AeccDbGeo") (100 . "AeccDbSection"))

If I list entity 330 I see that is a block
((-1 . <Entity name: 7ffff8139f0>) (0 . "BLOCK_RECORD") (5 . "1F") (102 . "{ACAD_XDICTIONARY") (360 . <Entity name: 7ffff81ff70>) (102 . "}") (330 . <Entity name: 7ffff813810>) (100 . "AcDbSymbolTableRecord") (100 . "AcDbBlockTableRecord") (2 . "*Model_Space") (360 . <Entity name: 7ffff813a00>) (340 . <Entity name: 7ffff813a20>) (70 . 0) (280 . 1) (281 . 0))

I have no idea how I can find in VLA correctly object.

In the end I want create a closed Polyline looks like pict. "after"

[Jeff_M]

Using the ActiveX objects... (setq obj (vlax-ename->vla-object (car (entsel)))) ... this gives you an AeccSection object which has a Links property from which you can gather the points to create a polyline with. However, in my testing I have found that the Datum section returns some invalid points outside the daylight points. I've posted about this on the Autodesk C3D customization forum: HERE . Here's the lisp I used to get to that point, perhaps it will help you with completing the chore.

Code - Auto/Visual Lisp: [Select]

1. ;;select vla-object
2. (defun vl-sel (/ ent)
3.   (if (setq ent (car (entsel "\nSelect object: ")))
4.     (vlax-ename->vla-object ent)
5.     )
6.   )
7.  
8. ;;convert a C3D section object to a list of points from which a polyline
9. ;; may be created
10. (defun getpointlist (sctn / links idx link start end ptlist)
11.   (setq links (vlax-get-property sctn 'links))
12.   (setq idx -1)
13.   (while (< (setq idx (1+ idx)) (vlax-get links 'count))
14.     (setq link  (vlax-invoke links 'item idx)
15.           start (cons (vlax-get link 'startpointx) (vlax-get link 'startpointy))
16.           end   (cons (vlax-get link 'endpointx) (vlax-get link 'endpointy))
17.     )
18.     (if (not (member start ptlist))
19.       (setq ptlist (cons start ptlist))
20.     )
21.     (if (not (member end ptlist))
22.       (setq ptlist (cons end ptlist))
23.     )
24.   )
25.   (setq ptlist (reverse ptlist))
26. )
27.  
28.  
29. ;;select the ground section, then the datum section
30. (setq grnd (vl-sel)
31.       dtm  (vl-sel)
32. )
33. ;;get the points
34. (setq grndpts (getpointlist grnd)
35.       datumpts (getpointlist dtm)
36.       )
37.  

[Jeff_M]

Here's a more complete version that correctly draws a polyline. Remember, if you want the areas you will need to compensate for any vertical exaggeration.

I leave it up to you to make it work continuously and/or automatically.

Code - Auto/Visual Lisp: [Select]

1. (defun c:drawpolyonsection (/ datumpts doc dtm grnd grndpts mspace pline prunedpts sctnvw)
2.  
3.   ;;select vla-object
4.   (defun vl-sel (msg / ent)
5.     (if (setq ent (car (entsel msg)))
6.       (vlax-ename->vla-object ent)
7.     )
8.   )
9.  
10.   ;;convert a C3D section object to a list of points from which a polyline
11.   ;; may be created
12.   (defun getpointlist
13.          (sctn sctnvw / links idx link start end ptlist x y)
14.     (setq links (vlax-get-property sctn 'links))
15.     (setq idx -1)
16.     (while (< (setq idx (1+ idx)) (vlax-get links 'count))
17.       (setq link (vlax-invoke links 'item idx))
18.       (vlax-invoke-method
19.         sctnvw
20.         'FindXYAtStationOffsetAndElevation
21.         0
22.         (vlax-get link 'startpointx)
23.         (vlax-get link 'startpointy)
24.         'x
25.         'y
26.       )
27.       (setq start (cons x y))
28.       (vlax-invoke-method
29.         sctnvw
30.         'FindXYAtStationOffsetAndElevation
31.         0
32.         (vlax-get link 'endpointx)
33.         (vlax-get link 'endpointy)
34.         'x
35.         'y
36.       )
37.       (setq end (cons x y)
38.       )
39.       (if (= (vlax-get link 'type) 0)
40.         ;;this link is displayed
41.         (progn
42.           (if (not (member start ptlist))
43.             (setq ptlist (cons start ptlist))
44.           )
45.           (if (not (member end ptlist))
46.             (setq ptlist (cons end ptlist))
47.           )
48.         )
49.       )
50.     )
51.     (setq ptlist (reverse ptlist))
52.   )
53.  
54.   (defun flattenlist (lst / result)
55.     (foreach l lst
56.       (setq result (cons (car l) result)
57.             result (cons (cdr l) result)
58.       )
59.     )
60.     result
61.   )
62.  
63.  
64.   ;;selct the ground section, then the datum section, then the sectionview
65.   (setq grnd   (vl-sel "\nSelect ground section: ")
66.         dtm    (vl-sel "\nSelect datum section: ")
67.         sctnvw (vl-sel "\nSelect SectionView: ")
68.   )
69.   ;;get the points, all start from left and go to the right
70.   (setq grndpts  (getpointlist grnd sctnvw)
71.         datumpts (getpointlist dtm sctnvw)
72.   )
73.  
74.  
75.   ;;use the points to construct pline. Omit the ground points outside the limits of the datum
76.   (setq prunedpts nil)
77.   (foreach pt grndpts
78.     (if (and (> (car pt) (caar datumpts))
79.              (< (car pt) (car (last datumpts)))
80.         )
81.       (setq prunedpts (cons pt prunedpts))
82.     )
83.   )
84.   (setq doc    (vla-get-activedocument (vlax-get-acad-object))
85.         mspace (vla-get-modelspace doc)
86.   )
87.   (setq pline (vlax-invoke
88.                 mspace
89.                 'addlightweightpolyline
90.                 (reverse (flattenlist (append datumpts prunedpts)))
91.               )
92.   )
93.   (vla-put-closed pline :vlax-true)
94.   (princ)
95. )
96.  

[cadplayer]

Thatīs very nice done - thank you for your work Jeff.