Topic: Whats wrong with this lisp?

[HasanCAD]

the lisp working but not create the 3dpoly

Code: [Select]

(defun c:3dp ( / 3D CNT ELIST POINT PT ST ) (vl-load-com)

(defun _value (str / ATTS)
    (while (not
     (if (and (setq ATTS (car (nentsel str)))
      (member (vla-get-objectname (setq ATTS (vlax-ename->vla-object ATTS)))
      '("AcDbAttribute" "AcDbText"))
      (setq ATTS (vl-string-left-trim "EL. " (vla-get-textstring ATTS)))
      (numberp (setq ATTS (read ATTS))))
       ATTS (progn (princ "\nNot Valid") nil)))) ATTS)

(defun Make3DPoly ( pointlist / lastent)

(setq lastent (entlast))
(foreach definition
(append
  '(((0 . "POLYLINE") (100 . "AcDbEntity") (100 . "AcDb3dPolyline") (66 . 1) (10 0.0 0.0 0.0) (70 . 8) (40 . 0.0) (41 . 0.0)
     (210 0.0 0.0 1.0) (71 . 0) (72 . 0) (73 . 0) (74 . 0) (75 . 0)))
  (mapcar
    '(lambda (point)
       (append
'((0 . "VERTEX") (100 . "AcDbEntity") (100 . "AcDbVertex") (100 . "AcDb3dPolylineVertex"))
(list (cons 10 point))
'((40 . 0.0) (41 . 0.0) (42 . 0.0) (70 . 32) (50 . 0.0) (71 . 0) (72 . 0) (73 . 0) (74 . 0)))) PointList)
  '(( (0 . "SEQEND") (100 . "AcDbEntity")))) (entmake definition)) (not (eq (entlast) lastent)))

  (setq cnt 1)
  (while
    (setq pt (getpoint (strcat "\nPick Point No. 0" (itoa cnt) ": ")))
    (setq st (_value (strcat "\nPick Point No. 0" (itoa cnt) " Level: ")))
    (setq pt (list (float (nth 0 pt)) (float (nth 0 pt)) (float st)) )
      (setq elist (cons pt elist))
    (setq cnt (1+ cnt)))

  (setq 3d (Make3DPoly elist))
  (entmod 3d)
  )

[HasanCAD]

I found the mistake

Code: [Select]

(setq pt (list (float (nth 0 pt)) (float (nth 1 pt)) (float st)) )instead

Code: [Select]

(setq pt (list (float (nth 0 pt)) (float (nth 0 pt)) (float st)) )
Thanks all

[HasanCAD]

But How to repeat?

[roy_043]

But How to repeat?

You are already using a while loop, just nest it in another while loop:

Code - Auto/Visual Lisp: [Select]

1. (defun c:3dp ( / _value Make3DPoly cnt loopSwitch pt ptList st)
2.  
3.   (vl-load-com)
4.  
5.   (defun _value (str / atts)
6.     ; ...
7.   )
8.  
9.   ;; Note 1: This function does not return an entity list but T or nil.
10.   ;; Note 2: PointList must be a valid point list. It cannot be nil.
11.   (defun Make3DPoly (pointList / lastEnt)
12.     ; ...
13.   )
14.  
15.   (setq loopSwitch T)
16.   (while loopSwitch
17.     (setq cnt 1)
18.     (setq ptList nil)
19.     (while
20.       (and
21.         (setq pt (getpoint (strcat "\nPick Point No. 0" (itoa cnt) ": ")))
22.         (setq st (_value (strcat "\nPick Point No. 0" (itoa cnt) " Level: ")))
23.       )
24.       (setq pt (list (nth 0 pt) (nth 1 pt) (float st)))
25.       (setq ptList (cons pt ptList))
26.       (setq cnt (1+ cnt))
27.     )
28.     (setq loopSwitch (if ptList (Make3DPoly ptList)))
29.   )
30.   (princ)
31. )
32.  

[HasanCAD]

But How to repeat?

You are already using a while loop, just nest it in another while loop:

Thanx Roy