Topic: How to force user input 5 digits?

[MeasureUp]

This is a sample:

Code: [Select]

(getstring "Enter \"B\" followed by 5 digits no more or less: ")
Thanks for your help.

[BlackBox]

Code - Auto/Visual Lisp: [Select]

1. (if
2.   (and
3.     (setq s (strcase
4.               (getstring
5.                 "Enter \"B\" followed by 5 digits no more or less: "
6.               )
7.             )
8.     )
9.     (= "B" (substr s 1 1))
10.     (= 6 (strlen s))
11.   )
12.   ;; <-- do something
13. )
14.  

You should really start reading the developer documentation.

[CAB]

Code - Auto/Visual Lisp: [Select]

1. ;;  CAB 12.26.2009
2. ;;  example Get number within a Numeric Range
3. ;;    Arguments
4. ;;  If nil, Ignore MinNum or MaxNum or DefNum
5. ;;  msg and ErrMsg may be nil as well
6. (defun GetNumInRange(MinNum MaxNum DefNum msg ErrMsg / num)
7.   (or msg (setq msg "\nEnter number: "))
8.   (or ErrMsg (setq ErrMsg "\nEntry is out of range. Try Again."))
9.   (while
10.     (cond
11.       ((null (setq num (getdist msg)))
12.        (if DefNum
13.          (null (setq num DefNum))
14.          (princ ErrMsg)
15.        )
16.       )
17.       ((and MinNum (< num MinNum))
18.        (princ ErrMsg))
19.       ((and MaxNum (> num MaxNum))
20.        (princ ErrMsg))
21.     )
22.   )
23.   num
24. )

Code: [Select]

(defun c:test()
  (print
  (GetNumInRange 10 50 39 "\nEnter number [10 =< Num >= 50]."
                     "\nError - entry is out of range. Try Again.")
    )
  (princ)
 
)

[Lee Mac]

Maybe:

Code: [Select]

(defun c:test ( / str )
    (while
        (not
            (or
                (= "" (setq str (strcase (getstring "\nEnter \"B\" followed by 5 digits: "))))
                (wcmatch str "B#####")
            )
        )
        (princ "\nPlease enter a string of the form \"B#####\".")
    )
    (if (/= "" str)
        (princ "\nWe have a winner!")
    )
    (princ)
)

[BlackBox]

Code: [Select]

(wcmatch str "B#####")

... Brilliant.

[Stefan]

Maybe this

Code - Auto/Visual Lisp: [Select]

1. (defun get_n_digits (n / s msg gr c i)
2.   (grread t)
3.   (princ (setq i 0 s "" msg (strcat "\rEnter " (itoa n) " digits number: ")))
4.   (while
5.     (and
6.       (< i n)
7.       (= (car (setq gr (grread nil 2))) 2)
8.       )
9.       (if
10.          (< 47 (setq c (cadr gr)) 58)
11.          (setq i (1+ i)
12.                s (strcat s (chr c))
13.                )
14.         (if
15.           (= c 8)
16.           (setq i (max (1- i) 0)
17.                 s (substr s 1 i)
18.                 )
19.           (princ (strcat "\nInvalid character \"" (chr c) "\"\n"))
20.          )
21.         )
22.     (princ (strcat msg s))
23.     )
24.   (print)
25.   (if (= i n) s (not (princ (strcat "\nPlease enter exactly " (itoa n) " digits\n"))))
26. )

Code: [Select]

(setq nr (get_n_digits 5))
Description:
-only valid digits are counted 0, 1, ..., 9
-you can press backspace to delete last valid character
-no need to press enter at the end. The routine ends once the n-th number is entered
-returns a string

[pBe]

Autocad version in alternative reality (parallel universe)


(initget 2048)
Prevents the user from responding to the request by entering non-numeric values at getstring prompt


 

[efernal]

another...

Code - Auto/Visual Lisp: [Select]

1. (DEFUN c:test (/ m_str)
2.   (WHILE (NOT (WCMATCH (SETQ m_str (GETSTRING "\n-> Type 5 digits : ")) "#####")))
3.   (SETQ m_str (STRCAT "B" m_str))
4.   (ALERT m_str)
5. )
6.  

[MeasureUp]

Big Thanks to all your helps.
In my case, "B#####" is the simple sulotion.
And all your helps are Brilliant, surely.

BTW, I have wrote more than hundred lines by looking at "acsii"...

[Lee Mac]

Code: [Select]

(wcmatch str "B#####")

... Brilliant.

Cheers dude