Topic: {Challenge}Get the textstrings in each line of the mtext

[xiaxiang]

HI
I Assume that there was one mtext with group code as follow

Code: [Select]

((-1 . <图元名: 7ed62ec8>) (0 . "MTEXT") (330 . <图元名: 7ed62c10>) (5 . "59")
(100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "0") (100 . "AcDbMText") (10
56.4981 -14.2706 0.0) (40 . 3.5) (41 . 15.9327) (46 . 20.4843) (71 . 1) (72 .
5) (1 . "abc        abc abc") (7 . "Standard") (210 0.0 0.0 1.0) (11 1.0 0.0
0.0) (42 . 9.33333) (43 . 15.1667) (50 . 0.0) (73 . 1) (44 . 1.0))
Now we know the textstrings content is "abc        abc abc".
Note that there isn't "\\p" Included in the textstrings content .
So the question:how can I get the textstrings in each line of the mtext and return the list of the result?
In this example the return value is ("abc        " "abc " "abc").
I want to know if someone can do that as a Challenge and do help for me.
It seems like  that  we can use explode command ,but any other suggestion?
Sorry for my bad English.
The sample picture and file are as Attachments.
Regards Xia

[Tharwat]

This may do the trick .  ( considering the space as a start for another word ) so it is not typical at all .

Code - Auto/Visual Lisp: [Select]

1. (defun Deconstruct_Strings (string delimiter / pos lst)
2. ;;;;;   Author  :  Tharwat Al Shoufi            ;;;;;
3. ;;;;; Sub-Function to separate a string into  ;;;;;
4. ;;;;; a list acoording to the Delimiter         ;;;;;
5.   (while (setq pos (vl-string-search delimiter string 0))
6.     (progn (setq lst (cons (substr string 1 pos) lst))
7.            (setq string (substr string (+ pos 2) (strlen string)))
8.     )
9.   )
10.   (if string
11.     (setq lst (cons string lst))
12.   )
13.   (setq lst (reverse lst))
14. )
15.  
16. (defun c:Test (/ ss)
17.   (if (and (setq ss (car (entsel "\n Select Mtext :"))) (eq (cdr (assoc 0 (entget ss))) "MTEXT"))
18.     (vl-remove "" (Deconstruct_strings (cdr (assoc 1 (entget ss))) " "))
19.   )
20. )
21.  

[roy_043]

This would be anything but easy. Just consider all the formatting code that can be used in mtexts! The question is: what is your goal?

[xiaxiang]

This would be anything but easy. Just consider all the formatting code that can be used in mtexts! The question is: what is your goal?

I want to explode this mtext with no other formats(even no spaces)to single texts and hold their own  locations.This is the real subject of this topic.
Thanks.
xia

[Lee Mac]

I want to explode this mtext with no other formats(even no spaces)to single texts and hold their own  locations.This is the real subject of this topic.

Why not use the explode command?

[PKENEWELL]

This may do the trick .  ( considering the space as a start for another word ) so it is not typical at all .

Code - Auto/Visual Lisp: [Select]

1. (defun Deconstruct_Strings (string delimiter / pos lst)
2. ;;;;;   Author  :  Tharwat Al Shoufi            ;;;;;
3. ;;;;; Sub-Function to separate a string into  ;;;;;
4. ;;;;; a list acoording to the Delimiter         ;;;;;
5.   (while (setq pos (vl-string-search delimiter string 0))
6.     (progn (setq lst (cons (substr string 1 pos) lst))
7.            (setq string (substr string (+ pos 2) (strlen string)))
8.     )
9.   )
10.   (if string
11.     (setq lst (cons string lst))
12.   )
13.   (setq lst (reverse lst))
14. )
15.  
16. (defun c:Test (/ ss)
17.   (if (and (setq ss (car (entsel "\n Select Mtext :"))) (eq (cdr (assoc 0 (entget ss))) "MTEXT"))
18.     (vl-remove "" (Deconstruct_strings (cdr (assoc 1 (entget ss))) " "))
19.   )
20. )
21.  

@Tharwat

Just getting DXF code 1 will not do the trick if the text string is greater than 250 characters. if the text string length is greater than 250, then you must iterate through DXF code 3, which holds the rest of the string in 250 character chunks. Formatting is a different matter, after retrieving all the text, you have to strip the formatting. Lee Mac's unformat string function: http://www.lee-mac.com/unformatstring.html can be used for that.

It's a whole different matter to preserve the formatting, and put it back into the string afterwards. It can be done - but it is complex, you have to write a new program that replaces the formatting with placeholders in a list along with the string, then replaces the formatting afterwards before recombining the string.

[mkweaver]

Breaking the text down to lines can be done with explode and vl-string-trim. Exploding to individual words is a bit more work.
[ :-Dquote author=xiaxiang link=topic=44128.msg493796#msg493796 date=1362664356]

This would be anything but easy. Just consider all the formatting code that can be used in mtexts! The question is: what is your goal?

I want to explode this mtext with no other formats(even no spaces)to single texts and hold their own  locations.This is the real subject of this topic.
Thanks.
xia
[/quote]

[CAB]

This what I have been using on Plain Text. (explode Mtext)

Code - Auto/Visual Lisp: [Select]

1. ;;  CAB 05/12/2011
2. ;;  Break dText into text words
3.  
4. ;; NOTE, will only work with LEFT justification now
5.  
6. (defun c:t2w() (c:text2words))
7. (defun c:text2words (/ ang elst ent wordlst pt10 pt11 spcwid wid)
8.   ;;  phraser by CAB
9.   (defun sparser (str delim / ptr lst)
10.     (while (setq ptr (vl-string-search delim str))
11.       (setq lst (cons (substr str 1 ptr) lst))
12.       (setq str (substr str (+ ptr 2)))
13.     )
14.     (reverse (cons str lst))
15.   )
16.   ;;  Strip these dxf code pairs from original list
17.   (defun dxfstrip (el)
18.     (vl-remove-if '(lambda (pr) (member (car pr) '(-2 -1 5 102 300 330 331 340 350 360 410))) el)
19.   )
20.  
21.   (defun getwidth(el)
22.     (abs (apply '- (mapcar 'car (textbox el))))
23.   )
24.  
25.  
26.   (if (and (setq ent (entsel "\nSelect the text"))
27.            (setq elst (entget (car ent)))
28.            (= (cdr (assoc 0 elst)) "TEXT")
29.       )
30.     (progn
31.       (entdel (car ent))
32.       (setq elst (dxfstrip elst))
33.       (setq txt (cdr (assoc 1 elst)))
34.       (setq wordlst (vl-remove "" (sparser txt " ")))
35.       (setq ang (cdr (assoc 50 elst))
36.             pt10 (cdr (assoc 10 elst))
37.             pt11 (cdr (assoc 11 elst))
38.       )
39.       ;;  get approx width a space to seperate new text with
40.       (setq elst (subst '(1 . "hl") (assoc 1 elst)  elst))
41.       (setq spcwid (getwidth elst))
42.  
43.       (foreach word wordlst
44.         (entmake (setq elst (subst (cons 1 word) (assoc 1 elst)  elst)))
45.         (setq wid (getwidth elst)
46.               pt10 (polar pt10 ang (+ wid spcwid))
47.               pt11 (polar pt11 ang (+ wid spcwid))
48.               elst (subst (cons 10 pt10) (assoc 10 elst)  elst)
49.               elst (subst (cons 11 pt11) (assoc 11 elst)  elst)
50.         )
51.       )
52.     )
53.     (princ "\nMissed or Not plain TEXT.")
54.   )
55.  
56.   (princ)
57. )

[ronjonp]

Nice code Charles 

[Tharwat]

CAB , I think the OP is talking about Mtext and not Text .

[Lee Mac]

Nice one CAB 

This was my version (I'll add it to my site when I get a chance!)

[CAB]

Thanks fellas, Nice one Lee. 

[ribarm]

Although it functions as expected, it could be better if all split words were to be counted including " " words...

Code - Auto/Visual Lisp: [Select]

1. (defun _splitwords ( str / pos )
2.     (if (setq pos (vl-string-position 32 str))
3.         (cons (cons 1 (substr str 1 (if (eq pos 0) 1 pos))) (_splitwords (substr str (+ (if (eq pos 0) 1 pos) 1))))
4.         (list (cons 1 str))
5.     )
6. )
7.  

And at the end of routine, you just erase those empty text entities :

Code - Auto/Visual Lisp: [Select]

1. (vl-cmdf "_.erase" (ssget "_X" '((0 . "TEXT") (1 . " "))) "")
2.  

This minor modifications I made for my purposes, just thinking that if the words are separated with more spaces, this variant is better (my opinion)...

Cheers, and thank you Lee...

[xiaxiang]

This may do the trick .  ( considering the space as a start for another word ) so it is not typical at all .

Thanks Tharwat!Your codes work well with the textstrings which contain spaces in them as the Attachments of my topic supplied.
If process mtexts which haven't any spcace in their textstrings,the only way I think is explode command
Regards.

I want to explode this mtext with no other formats(even no spaces)to single texts and hold their own  locations.This is the real subject of this topic.

Why not use the explode command?

Is there any other way to change mtext to texts properly?
It seems like only explode command can do that thing.
Regards.

[xiaxiang]

This what I have been using on Plain Text. (explode Mtext)

Nice one CAB 
This was my version (I'll add it to my site when I get a chance!)

Hi,Charles Hi,Lee
All the codes you supplied are designed to process Dtext.
I hope that Mtext could also be done well.
So please allow me to change the OP to "How to break mText into text words".
You'll tell me that using the explode command.
 

[irneb]

It seems like only explode command can do that thing.

I seem to remember that MText actually stores the portions as DText inside an anonymous block definition. But for the love of Pete ... I can't seem to find this. Perhaps I was thinking of something else 

[xiaxiang]

It seems like only explode command can do that thing.

I seem to remember that MText actually stores the portions as DText inside an anonymous block definition. But for the love of Pete ... I can't seem to find this. Perhaps I was thinking of something else 

Really nice! As far as I've know the textstring of Mtext is stored as one combination.Any further information is welcome.
Xia

[fervour]

I have a sentence in mtext and all the words are separated with TAB spacer. What is the modification to make so that it only breaks the tabs between words and not regular spaces.

Thank you.

[alanjt]

I have a sentence in mtext and all the words are separated with TAB spacer. What is the modification to make so that it only breaks the tabs between words and not regular spaces.

Thank you.

Lee's code should do the trick, just edit the _splitwords fuction to include tabs.

*untested*

Code: [Select]

    (defun _splitwords ( str / pos )
        (if (setq pos (vl-string-position 9 str)) ;alanjt edit 32 to 9 (search for tab instead of space
            (cons (cons 1 (substr str 1 pos)) (_splitwords (substr str (+ pos 2))))
            (list (cons 1 str))
        )
    )

[Lee Mac]

Thanks Alan -

Since the difference between the total text width and the sum of the width of each word is divided equally between the words, then providing all of the words are separated by tabs, the modification should work. Obviously, if one has a combination of spaces & tabs, the new text items will be spaced using an average of the space between each of the original words.

Lee

[fervour]

Thanks for the suggestion.

I tried, but the code only look after Dtext, and the Tab delimiter turns into space after being converted from mtext to dtext.
I have a single mtext entity with 2 lines for example:

1st line of mtext: Today[Tab]is[space]a[space]great[tab]day
2nd line of mtext: Tomorrow[Tab]will[space]also[space]be[space]a[space]great[tab]day

I am hoping to break the above by looking at [tab] only.
So the above result will convert 1 mtext to 6 dtext or 6 mtext:

Today
is a great
day
Tomorrow
will also be a a great
day

(no need to be in separate new lines like above, I just showed like as an example).

Thanks again 

[ronjonp]

This works for me:

Code - Auto/Visual Lisp: [Select]

1. (defun _splitwords (str del / pos)
2.   ;; RJP mod vl-string-search for readability and delimiter argument
3.   (if (setq pos (vl-string-search del str))
4.     (cons (substr str 1 pos) (_splitwords (substr str (+ pos (1+ (strlen del))))del))
5.     (list str)
6.   )
7. )
8. (setq str (vla-get-textstring (vlax-ename->vla-object (car (entsel)))))
9. (_splitwords str "\t")
10.  
11.  
12. ;; "Tomorrow\twill also be a great\tday"
13. ;; Returns
14. ;; ("Tomorrow" "will also be a great" "day")

[alanjt]

This works for me:

Code - Auto/Visual Lisp: [Select]

1. (defun _splitwords (str del / pos)
2.   ;; RJP mod vl-string-search for readability and delimiter argument
3.   (if (setq pos (vl-string-search del str))
4.     (cons (substr str 1 pos) (_splitwords (substr str (+ pos 2))del))
5.     (list str)
6.   )
7. )
8. (setq str (vla-get-textstring (vlax-ename->vla-object (car (entsel)))))
9. (_splitwords str "\t")
10.  
11.  
12. ;; "Tomorrow\twill also be a great\tday"
13. ;; Returns
14. ;; ("Tomorrow" "will also be a great" "day")

Be aware that the +2 would fail to yield desired results if the delimiter exceeded the intended single digit.

eg.

Code: [Select]

Command: (_splitwords "i_-_love_-_pizza" "_-_")
("i" "-_love" "-_pizza")
This is pointless in this situation, and a simple strlen would fix the issue, but I just thought it was worth mentioning.

[ronjonp]

Ah yes thanks Alan .. I'll modify above.

[alanjt]

Ah yes thanks Alan .. I'll modify above.

I was mainly just looking for an excuse to express admiration for my one true love.

[fervour]

The lisp won't let me select Mtext though...?

[ronjonp]

The lisp won't let me select Mtext though...?

Sure it does.

[ronjonp]

Ah yes thanks Alan .. I'll modify above.

I was mainly just looking for an excuse to express admiration for my one true love.

Ummmm .. 

[fervour]

I used Lee's code and updated the _splitwords section. What did I do wrong?

Code: [Select]

(defun c:s2w ( / _splitwords _textwidth ang dxf ent enx fun inc lst pnt sel spc tot wid )

(defun _splitwords (str del / pos)
  ;; RJP mod vl-string-search for readability and delimiter argument
  (if (setq pos (vl-string-search del str))
    (cons (substr str 1 pos) (_splitwords (substr str (+ pos (1+ (strlen del))))del))
    (list str)
  )
)

(setq str (vla-get-textstring (vlax-ename->vla-object (car (entsel)))))
(_splitwords str "\t")

    (defun _textwidth ( enx )
        ((lambda ( lst ) (- (caadr lst) (caar lst))) (textbox enx))
    )

    (if (setq sel (ssget "_:L" '((0 . "TEXT") (-4 . "<NOT") (-4 . "<OR") (72 . 3) (72 . 4) (72 . 5) (-4 . "OR>") (-4 . "NOT>"))))
        (repeat (setq inc (sslength sel))
            (setq ent (ssname sel (setq inc (1- inc)))
                  enx (entget ent)
                  tot 0.0
                  lst nil
            )
            (foreach item (_splitwords (cdr (assoc 1 enx)))
                (setq dxf (entget (entmakex (subst item (assoc 1 enx) enx)))
                      wid (_textwidth dxf)
                      tot (+ tot wid)
                      lst (cons (cons dxf wid) lst)
                )
            )
            (if (< 1 (length lst))
                (progn
                    (setq wid (_textwidth enx)
                          spc (/ (- wid tot) (float (1- (length lst))))
                          lst (reverse lst)
                          ang (cdr (assoc 50 enx))
                    )
                    (if
                        (and
                            (= 0 (cdr (assoc 72 enx)))
                            (= 0 (cdr (assoc 73 enx)))
                        )
                        (setq pnt (cdr (assoc 10 enx)))
                        (setq pnt (cdr (assoc 11 enx)))
                    )
                    (cond
                        (   (= (cdr (assoc 72 enx)) 0)
                            (setq fun (lambda ( a b ) (+ spc (cdr a))))
                        )
                        (   (= (cdr (assoc 72 enx)) 1)
                            (setq fun (lambda ( a b ) (+ spc (/ (+ (cdr a) (cdr b)) 2.0)))
                                  pnt (polar pnt (+ ang pi) (/ (- wid (cdar lst)) 2.0))
                            )
                        )
                        (   (= (cdr (assoc 72 enx)) 2)
                            (setq fun (lambda ( a b ) (+ spc (cdr b)))
                                  pnt (polar pnt (+ ang pi) (- wid (cdar lst)))
                            )
                        )
                    )
                    (mapcar
                        (function
                            (lambda ( a b / dxf )
                                (setq dxf (car a)
                                      dxf (subst (cons 10 pnt) (assoc 10 dxf) dxf)
                                      dxf (subst (cons 11 pnt) (assoc 11 dxf) dxf)
                                      pnt (polar pnt ang (fun a b))
                                )
                                (entmod dxf)
                            )
                        )
                        lst (append (cdr lst) '((nil . 0.0)))
                    )
                    (entdel ent)
                )
            )
        )
    )
    (princ)
)
(princ)

[alanjt]

Ah yes thanks Alan .. I'll modify above.

I was mainly just looking for an excuse to express admiration for my one true love.

Ummmm .. 

I love you too, but I love pizza more.

[ronjonp]

Ah yes thanks Alan .. I'll modify above.

I was mainly just looking for an excuse to express admiration for my one true love.

Ummmm .. 

I love you too, but I love pizza more.

Agreed .. I love pizza more too .

[RAYAKMAL]

Nice one CAB 

This was my version (I'll add it to my site when I get a chance!)

Lee... Thanks. That's exactly what I wanted a few days ago

Here's my story:
When there's a need to distribute standard drawings to a contractor, I usually export them to WMF and then I use MS WORD to create the pdf.
It suits my need.  Unfortunately some portion of the pdf consist of paragraph text still can be disassembled from pdf.
With your code, problem solved. Texts are words, not one sentence.
 

[Lee Mac]

I'm delighted that you find it useful RAYAKMAL 

FWIW, I subsequently published the program to my site as 'Text to Words' - though, I believe the code published on my site is mostly unchanged from the version posted in this thread.

[fervour]

I tried, but I am still not able to select Mtext using the code above.... 

[fervour]

Hi ronjonp,

Could you please help me why I could not select Mtext?

Thank you