Topic: Edit constant attributes

[Cawaugh]

I am trying to convert this piece of code to handle constant attributes. So far I have had no luck.
The process should be the same except getting and modifying a constant attrib instead of a non-constant.
Any help will be greatly appreciated. If you want to get in contact with me offline, my email is charles.waugh@wmeng.com.
Thanks for any help you may be able to give to me on this. 

Code - Auto/Visual Lisp: [Select]

1. ;; -----------------------------------------------------------------------------
2. ;; Function: ATTRIB_REPLACE_INCREMENTAL
3. ;; Purpose : Modifies attribute values according to params:
4. ;; Params  : BNAME:  Block name(s), can be wildcard
5. ;;           TAG:    Attribute tag, should be wildcard
6. ;;           ACTION: String describing what to do (Add or Delete)
7. ;;           VALUE:  List of Values to insert/delete/whatever
8. ;; Local   : ss, ssl: Selection set, length
9. ;;           #:       Loop counter
10. ;;           en, eg:  Entity name, (entget) list
11. ;;           modlist: List of (entget) lists for attributes which match TAG
12. ;;           vallist: List of values to place in attribute slots
13. ;; Uses    : (naus_aso) (naus_strplace)
14. ;; Returns : Number of blocks processed (but not necessarily modified)
15. ;; -----------------------------------------------------------------------------
16. ;; codelist looks like ("US001" "US253")
17.  
18. (attrib_replace_incremental "3M-BORDER-E" "3MA#" "Add" codelist)
19.  
20. (defun attrib_replace_incremental (BNAME TAG ACTION VALUE
21.                                         / ss ssl # en eg modlist vallist)
22.   (graphscr)
23.   (setq
24.     ss (ssget "X" (list '(0 . "INSERT") (cons 2 BNAME)))
25.     ssl (if ss (sslength ss) 0.0)
26.     # 0.0
27.   )
28.   (while (< # ssl)
29.     (setq
30.       en (ssname ss #)
31.       modlist nil
32.       vallist (if (= ACTION "Add") VALUE nil)
33.     )
34.     (while (setq en (entnext en))
35.       (setq eg (entget en))
36.       (if (and (= "ATTRIB" (naus_aso 0 eg)) (wcmatch (naus_aso 2 eg) TAG))
37.         (progn
38.           (setq modlist (cons eg modlist)) ; Add to list of potential code slots
39.           (if (/= (naus_aso 1 eg) "")
40.             (setq vallist (cons (naus_aso 1 eg) vallist)) ; Add to list of codes
41.           )
42.         )
43.       )
44.     )
45.  
46.     (setq cnt 1)
47.     (if (= ACTION "Delete")
48.         (foreach item value
49.          (progn
50.           (setq vallist (naus_list_delall item vallist))
51.           (setq cnt (+ cnt 1))
52.          );end progn
53.         );foreach
54.     );end if (= ACTION "Delete")
55.  
56.     (if modlist
57.       (progn
58.         (setq
59.           modlist (reverse modlist)
60.           vallist (naus_list_unique vallist) ; Remove duplicates
61.           vallist ; Place in ascending order
62.            (naus_sort
63.              vallist
64.              '(lambda (X Y)
65.                 (if (= (atof X) (atof Y)) (< X Y) (< (atof X) (atof Y)))
66.               )
67.            )
68.         )
69.             ;(strcat "\nWARNING: no room for code " (car vallist) ", discarded.")
70.         (if (> (length vallist) (length modlist)) ; If more values than slots
71.              (progn
72.                 (princ (strcat "\nWARNING: Room for only 6 Access code!"))
73.                 (princ (strcat "\nDelete old or no longer used codes, then add in new codes!"))
74.         (exit)
75.                 ;(setq vallist (cdr vallist)) ; Reduce list of values
76.              );end progn
77.         );end if
78.         (foreach eg modlist ; For each code slotmc
79.  
80.           (if (setq val (car vallist)) ; If there are values left,
81.             (entmod (subst (cons 1 val) (assoc 1 eg) eg)) ; insert value, else
82.             (entmod (subst (cons 1 "") (assoc 1 eg) eg))  ; remove existing value
83.           )
84.  
85.           (setq vallist (cdr vallist)) ; Reduce list of values
86.         )
87.  
88.         (entupd (ssname ss #))
89.  
90.       )
91.     )
92.     (setq # (1+ #))
93.   )
94.   (graphscr)
95.   ssl ; Return number of blocks processed
96. )

[CAB]

I assume there is no error just no change?
Nothing jumps out.
Could you post a DWG of a test Block / Insert?

[Lee Mac]

I am trying to convert this piece of code to handle constant attributes. So far I have had no luck.
The process should be the same except getting and modifying a constant attrib instead of a non-constant.

You cannot modify the value of a constant attribute reference [ATTRIB] (hence the name); you will need to modify the value held by the attribute definition [ATTDEF] of the constant attribute by iterating over the entities contained within the block definition.

[Lee Mac]

I am trying to convert this piece of code to handle constant attributes. So far I have had no luck.
The process should be the same except getting and modifying a constant attrib instead of a non-constant.

You cannot modify the value of a constant attribute reference [ATTRIB] (hence the name); you will need to modify the value held by the attribute definition [ATTDEF] of the constant attribute by iterating over the entities contained within the block definition.

A simple example to clarify my point:

Code - Auto/Visual Lisp: [Select]

1. (defun _changeconstantattrib ( blk tag val / ent enx rtn )
2.     (if (setq ent (tblobjname "BLOCK" blk)) ;; Does the block exist?
3.         (while (setq ent (entnext ent))
4.             (if
5.                 (and
6.                     (= "ATTDEF" (cdr (assoc 0 (setq enx (entget ent))))) ;; is it an ATTDEF?
7.                     (= 2 (logand 2 (cdr (assoc 70 enx)))) ;; is the ATTDEF constant?
8.                     (= (strcase tag) (strcase (cdr (assoc 2 enx)))) ;; is it our tag?
9.                 )
10.                 (setq rtn (entmod (subst (cons 1 val) (assoc 1 enx) enx)))
11.             )
12.         )
13.     )
14.     (and rtn)
15. )

Code - Auto/Visual Lisp: [Select]

1. (_changeconstantattrib <block-name> <attribute-tag> <new-value>)

Since the block definition is being modified, a REGEN is required to reflect changes to all block references.

[irneb]

Yep, a constant attrib is noting different from a normal piece of text inside the block. I don't think the OP's idea would ever work with constant attribs. Incrementing one would update all to the same number. Why do you need to have this attribute set as constant?

[Cawaugh]

Lee, it works. I did modified a little for my program but it came out great.
Just missing that line of thought for constants. Thanks again!!

[Lee Mac]

You're welcome!