Topic: Select objects inside 3D solid - SOLVED -

[ribarm]

I grouped every pair of sphere-block, after using your lisp only spheres are selected not the entire group.
another way to link them?

tried Gccoincident but only works with 2d objects

For linking purposes, I stated GROUPS, but there are more ways : XDATA, LDATA, LAYER, and so on...
Could you try to GROUP/LINK by LAYER for ex...
After your SOLIDS have been highlighted, you could qselect with LAYER matching filter, and choose non SOLID entity types, do SELECT command, press ENTER, qselect with LAYER matching filter, choose only SOLID entity types, hit DEL and finally you'll have (sssetfirst nil (ssget "_P"))...

[It's Alive!]

I compiled this for 2018 (R22), I can't test it
if it does load call the lisp function (getBlocksInsidesolid)

[nekonihonjin]

Bummer, yeah you can probably get the solid and decode it (http://www.theswamp.org/index.php?topic=25097.0)
You should be able to build a list of planes from the face vertexs, then do the ray trace thing. 
I noticed some plane functions here (http://www.theswamp.org/index.php?topic=40494.msg457913#msg457913)

here's the list of objects I found.. though it seems the ID is not unique

ID = BJ1-106
ID = BJ1-106
ID = BJ1-106
ID = BJ1-140
ID = BJ1-108
ID = BJ1-102
ID = BJ1-140
ID = BJ1-125
ID = BJ1-102
ID = BJ1-143
ID = BJ1-132
ID = BJ1-132
ID = BJ1-119
ID = BJ1-115
ID = BJ1-145
ID = BJ1-141
ID = BJ1-131
ID = BJ1-129
ID = BJ1-127
ID = BJ1-122
ID = BJ1-12
ID = BJ1-117
ID = BJ1-107
ID = BJ1-106
ID = BJ1-10

before uploading the file I just copied some of them to make more evident what I want, but in a real job it'll be unique.

[nekonihonjin]

I grouped every pair of sphere-block, after using your lisp only spheres are selected not the entire group.
another way to link them?

tried Gccoincident but only works with 2d objects

For linking purposes, I stated GROUPS, but there are more ways : XDATA, LDATA, LAYER, and so on...
Could you try to GROUP/LINK by LAYER for ex...
After your SOLIDS have been highlighted, you could qselect with LAYER matching filter, and choose non SOLID entity types, do SELECT command, press ENTER, qselect with LAYER matching filter, choose only SOLID entity types, hit DEL and finally you'll have (sssetfirst nil (ssget "_P"))...

Thanks Marko, gonna try the layer thing now...

[nekonihonjin]

Marko, again asking for your help, would it be possible to modify your code so that, instead of checking for interference between each and every one of the solids, it would check only using the first one as a base/pivot and only those that interfere with it?

[ribarm]

Marko, again asking for your help, would it be possible to modify your code so that, instead of checking for interference between each and every one of the solids, it would check only using the first one as a base/pivot and only those that interfere with it?

Code - Auto/Visual Lisp: [Select]

1. (defun c:chk3DSOLint ( / *error* s sol_ sol n interf sol_interf ss )
2.  
3.   (vl-load-com)
4.  
5.   (defun *error* ( msg )
6.     (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
7.     (if msg (prompt msg))
8.     (princ)
9.   )
10.  
11.   (vla-startundomark (vla-get-activedocument (vlax-get-acad-object)))
12.   (if
13.     (and
14.       (princ "\nSelect MAIN 3D SOLID")
15.       (setq s (ssget "_+.:E:S" '((0 . "3DSOLID"))))
16.       (while (null sol_)
17.         (princ "\nSelect CHECKING 3D SOLIDS")
18.         (setq sol_ (ssget "_:L" '((0 . "3DSOLID"))))
19.         (if (null sol_)
20.           (prompt "\nEmpty sel. set... Try selecting again...")
21.           sol_
22.         )
23.       )
24.     )
25.     (progn
26.       (if (ssmemb (ssname s 0) sol_)
27.         (ssdel (ssname s 0) sol_)
28.       )
29.       (repeat (setq n (sslength sol_))
30.         (setq sol (cons (ssname sol_ (setq n (1- n))) sol))
31.       )
32.       (setq interf 0)
33.       (mapcar
34.         (function (lambda ( a )
35.           (if (vla-checkinterference (vlax-ename->vla-object a) (vlax-ename->vla-object (ssname s 0)) :vlax-true 'test)
36.             (progn
37.               (setq sol_interf (cons a sol_interf))
38.               (setq interf (1+ interf))
39.               (entdel (entlast))
40.             )
41.           )
42.         ))
43.         sol
44.       )
45.       (setq ss (ssadd))
46.       (foreach ent sol_interf (ssadd ent ss))
47.       (sssetfirst nil ss)
48.       (princ
49.         (strcat
50.           "\nNumber of checked 3D SOLIDS : " (itoa (sslength ss))
51.           "\nNumber of interferences : " (itoa interf)
52.         )
53.       )
54.     )
55.   )
56.   (*error* nil)
57. )
58.  

HTH.

[nekonihonjin]

Marko, again asking for your help, would it be possible to modify your code so that, instead of checking for interference between each and every one of the solids, it would check only using the first one as a base/pivot and only those that interfere with it?

Code: [Select]

(defun c:chk3DSOLint ( / *error* s sol_ sol n interf sol_interf ss )

  (vl-load-com)

  (defun *error* ( msg )
    (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
    (if msg (prompt msg))
    (princ)
  )

  (vla-startundomark (vla-get-activedocument (vlax-get-acad-object)))
  (if (and
      (princ "\nSelect MAIN 3D SOLID")
      (setq s (ssget "_.+:E:S" '((0 . "3DSOLID"))))
      (princ "\nSelect CHECKING 3D SOLIDS")
      (while (null sol_)
        (setq sol_ (ssget "_:L" '((0 . "3DSOLID"))))
        (if (null sol_) (prompt "\nEmpty sel. set... Try selecting again...") sol_ )
      )
    )
    (progn
      (repeat (setq n (sslength sol_))
        (setq sol (cons (ssname sol_ (setq n (1- n))) sol))
      )
      (mapcar
        (function (lambda ( a )
          (if (vla-CheckInterference (vlax-ename->vla-object a) (vlax-ename->vla-object (ssname s 0)) :vlax-true 'test)
            (progn
              (setq sol_interf (cons a sol_interf))
              (entdel (entlast))
              (setq interf (1+ interf))
            )
          )
        ))
        sol
      )
      (setq ss (ssadd))
      (foreach ent sol_interf (ssadd ent ss))
      (sssetfirst nil ss)
      (princ
        (strcat
          "\nNumber of checked 3D SOLIDS : " (itoa (sslength ss))
          "\nNumber of interferences : " (itoa interf)
        )
      )
    )
  )
  (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
  (princ)
)

HTH.

Thanks for the quick response, it says      --bad ssget mode string-- 
as I try to use it. 


changed the first sseget to     ssget "_:L"    and now it allows me to select the objects (it's posible to select more than one 3d solid now, but I select the main one and then enter, but after selecting the next set, it returns: --  bad argument type: numberp: nil --

[ribarm]

I've fixed it in my post...

[ribarm]

I suppose this is what you were aiming to/for :

Code - Auto/Visual Lisp: [Select]

1. (defun c:chk3DSOLint-processlinks ( / *error* mid s en ex sel elst n counter layname bb sph bbx sphx minpt maxpt midpt assoclst sol interf sol_interf ss dx dy dz ) ;; *templayprefix* - global variable ;; cad ; doc ; spc ; alo - main globals
2.  
3.   (or cad (progn (vl-load-com) (setq cad (vlax-get-acad-object))))
4.   (or doc (setq doc (vla-get-activedocument cad)))
5.   (or spc (setq spc (vla-get-block (setq alo (vla-get-activelayout doc)))))
6.  
7.   (defun *error* ( msg )
8.     (vla-endundomark doc)
9.     (if msg
10.       (prompt msg)
11.     )
12.     (princ)
13.   )
14.  
15.   (defun mid ( p1 p2 )
16.     (mapcar (function (lambda ( a b ) (/ (+ a b) 2.0))) p1 p2)
17.   )
18.  
19.   (vla-startundomark doc)
20.   (if
21.     (and
22.       (princ "\nSelect MAIN 3D SOLID")
23.       (setq s (ssget "_+.:E:S" (list (cons 0 "3DSOLID"))))
24.       (setq en (ssname s 0))
25.       (while (not sel)
26.         (princ "\nSelect CHECKING ENTITIES")
27.         (setq sel (ssget))
28.         (if (not sel)
29.           (prompt "\nEmpty sel. set... Try selecting again...")
30.           sel
31.         )
32.       )
33.       (not (initget "BB SPH"))
34.       (or (setq ch (getkword "\nChoose option [BB / SPH] <BB> : ")) (setq ch "BB"))
35.       (or *templayprefix* (setq *templayprefix* (cond ( (/= (setq *templayprefix* (getstring t "\nSpecify temporary layer prefix <\"link_\"> : ")) "") *templayprefix* ) ( t "link_" ))))
36.     )
37.     (progn
38.       (if (ssmemb en sel)
39.         (ssdel en sel)
40.       )
41.       (repeat (setq n (sslength sel))
42.         (setq elst (cons (ssname sel (setq n (1- n))) elst))
43.       )
44.       (setq counter 0)
45.       (foreach e elst
46.         (while (tblsearch "LAYER" (setq layname (strcat *templayprefix* (itoa (setq counter (1+ counter)))))))
47.         (cond
48.           ( (/= (cdr (assoc 0 (entget e))) "3DSOLID")
49.             (vla-getboundingbox (vlax-ename->vla-object e) 'minpt 'maxpt)
50.             (mapcar (function set) (list (quote minpt) (quote maxpt)) (mapcar (function safearray-value) (list minpt maxpt)))
51.             (setq midpt (mid minpt maxpt))
52.             (if (= ch "BB")
53.               (setq bb (vla-addbox spc (vlax-3d-point midpt) (if (> (setq dx (- (nth 0 maxpt) (nth 0 minpt))) 0) dx 1e-3) (if (> (setq dy (- (nth 1 maxpt) (nth 1 minpt))) 0) dy 1e-3) (if (> (setq dz (- (nth 2 maxpt) (nth 2 minpt))) 0) dz 1e-3)))
54.               (setq sph (vla-addsphere spc (vlax-3d-point midpt) 1.0))
55.             )
56.             (if (= ch "BB")
57.               (progn
58.                 (setq bbx (entget (vlax-vla-object->ename bb)))
59.                 (entupd (cdr (assoc -1 (entmod (subst (cons 8 layname) (assoc 8 bbx) bbx)))))
60.                 (setq sol (cons (vlax-vla-object->ename bb) sol))
61.               )
62.               (progn
63.                 (setq sphx (entget (vlax-vla-object->ename sph)))
64.                 (entupd (cdr (assoc -1 (entmod (subst (cons 8 layname) (assoc 8 sphx) sphx)))))
65.                 (setq sol (cons (vlax-vla-object->ename sph) sol))
66.               )
67.             )
68.           )
69.           ( t
70.             (setq ex (entget (vlax-vla-object->ename (vla-copy (vlax-ename->vla-object e)))))
71.             (setq sol (cons (entupd (cdr (assoc -1 (entmod (subst (cons 8 layname) (assoc 8 ex) ex))))) sol))
72.           )
73.         )
74.         (setq assoclst (cons (list layname e) assoclst))
75.       )
76.       (setq interf 0)
77.       (mapcar
78.         (function (lambda ( x / el chk )
79.           (setq el (entlast))
80.           (if (and en (not (vl-catch-all-error-p (setq chk (vl-catch-all-apply (function vla-checkinterference) (list (vlax-ename->vla-object x) (vlax-ename->vla-object en) :vlax-true 'test))))) chk)
81.             (progn
82.               (setq sol_interf (cons x sol_interf))
83.               (setq interf (1+ interf))
84.               (if (not (eq el (entlast)))
85.                 (while (setq el (entnext el))
86.                   (entdel el)
87.                 )
88.               )
89.               (if (vlax-erased-p en)
90.                 (entdel en)
91.               )
92.             )
93.           )
94.         ))
95.         sol
96.       )
97.       (setq ss (ssadd))
98.       (foreach ent sol_interf
99.         (if (and ent (not (vlax-erased-p ent)))
100.           (ssadd (cadr (assoc (setq layname (cdr (assoc 8 (entget ent)))) assoclst)) ss)
101.         )
102.       )
103.       (foreach ent sol
104.         (if (and ent (not (vlax-erased-p ent)))
105.           (progn
106.             (setq layname (cdr (assoc 8 (entget ent))))
107.             (entdel ent)
108.             (vla-delete (vla-item (vla-get-layers doc) layname))
109.           )
110.         )
111.       )
112.       (sssetfirst nil ss)
113.       (princ
114.         (strcat
115.           "\nNumber of interferences : " (itoa interf)
116.           "\nNumber of highlighted entities inside boundary MAIN 3DSOLID : " (itoa (sslength ss))
117.         )
118.       )
119.     )
120.   )
121.   (*error* nil)
122. )
123.  

HTH.

[nekonihonjin]

I've fixed it in my post...

perfect! thanks a lot man.

the code from last post it's not working for some reason, but with the one you just fixed it's more than enough.

[ribarm]

I've fixed it in my post...

perfect! thanks a lot man.

the code from last post it's not working for some reason, but with the one you just fixed it's more than enough.

Can you check it once again, have changed some minor mistakes...

[nekonihonjin]

I've fixed it in my post...

perfect! thanks a lot man.

the code from last post it's not working for some reason, but with the one you just fixed it's more than enough.

Can you check it once again, have changed some minor mistakes...

still error, but not the same, if I select "BB" it says "bb too few actual parameters".
if I choose "SPH" it creates a sphere only in one block and then it says "bad argument type: stringp nil".

Maybe I am not following the procedure as requested by the lisp, as I understand now you can directly select the blocks, but they need to be grouped with a solid? a sphere inserted inside the same block?
What would be an input entity?

[ribarm]

I've fixed it in my post...

perfect! thanks a lot man.

the code from last post it's not working for some reason, but with the one you just fixed it's more than enough.

Can you check it once again, have changed some minor mistakes...

still error, but not the same, if I select "BB" it says "bb too few actual parameters".
if I choose "SPH" it creates a sphere only in one block and then it says "bad argument type: stringp nil".

Maybe I am not following the procedure as requested by the lisp, as I understand now you can directly select the blocks, but they need to be grouped with a solid? a sphere inserted inside the same block?
What would be an input entity?

OK... Thanks for feedback... I'll try to debug on some drawing with few blocks and bounding 3DSOLID...

[ribarm]

It works, but during debugging, I've noticed that rectangular Bounding Box 3DSOLIDS (height = 1e-3) don't match position of blocks - it looks that perhaps that small height (1e-3) causes that blocks don't overlap with their linking 3DSOLID - with spheres it's all well... Don't know, try changing that height to something more reliable, but can't guess what would it be...

I've figured it out :
vla-addbox looks for first argument as center of box - i.e. (mid minpt maxpt) and I thought it should be just minpt... Fixed all - should work as expected...

[nekonihonjin]

It works, but during debugging, I've noticed that rectangular Bounding Box 3DSOLIDS (height = 1e-3) don't match position of blocks - it looks that perhaps that small height (1e-3) causes that blocks don't overlap with their linking 3DSOLID - with spheres it's all well... Don't know, try changing that height to something more reliable, but can't guess what would it be...

I've figured it out :
vla-addbox looks for first argument as center of box - i.e. (mid minpt maxpt) and I thought it should be just minpt... Fixed all - should work as expected...

Sir, you're a mastermind, it works like a charm indeed, thank you again!!