Topic: Runs yet it doesn't

[David Hall]

If I manually load each line of code from VLisp, it works.  But if I load the whole routine, and call from command line in Autocad, it fails.  Any ideas?



(defun c:foo (/LayerFrozen)
  (vl-load-com)
  (setq
    acadObject     (vlax-get-acad-object)
    acadActiveDoc (vla-get-ActiveDocument acadObject)
  )
  (setq acadLayers (vla-get-Layers acadActiveDoc))
  (vlax-for eachLayer acadLayers
    (if
      (= (vla-get-Freeze eachLayer) :vlax-true)
    (vla-put-Freeze eachLayer :vlax-false)
    )
  )
)

[MP]

manually load each line 

without running that code my hint would be: branch the logic when the layer being processed is the current layer

[fixo]

Try to wrap your logic in 'vl-catch-all-apply' function

[MP]

sledge hammers, how do they work?

[David Hall]

MP - since Im not trying to freeze current layer would it matter?
FIXO - I haven't learned how to do that yet

[David Hall]

OK, but why?  I know that seems open-ended, but reading a property shouldn't make it fail

[Lee Mac]

This:

Code: [Select]

(defun c:foo (/LayerFrozen)needs to be:

Code: [Select]

(defun c:foo (/ LayerFrozen)else the '/LayerFrozen' symbol is interpreted as a parameter.

[ Well, strictly it should be ]:

Code: [Select]

(defun c:foo (/ acadObject acadActiveDoc acadLayers)

[David Hall]

Lee, that was it.  Stupid space

[Lee Mac]

Lee, that was it.  Stupid space

No worries 

FWIW, I would suggest:

Code: [Select]

(defun c:foo ( )
    (vlax-for layer (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
        (if (= :vlax-true (vla-get-freeze layer))
            (vla-put-freeze layer :vlax-false)
        )
    )
    (princ)
)

[dgorsman]

I get bitten by that from time to time as well, mostly when I hurry.  I put it in the same category as typing ".8" instead of "0.8".  Seems small but carries *really* big teeth.   

[David Hall]

Lee, I see what you did, but for clarity I am explicitly setting up vars so I can follow along.  I'm finally trying to learn VLisp

[MP]

Good eye Lee.

Having said that, observe:

Code: [Select]

(vla-put-freeze
    (vla-item
        (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
        (getvar "clayer")
    )           
    :vlax-false
)
; error: Automation Error. Invalid layer

[fixo]

FIXO - I haven't learned how to do that yet
See if this will works

Code: [Select]

(setq adoc (vla-get-activedocument
              (vlax-get-acad-object))
      aclayers (vla-get-layers adoc))
       ;;thaw
      (vlax-for olayer aclayers
(vl-catch-all-apply 'vla-put-freeze
  (list olayer :vlax-false)))
        ;;freeze
      (vlax-for olayer aclayers
(vl-catch-all-apply 'vla-put-freeze
  (list olayer :vlax-true)))

[Lee Mac]

Lee, I see what you did, but for clarity I am explicitly setting up vars so I can follow along.  I'm finally trying to learn VLisp

No problem!
I tend to only assign variables if I intend to reference the object more than once in the code - but if it helps you learn the object model hierarchy, I won't object 

Good eye Lee.

Cheers dude 

Having said that, observe...

Thanks, I considered that - however, for this case, since the current layer will never be frozen, it's freeze property will not be modified by the code.

[MP]

... however, for this case, since the current layer will never be frozen, it's freeze property will not be modified by the code.

True, good point.