Topic: Grab all...

[MeasureUp]

After arrying (5 columns) an object, how to get all the 5 objects?
l want to change the layer of the 5 objects and make them as a black.
Thanks in advance.

[Tharwat]

The array command or so , is just a copy of the original object  AFAIK .

Can you show the code that you used to make that array ?

[MeasureUp]

I haven't actually started the code but the following is the idea:

Code: [Select]

(defun c:Test (/ Ent)
(command "_.point")
(setq Ent (Entlast))
(command "_.-array" Ent "" "Rectangular" 5 1 100)

; grab the 5 obiects created above
; then change layer and make them to a block
)

Thanks

[fixo]

Try this one but adopt to your needs

Code: [Select]

(defun c:sb (/ pt Ent ss)
(setq ss (ssadd))
(setq pt (getpoint "\nPick first point:")
      )
(entmake
(list
(cons 0 "POINT")
(cons 100 "AcDbEntity")
(cons 100 "AcDbPoint")
(cons 10 pt)
(cons 8  "0")
)
)
(setq Ent (Entlast))
(command "_.-array" Ent "" "Rectangular" 5 1 100)
  (command "_.zoom" "_e")
(setq ss (ssadd Ent ss))
(repeat 4 (setq Ent (entnext Ent))
(ssadd Ent ss)
);repeat
 
; grab the 5 obiects created above
; then change layer and make them to a block
(command "_.chprop" ss "" "_LA" "MyCoolLayer" "" "");<-- change layer name here
(command "-block" "MyBlock" pt ss  "");<-- change block name here
  (command "_.zoom" "_p")
(princ)
)

[Tharwat]

Try this instead of the array command .

Code - Auto/Visual Lisp: [Select]

1. (defun c:Test (/ *error* showdcl checkitout blk p on i j pt sad)
2. ;;;--- Tharwat 14. May. 2013 ---;;;
3.   (or doc
4.       (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
5.   )
6.   (defun *error* (x)
7.     (if doc
8.       (vla-endundomark doc)
9.     )
10.     (if f
11.       (progn (close f) (vl-file-delete fn))
12.     )
13.     (princ "\n*Cancel*")
14.   )
15.   (defun ShowDcl (/ sn f str dcl_id l lays pos)
16.     (setq fn (vl-filename-mktemp "dcl.dcl"))
17.     (setq f (open fn "w"))
18.     (foreach str
19.              (list
20.                "Layers : dialog { label = \"Layer List\"; fixed_width = true;"
21.                ": popup_list { label = \"Select Layer\"; key = \"layer\"; width = 32;}"
22.                ": boxed_row { label = \"Action\";" ": row {"
23.                ": button { label = \"Accept\"; key = \"accept\"; is_default = true;  }"
24.                ": button { label = \"Cancel\"; key = \"cancel\"; is_cancel = true; }}}}"
25.               )
26.       (write-line str f)
27.     )
28.     (close f)
29.     (setq dcl_id (load_dialog fn))
30.     (if (not (new_dialog "Layers" dcl_id))
31.       (exit)
32.     )
33.     (while (setq l (tblnext "LAYER" (not l)))
34.       (setq lays (cons (cdr (assoc 2 l)) lays))
35.     )
36.     (setq lays (reverse lays))
37.     (start_list "layer")
38.     (mapcar 'add_list lays)
39.     (end_list)
40.     (action_tile
41.       "accept"
42.       "(setq pos (get_tile \"layer\"))(done_dialog)"
43.     )
44.     (action_tile "cancel" "(done_dialog)")
45.     (start_dialog)
46.     (unload_dialog dcl_id)
47.     (if pos
48.       (princ (nth (atoi pos) lays))
49.     )
50.   )
51.   (defun CheckItOut (/ blk)
52.     (while (and (setq blk (getstring t "\n specify New Block name :"))
53.                 (tblsearch "BLOCK" blk)
54.            )
55.       (princ "\n Block is already existed ! < Try again > ")
56.     )
57.     (if (not (tblsearch "BLOCK" blk))
58.       blk
59.     )
60.   )
61.   (if (and (setq p (getpoint "\n Specify point :"))
62.            (setq blk (CheckItOut))
63.            (setq on (ShowDcl))
64.       )
65.     (progn
66.       (vl-file-delete fn)
67.       (vla-StartUndomark doc)
68.       (setq sad (ssadd))
69.       (setq i  0
70.             pt p
71.       )
72.       (ssadd (entmakex (list '(0 . "POINT") (cons 10 p) (cons 8 on)))
73.              sad
74.       )
75.       (repeat 4
76.         (setq p (polar p (* pi 0.5) 100))
77.         (ssadd (entmakex (list '(0 . "POINT") (cons 10 p) (cons 8 on)))
78.                sad
79.         )
80.       )
81.       (command "_.-block" blk "_none" pt sad "")
82.       (command "_.-insert" blk "_none" pt "" "" "")
83.       (vla-put-layer (vlax-ename->vla-object (entlast)) on)
84.       (vla-endundomark doc)
85.     )
86.   )
87.   (princ "\n Written By Tharwat Al Shoufi")
88.   (princ)
89. )
90.  
91.  

[MeasureUp]

Thanks to fixo & Tharwat.
fixo: your solution provides a few lines and simple explanation in the code. Neat is the word.
Tharwat: you are a LG = Lisp Giant.
Many thanks to both of you!

BTW. how to make this work if the source object arraying to a sepecified path (two points)?
Please see my another thread "How to array object to a path by selecting 2 points?"

[Tharwat]

Thanks to fixo & Tharwat.
Tharwat: you are a LG = Lisp Giant.

You're welcome .

I am also still learning and not a Lisp Giant yet