Topic: lambda with strings

[cadplayer]

Hello!

I need help with a string like this "Cut=\"172.87\"" to get two strings
 -"Cut" 
 -"172.87"
My try is to read string after = 
symbol (x) get "Cut"
symbol (y) get "172.87"

But it doesn´t work in anonym function, I have no expierence with lambda...

Code: [Select]

(setq str "Cut=\"172.87\"")
                                  (function 
                                      (lambda (x y)
                                          (strcat
                                              (if (setq x (cdr (member 61 (reverse (vl-string->list x)))))
                                                  (setq x (vl-list->string (reverse x)))
                                                  )
                                              (if (setq y (cdr (member 61 (vl-string->list y))))
                                                  (vl-list->string (vl-remove-if-not '(lambda(X)(member X (vl-string->list "0123456789."))) y))
                                                  )
                                              )
                                          )
                                      )

[Tharwat]

Maybe without lambda ...

Code - Auto/Visual Lisp: [Select]

1. (setq str "Cut=\"172.87\"")
2.  
3. (if (setq p (vl-string-search "=" str))
4.   (setq cut (substr str 1 p))
5. )
6.  
7. (setq no (vl-list->string
8.            (vl-remove-if-not
9.              '(lambda (x)
10.                 (member x '(46 48 49 50 51 52 53 54 55 56 57))
11.               )
12.              (vl-string->list str)
13.            )
14.          )
15. )
16.  

[cadplayer]

Thanks it works fine and good suggestion, I build in as helper function...

[Tharwat]

Thanks it works fine and good suggestion, I build in as helper function...

You're welcome , and very happy to help . 

[BlackBox]

FWIW - Here's a couple more ways of doing this, and a quick speed test... Each function tested returns a list of strings:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun _foo1 (str / p)
4.   (if (setq p (vl-string-search "=" str))
5.     (list
6.       (substr str 1 p)
7.       (vl-list->string
8.         (vl-remove-if-not
9.           '(lambda (x)
10.              (member x '(46 48 49 50 51 52 53 54 55 56 57))
11.            )
12.           (vl-string->list str)
13.         )
14.       )
15.     )
16.   )
17. )
18.  
19. (defun _foo2 (str / p)
20.   (if (setq p (vl-string-search "=" str))
21.     (list
22.       (substr str 1 p)
23.       (vl-string-right-trim
24.         "\""
25.         (vl-string-left-trim "\"" (substr str (+ 2 p)))
26.       )
27.     )
28.   )
29. )
30.  
31. (defun _foo3 (str / p)
32.   (if (setq p (vl-string-search "=" str))
33.     (list
34.       (substr str 1 p)
35.       (rtos (atof (vl-string-translate "\"" "0" (substr str (+ 2 p))))
36.             2
37.             2
38.       )
39.     )
40.   )
41. )
42.  

... Results from console:

Code - Auto/Visual Lisp: [Select]

1. _$ (bench '(_foo1 _foo2 _foo3) '("Cut=\"172.87\"") 10000)
2.  
3. _FOO1
4. Elapsed: 577
5. Average: 0.0577
6.  
7. _FOO2
8. Elapsed: 78
9. Average: 0.0078
10.  
11. _FOO3
12. Elapsed: 110
13. Average: 0.0110
14.  
15. _$
16.  

[cadplayer]

cool trials
bench is it your own measure-tool?

[BlackBox]

cool trials
bench is it your own measure-tool?

No, it's actually R. Robert Bell's routine (AU Instructor, etc.), but he granted me permission to post it publicly here.

[cadplayer]

Thanx Blackbox: could be useful

[BlackBox]

Thanx Blackbox: could be useful

You're welcome; I'm happy to help. :beer:

I do not find any value from this in production directly, but it is a useful utility for testing various ways of doing the same thing... There are many times, when I will not use the fastest, but instead use one close in speed, but easier to read, or provides a slightly different returned value based on usability with/without ObjectDBX, etc.... But one cannot make an informed decision without the applicable information.

Cheers

[Lee Mac]

Code - Auto/Visual Lisp: [Select]

1. (defun _foo2 (str / p)
2.   (if (setq p (vl-string-search "=" str))
3.     (list
4.       (substr str 1 p)
5.       (vl-string-right-trim
6.         "\""
7.         (vl-string-left-trim "\"" (substr str (+ 2 p)))
8.       )
9.     )
10.   )
11. )

For what its worth, the left & right string trim could be replaced by a single vl-string-trim:

Code - Auto/Visual Lisp: [Select]

1. (defun parse ( s / p )
2.     (if (setq p (vl-string-position 61 s))
3.         (list (substr s 1 p) (vl-string-trim "\"" (substr s (+ 2 p))))
4.     )
5. )