Topic: [Community Project] Clean Drawing Program

[Lee Mac]

Inspired by this recent thread, I thought it would be beneficial to the community for us to construct a general program to clean drawings which are bloated by hundreds or thousands of what may be deemed as unnecessary objects, or common causes of drawings with ostensibly inexplicably huge file sizes.

To begin, I have put together the following program:

Code - Auto/Visual Lisp: [Select]

1. (defun c:cleandwg ( / *error* _effectivename bkc cmd doc ext flg lck lst lyc )
2.  
3.     ;; Error Handler
4.     (defun *error* ( m )
5.         ;; Relock Layers
6.         (foreach lay lck
7.             (if (not (vlax-erased-p lay))
8.                 (vla-put-lock lay :vlax-true)
9.             )
10.         )
11.         ;; Reset CMDECHO
12.         (if (= 'int (type cmd))
13.             (setvar 'cmdecho cmd)
14.         )
15.         ;; Print critical errors
16.         (if (not (wcmatch (strcase m t) "*break,*cancel*,*exit*"))
17.             (princ (strcat "\nError: " m))
18.         )
19.         (princ)
20.     )
21.  
22.     ;; Function to return block effective name
23.     (defun _effectivename ( obj )
24.         (if (vlax-property-available-p obj 'effectivename)
25.             (vla-get-effectivename obj)
26.             (vla-get-name obj)
27.         )
28.     )
29.  
30.     (setq doc (vla-get-activedocument (vlax-get-acad-object))
31.           lyc (vla-get-layers doc)
32.           bkc (vla-get-blocks doc)
33.           cmd (getvar 'cmdecho)
34.     )
35.     ;; Unlock all layers
36.     (vlax-for lay lyc
37.         (if (= :vlax-true (vla-get-lock lay))
38.             (progn
39.                 (setq lck (cons lay lck))
40.                 (vla-put-lock lay :vlax-false)
41.             )
42.         )
43.     )
44.  
45.     ;; Remove Anonymous Groups
46.     (vlax-for grp (vla-get-groups doc)
47.         (if (wcmatch (vla-get-name grp) "`**")
48.             (vl-catch-all-apply 'vla-delete (list grp))
49.         )
50.     )
51.  
52.     ;; Detect empty block definitions
53.     (vlax-for blk bkc
54.         (if
55.             (and
56.                 (= :vlax-false (vla-get-isxref blk))
57.                 (= :vlax-false (vla-get-islayout blk))
58.             )
59.             (progn
60.                 (vlax-for obj blk (setq flg t))
61.                 (if (null flg)
62.                     (setq lst (cons (strcase (vla-get-name blk)) lst))
63.                 )
64.                 (setq flg nil)
65.             )
66.         )
67.     )
68.     ;; Remove all references of empty definitions
69.     (vlax-for blk bkc
70.         (vlax-for obj blk
71.             (if
72.                 (and
73.                     (= "AcDbBlockReference" (vla-get-objectname obj))
74.                     (member (strcase (_effectivename obj)) lst)
75.                 )
76.                 (vl-catch-all-apply 'vla-delete (list obj))
77.             )
78.         )
79.     )
80.     ;; Remove empty block definitions
81.     (foreach blk lst
82.         (vl-catch-all-apply 'vla-delete (list (vla-item bkc blk)))
83.     )
84.  
85.     ;; Remove Layer Property & Group Filters
86.     (if
87.         (and
88.             (= :vlax-true (vla-get-hasextensiondictionary lyc))
89.             (setq ext (vla-getextensiondictionary lyc))
90.         )
91.         (foreach dic '("ACLYDICTIONARY" "ACAD_LAYERFILTERS")
92.              (vl-catch-all-apply 'vla-remove (list ext dic))
93.         )
94.     )  
95.  
96.     ;; Turn off command echo
97.     (setvar 'cmdecho 0)
98.    
99.     ;; Remove unused scales
100.     (command "_.-scalelistedit" "_D" "*" "_E")
101.  
102.     ;; Purge All
103.     (repeat 3 (command "_.-purge" "_A" "*" "_N"))
104.  
105.     ;; Reset command echo
106.     (setvar 'cmdecho cmd)
107.  
108.     ;; Relock Layers
109.     (foreach lay lck
110.         (if (not (vlax-erased-p lay))
111.             (vla-put-lock lay :vlax-true)
112.         )
113.     )
114.  
115.     ;; Exit cleanly
116.     (princ)
117. )
118. (vl-load-com) (princ)

As indicated by the thread title, I welcome others to contribute & improve this program, so that we may create a robust and all-purpose drawing cleaner for the community to use.

Ideas & suggestions are welcome!

Latest Version attached:

[CAB]

Good idea Lee.
Off to play tennis but will take a look this afternoon. 

[Lee Mac]

Good idea Lee.
Off to play tennis but will take a look this afternoon. 

Thanks Alan - have a great game! 

[Tharwat]

It looks very useful tool and clear to read .

Is not it good idea to use vla-purgeall function instead of the command call ?

Thanks for your great efforts . 

[Lee Mac]

It looks very useful tool and clear to read .

Thanks for your great efforts . 

Thank you Tharwat 

Is not it good idea to use vla-purgeall function instead of the command call ?

Although the PurgeAll method may be generally faster than the command call, it will not purge Multileader Styles, Empty Text objects, Zero-Length geometry, etc. etc.

[roy_043]

Some quick thoughts:

Your line 60 etc:

Code - Auto/Visual Lisp: [Select]

1. (vlax-for obj blk (setq flg t))

Could become

Code - Auto/Visual Lisp: [Select]

1. (if (zerop (vla-get-count blk)) ...

Why (only) remove anon groups? They can be as useful/useless as named groups.

Redundant groups:

Code - Auto/Visual Lisp: [Select]

1. ;;; Purpose:       Get groups containing 1 or zero objects.
2. ;;; Arguments:     groupObjectList - list of group objects
3. ;;; Return value:  List of group objects or nil.
4. (defun _GetRedundantGroups (groupObjectList)
5.   (vl-remove-if
6.     '(lambda (a) (> (vla-get-count a) 1))
7.     groupObjectList
8.   )
9. )

Some portions of the program would have to be run repeatedly. Block defs can become empty if block refs of empty blocks have been deleted. Modularize?

Perhaps (also) start with purging. That way the program will potentially have to analyse/do less.

[kruuger]

really great idea Lee. my suggestions are:
- create dcl (on the fly) to select what to delete/clean and what not
- maybe multilanguage option like

Code: [Select]

(nth *l (list "Utwórz blok anonimowy\n" "Make annonymous block\n"))- maybe option to delete some dictionary (only for experts)

kruuger

[PrinceLISPalot]

You might like to consider issues coming from older Legacy drawings, or other cad apps that generate .dwg. An example of this is empty text strings. These used to be created in AutoCAD by editing some TEXT/MTEXT and deleting all the text in the dialogue, which resulted in an empty text string. This was fixed in later versions of AutoCAD, but is still possible in BricsCAD, and your likely to strike if your working on older drawings. Created the following routine to deal with.

Code - Auto/Visual Lisp: [Select]

1. ; ****************************NOTXT.LSP*********************************
2.  
3. ;  Deletes empty TEXT strings from your drawing
4. ;  Rev A
5. ;  12/06/93
6. ;  Jason Bourhill
7. ; **********************************************************************
8.  
9. ;  Rev B
10. ;  Updated to check for empty MTEXT strings as well.
11. ;  10/09/99
12. ;  Jason Bourhill
13. ; **********************************************************************
14.  
15. ;  Rev C
16. ;  Change string checking part to use wcmatch. quicker?
17. ;  30/11/99
18. ;  Jason Bourhill
19. ; **********************************************************************
20.  
21. (defun C:NOTXT ( / searchtxt sset ans nfix)
22.  
23. ;-------------------------------SEARCHTXT-------------------------------
24. (defun searchtxt (sset rstr / num txtfnd entnum ent strcomp stn)
25. (setq num 0 txtfnd 0)
26.  (princ "\nWorking ")
27.  (repeat (sslength sset)
28.         (setq entnum (ssname sset num))
29.          (setq ent (entget entnum))
30.          (setq stn (strlen (cdr (assoc 1 ent))))
31.           (if (= 0 stn)(setq strcomp "")(setq strcomp " "))
32. ;          (if (/= 0 stn) (repeat stn (setq strcomp (strcat strcomp " "))))
33. ;           (cond ((= strcomp (cdr (assoc 1 ent)))
34.             (cond ((wcmatch (cdr (assoc 1 ent)) strcomp)
35.                         (if rstr (progn
36.                                         (setq ent
37.                                                 (subst (cons 1 rstr)
38.                                                        (assoc 1 ent)
39.                                                         ent
40.                                                 )
41.                                         )
42.                                         (entmod ent)
43.                                         (entupd entnum)
44.                                         (setq txtfnd (1+ txtfnd))
45.                                  )
46.                                  (progn (entdel entnum) (setq txtfnd (1+ txtfnd)))
47.                         )))
48.         (princ ">")
49.         (setq num (1+ num))
50.  )
51. txtfnd
52. )
53.  
54. ;-------------------------------MAIN PROG-------------------------------
55.  
56. (princ "\nSearching For Text Please Wait")
57. (setq sset
58.  (ssget "x" (list(cons -4 "<or")
59.                     (cons 0 "TEXT")
60.                     (cons 0 "MTEXT")
61.                  (cons -4 "or>")
62.             )
63.   )
64.  )
65.  (if sset (progn
66.                 (initget "Delete Replace")
67.                 (setq ans (getkword "\nDo you want to Delete or Replace empty text strings <Delete/Replace>: "))
68.                 (cond ((= ans "Delete")(setq rstr nil))
69.                       ((= ans "Replace")(setq rstr (getstring T "\nEnter replacement string: ")))
70.                 )
71.                 (setq nfix (searchtxt sset rstr))
72.                 (princ (strcat "\nFound and Fixed " (itoa nfix) " Empty text strings"))
73.          )
74.          (princ "\nNo TEXT found in Drawing Data Base")
75.  )
76. (prin1)
77. )
78.  

I've also seen bad implementation of valid objects on drawings. such as drawing a property boundary using the letter "X" instead of using an appropriate linetype. Maybe your routine needs to Audit first, provide the user with a list of potential issues, and allow them to select which ones they wish to act on.

I haven't checked, but you used to have issues with purging empty layers if you had set viewport related properties from within a paperspace viewport.

[Lee Mac]

Your line 60 etc:

Code - Auto/Visual Lisp: [Select]

1. (vlax-for obj blk (setq flg t))

Could become

Code - Auto/Visual Lisp: [Select]

1. (if (zerop (vla-get-count blk)) ...

Good catch roy - noted.

Why (only) remove anon groups? They can be as useful/useless as named groups.

My logic was that anonymous groups are more likely to be automatically generated by another program, or inadvertently generated by an unsuspecting user; whereas, named groups are more likely to have been created purposefully.

Redundant groups...

Good idea!

Some portions of the program would have to be run repeatedly. Block defs can become empty if block refs of empty blocks have been deleted. Modularize?

Another great idea, I had overlooked the case of nested empty block definitions whose reference is the only object within the parent definition - an unlikely scenario, but certainly should be included for completeness.

Perhaps (also) start with purging. That way the program will potentially have to analyse/do less.

Good shout - I'll change this also.

really great idea Lee.

Thanks Kruuger! 

- create dcl (on the fly) to select what to delete/clean and what not

Nice idea Kruuger, I shall certainly look to implement this 

- maybe multilanguage option like

Code: [Select]

(nth *l (list "Utwórz blok anonimowy\n" "Make annonymous block\n"))

Since this will be a general program for all to use, multilanguage support will be a necessity - though, I'll certainly need your's (& Google's) help with this!

- maybe option to delete some dictionary (only for experts)

The program currently removes the Layer Filter dictionaries, however, I was unsure as to which other dictionaries are unnecessary and can be safely removed in general - perhaps the AEC* dictionaries when opening a drawing in standard AutoCAD?

You might like to consider issues coming from older Legacy drawings, or other cad apps that generate .dwg. An example of this is empty text strings. These used to be created in AutoCAD by editing some TEXT/MTEXT and deleting all the text in the dialogue, which resulted in an empty text string. This was fixed in later versions of AutoCAD, but is still possible in BricsCAD, and your likely to strike if your working on older drawings.

Newer versions of AutoCAD include the option to purge Empty Text Objects using the in-built Purge command, though, I agree that it would be useful to create a separate function to remove these objects to account for versions in which the option is not present - thanks!

I've also seen bad implementation of valid objects on drawings. such as drawing a property boundary using the letter "X" instead of using an appropriate linetype.

These types of bad drafting practices will most probably be difficult to detect, and furthermore, many users may hold differing opinions over what is considered a good or bad drafting practice; for this program, I was aiming more to remove general redundancies which may be applicable across all industries of drafting.

Maybe your routine needs to Audit first, provide the user with a list of potential issues, and allow them to select which ones they wish to act on.

A great idea, but I see this being potentially difficult to implement, since some operations performed by the program (such as the Purge All operation) provide no programmatic output as to the objects available to be purged by the program.

I haven't checked, but you used to have issues with purging empty layers if you had set viewport related properties from within a paperspace viewport.

Aah, viewport overrides! Another can of worms! 

[hermanm]

My logic was that anonymous groups are more likely to be automatically generated by another program, or inadvertently generated by an unsuspecting user;

I have written programs which generate "anonymous" groups, by design.
I use also a third party application which has a use for one entity groups, because it associates additional information with them.

Suggest (as others have) that you provide options as to what gets "cleaned up."

[Lee Mac]

My logic was that anonymous groups are more likely to be automatically generated by another program, or inadvertently generated by an unsuspecting user;

I have written programs which generate "anonymous" groups, by design.
I use also a third party application which has a use for one entity groups, because it associates additional information with them.

Suggest (as others have) that you provide options as to what gets "cleaned up."

Agreed 

[Lee Mac]

I have attached an updated version of the program to the first post of the thread, incorporating a number of comments:

• Program has been 'modularised' into separate functions, with documentation for each function.
• Program now accounts for nested empty block definitions.
• 'Purge All' operation now moved to start of program.
• Groups with fewer than 2 objects now removed.

Still to do:

• Write program description for code header
• Create dialog to allow user to choose items to be 'cleaned'
• Create function to remove empty Text & MText objects
• Multilanguage support for dialog

[Patrick_35]

Hi

If you want, I did kind of program.
You can pick ideas here
It remains only to translate it into English

@+

[Lee Mac]

If you want, I did kind of program.
You can pick ideas here
It remains only to translate it into English

Wow - that is a very thorough and comprehensive program Patrick - thank you for sharing your efforts 

[Patrick_35]

Yes, and all the others are too detailed (on the same blog)
The only problem is that I have not mastered enough English to do the translation.
And as I have online, I was wondering what software did you animate your pictures to better explain your lisps

@+

[Lee Mac]

The only problem is that I have not mastered enough English to do the translation.

Your English is far better than my French! (and I studied French for 7 years  )

And as I have online, I was wondering what software did you animate your pictures to better explain your lisps

I use Camtasia 

[Krushert]

Lee, or whomever: 

With a quick glance, I did not see where regapps were getting purged.  IN the past I have had to specifically call the purging of those but with the new fancy code it might be already taken care of.

**EDIT**
maybe throw in a file save?   

[Lee Mac]

With a quick glance, I did not see where regapps were getting purged.  IN the past I have had to specifically call the purging of those but with the new fancy code it might be already taken care of.

Currently, I believe the regapps are being purged by the call to the Purge command with the 'All' option selected; however, you may be correct in that this option does not include regapps.

However, I intend to write separate functions for removing these items when incorporating the ability for the user to select the groups of items to be 'cleaned', rather than using the in-built Purge command.

**EDIT**
maybe throw in a file save?   

Risky should something important be accidentally removed... 

[VovKa]

some more tools for cleaning
http://www.theswamp.org/index.php?topic=22528.msg271392#msg271392
http://www.theswamp.org/index.php?topic=33516.msg388893#msg388893

[kruuger]

Since this will be a general program for all to use, multilanguage support will be a necessity - though, I'll certainly need your's (& Google's) help with this!

of course will be happy to help with polish translation.

i even wrote (community program) some translator. if someone is interesting please see attached sample file:
- makeblock.lsp - program with comments to translate
- tooltranslator.lsp
- library function - cadpack

more here -> http://forum.cad.pl/cadpl-pack-v1-lsp-t78161.html
kruuger

[cmwade77]

I vote for removal of AEC Dictionaries in regular AutoCAD. If we could automate exploding AEC objects to blocks in regular AutoCAD, that would be even better.

[MP]

Frustrating thread is frustrating. Subtitle: <I believe> there's sooooo much I could add to this thread, but I cannot under my current terms of employ. Having said that, there is tons of talent herein so my lack of participation is only a consequence for me. Kudos ya'll.

[Pepe]

Hi Lee Mac...

Sorry to say that '(command "_.-scalelistedit" "_D" "*" "_E")' doesn't work (in my version, at least...). It spits something like (traslating...) 'The scale "*" does not exists.'

I've tried via Dictionaries. I've used sometimes simply '(dictremove (namedobjdict) "ACAD_SCALELIST")' and file size decreased quite a lot. But, I've gone a little bit further, and I've tried this now:

Code - Auto/Visual Lisp: [Select]

1. (setq scls (dictsearch (namedobjdict) "ACAD_SCALELIST"))
2. (foreach n scls
3. (if (= (car n) 350) (setq lscl (cons (cadr n) lscl)))
4. )
5. (mapcar 'entdel lscl)
6.  

'SCALE' entities disappear, but if you call the command "_scalelistedit", scales are still there... ... :ugly:

Well. Curious, isn't it?

[irneb]

I've tried via Dictionaries. I've used sometimes simply '(dictremove (namedobjdict) "ACAD_SCALELIST")' and file size decreased quite a lot. But, I've gone a little bit further, and I've tried this now:

I'd be extremely careful about simply erasing the scales dictionary or any one scale from that. And you will keep on seeing them in the scales list because ACad tries to fix this possible crash situation of having no scales to display.

You need at least one scale left in the DWG. And you actually shouldn't delete scales which has been applied to something - that tends to crash acad. Erasing all scales' dictionaries do not test for scales being applied before deleting them. Anyhow thus use the Reset option in the scalelistedit command - that's a lot safer. Otherwise you'll need to step through everything in the DWG to see which scales can be erased.

[Pepe]

I've tried via Dictionaries. I've used sometimes simply '(dictremove (namedobjdict) "ACAD_SCALELIST")' and file size decreased quite a lot. But, I've gone a little bit further, and I've tried this now:

I'd be extremely careful about simply erasing the scales dictionary or any one scale from that. And you will keep on seeing them in the scales list because ACad tries to fix this possible crash situation of having no scales to display.

You need at least one scale left in the DWG. And you actually shouldn't delete scales which has been applied to something - that tends to crash acad. Erasing all scales' dictionaries do not test for scales being applied before deleting them. Anyhow thus use the Reset option in the scalelistedit command - that's a lot safer. Otherwise you'll need to step through everything in the DWG to see which scales can be erased.

Irneb, thank you very much for your advices!

My problems with scales came from a DWG file I recieved from a partner, used as a XREF in a project, in which I detected 6832 different scales (I suppose inherited from other drawings). Every drawing with that XREF attached took about 3 minutes to open ( :realmad: !!!). After I detected the problem, I just deleted the dictionary (the way I've posted), and saved... and it worked: default scales list were re-built as the file was opened without any other problem, 300kb saved in HD and few seconds to open drawings (sometimes, I go breathless, I swear  :doa:).

Just another curiosity 'to whom it may concern': I've used "scalelistedit" (NOT "-scalelistedit") against those 6832 scales, and it appears an error message saying "Matrix index out of range"...   Of course, "-scalelistedit", option "Reset", works properly.

Regards.

[Jeff H]

Do you guys want to match it up against a .NET version?
 
I was just going to Wblock the entire drawing then save it back to same file.

[irneb]

My problems with scales came from a DWG file I recieved from a partner, used as a XREF in a project, in which I detected 6832 different scales (I suppose inherited from other drawings). Every drawing with that XREF attached took about 3 minutes to open ( :realmad: !!!).

This is why I'm saying ADesk are idiots with the scales list. They don't have a clue about what a scale-name is supposed to be. They should never have written the extra code to affix that _XREF to the scale's name when loaded from a xref - there's no benefit to it and it causes this exponential growth in scales.

Just another curiosity 'to whom it may concern': I've used "scalelistedit" (NOT "-scalelistedit") against those 6832 scales, and it appears an error message saying "Matrix index out of range"...   Of course, "-scalelistedit", option "Reset", works properly.

That's because it's trying to load all 6832 names into the list for display in the dialog. And that listbox has a maximum length.

BTW, older acads popped up with that message due to the same list being displayed in the status bar - so you got that message simply by opening a dwg. Newer acads have an option to "Hide XRef Scales" so these are then not displayed in that dialog / status bar list. Though it only solves the issue of this error message, the _XREF scales are still there causing the usual slowdowns, they're just "out-of-sight-out-of-mind".

[Pepe]

Irneb, thank you very much, again, for your advices...  !

In Spain, we have a funny and rough way to say that someone has been taught. In direct translation from spanish... he or she has been dis-donkeyed (yes, from donkey, that also means in spanish, dunce). So, I've been dis-donkeyed a lot about dealing with scales!

Regards.

[Peter2]

AutoCAD >= 2012 has a standard-purge-command for "groups". Is the code here different from the "internal-purge"?

[ur_naz]

Think it is not a good idea to put all purge routines in single command because lisp is too slow even if compiled. On huge drawings it will freeze or even crash autocad

[ronjonp]

Think it is not a good idea to put all purge routines in single command because lisp is too slow even if compiled. On huge drawings it will freeze or even crash autocad

If you just use a simple wblock it's not slow at all.

[MP]

There are a number of precautions one need take when using wblock * (or -ExportToAutoCAD yada) to ensure things don't FUBAR on you. This includes making sure the WCS is active in all paper-space resident viewports and model-space before performing the export. Failure to ensure will sometimes produce wack-a-doodle, undersirable results ...

/Red Sector A

[ronjonp]

There are a number of precautions one need take when using wblock * (or -ExportToAutoCAD yada) to ensure things don't FUBAR on you. This includes making sure the WCS is active in all paper-space resident viewports and model-space before performing the export. Failure to ensure will sometimes produce wack-a-doodle, undersirable results ...

/Red Sector A

Funny you say that .. noticed that many moons back when I wblocked some files with twisted UCS set to view and shite was out in space


Fixed it with:

Code - Auto/Visual Lisp: [Select]

1. (setvar 'tilemode 1)
2. (command "_.ucs" "_World")
3. (command "._-wblock" file "*")

[MP]

Yep ... and post processing is required to fix other wblock | exporttoautocad | yada aberrations. For example: wipeouts.

[HasanCAD]

I belive this part of code ahould be considered (copied from another thread)

Code: [Select]

  ((lambda (dict)
     (if (dictsearch (namedobjdict) dict)
       (progn
(dictremove (namedobjdict) dict)
(princ "\nDGN Line Styles Removed")
       )
       (princ "\nDGN Line Styles not found")
     )
   )
    "ACAD_DGNLINESTYLECOMP"
  ) ;Delete DGN

[HasanCAD]

This too

Code: [Select]

(vl-load-com)
(setq doc (vla-get-ActiveDocument (setq *acad (vlax-get-Acad-Object))))

(progn
  (vlax-for layer (vla-get-Layers doc)
    (vl-catch-all-apply
      'vla-Remove
      (list (vla-GetExtensionDictionary layer)
    "ADSK_XREC_LAYER_RECONCILED"
      )
    ) ;(vl-catch-all-apply 'vla-Delete (list (vla-GetExtensionDictionary layer)))
  )
  (princ "\nRECONCILED Layers Removed")
) ; Delete reconciled filter


[ur_naz]

This code deletes all non-acad dictionaries.

Code - Auto/Visual Lisp: [Select]

1. (foreach & (entget (namedobjdict))
2.             (or (/= 3 (car &))
3.                 (wcmatch (strcase (cdr &)) "ACAD_*")
4.                 (wcmatch (cdr &) "AcDb*")
5.                 (dictremove (namedobjdict) (cdr &))
6.             )
7.           )

[Peter2]

This code deletes all non-acad dictionaries. ...

I would say it is important to make differences between "Purging" (not used) things and deleting things.

[MP]

This code deletes all non-acad dictionaries...

I HIGHLY advise against the sledge hammer approach. For example, if you delete "Ks_ShapeRefDictionary" you are in for a world of pain and quite possibly a lynching. Not all non acad dictionaries are evil and many of them are essential. In the case of "Ks_ShapeRefDictionary" it's essential for proper loading/display even if you are a mere consumer of a model (rather than the owner/maintainer).

tl:dr: Don't be the guy who knows enough to be dangerous.

[ur_naz]

This code deletes all non-acad dictionaries...

I HIGHLY advise against the sledge hammer approach. For example, if you delete "Ks_ShapeRefDictionary" you are in for a world of pain and quite possibly a lynching. Not all non acad dictionaries are evil and many of them are essential. In the case of "Ks_ShapeRefDictionary" it's essential for proper loading/display even if you are a mere consumer of a model (rather than the owner/maintainer).

tl:dr: Don't be the guy who knows enough to be dangerous.

Sometimes we have no choise to be or not to be a chicken. Life is also dangerous, it cause death.
At least noone said you cannot add filter mask for exceptions.

I had purged drawings deleting dictionaries 6mb->250kb, 150mb->20mb. Sure, all that MBs was very useful.

[MP]

This isn't about being a chicken. It's about judicious use of technique. As for espousing the merits of cleaning files you're preaching to the choir.

[ur_naz]

This isn't about being a chicken. It's about judicious use of technique. As for espousing the merits of cleaning files you're preaching to the choir.

Some drawings like a boat floating from hands to hands. When drawing I recieve freezes my autocad I extremely need to clean all damn garbage to do my work.
I also need s/pline optimization including processing in blocks or/and to restore exploded text from lines and arcs. And of course I need to explode all proxy. So don't say me about danger. I have no idea on how to be careful 

[Kerry]

< .. >  And of course I need to explode all proxy. So don't say me about danger. I have no idea on how to be careful 

With all due respect .. In this case you will deserve all the pain that will be heaped upon your head.

[Keith™]

I applaud the use of these techniques to clean up bloat in drawings. My average drawing is under 200k and I regularly purge everything. If it isn't in needed "right now", it gets purged ... I also flatten and overkill often just to make dang sure there isn't anything floating about in space or overlapping unnecessarily.

I only do 2d drawings so flattening it doesn't matter .. and I don't share with others so being aggressive cleaning it up doesn't matter either.

Make sure to clean up xrefs that aren't loading and images that are no longer being loaded.

[ur_naz]

Make sure to clean up xrefs that aren't loading and images that are no longer being loaded.

This is under construction for me
Below is VVA's version

Code - Auto/Visual Lisp: [Select]

1. (defun C:DUXI (/ *error* file tmpObj retxref retimg retimgobj pat)
2. ;;; Delete Unfound Xref and Image
3. ;;; posted VVA http://forum.dwg.ru/showthread.php?t=36574
4.   (vl-load-com)
5.   (defun *error* (msg)
6.     (princ msg)
7.     (mip:layer-status-restore)
8.     (princ)
9.   ) ;_ end of defun
10.   (defun mip:layer-status-restore ()
11.     (foreach item *MIP_LAYER_LST*
12.       (if (not (vlax-erased-p (car item)))
13.         (vl-catch-all-apply
14.           '(lambda ()
15.              (vla-put-lock
16.                (car item)
17.                (cdr (assoc "lock" (cdr item)))
18.              ) ;_ end of vla-put-lock
19.              (vla-put-freeze
20.                (car item)
21.                (cdr (assoc "freeze" (cdr item)))
22.              ) ;_ end of vla-put-freeze
23.            ) ;_ end of lambda
24.         ) ;_ end of vl-catch-all-apply
25.       ) ;_ end of if
26.     ) ;_ end of foreach
27.     (setq *MIP_LAYER_LST* nil)
28.   ) ;_ end of defun
29.  
30.   (defun mip:layer-status-save ()
31.     (setq *MIP_LAYER_LST* nil)
32.     (vlax-for item
33.                    (vla-get-layers
34.                      (vla-get-activedocument (vlax-get-acad-object))
35.                    ) ;_ end of vla-get-layers
36.       (setq *MIP_LAYER_LST*
37.              (cons (list item
38.                          (cons "freeze" (vla-get-freeze item))
39.                          (cons "lock" (vla-get-lock item))
40.                    ) ;_ end of cons
41.                    *MIP_LAYER_LST*
42.              ) ;_ end of cons
43.       ) ;_ end of setq
44.       (vla-put-lock item :vlax-false)
45.       (if (= (vla-get-freeze item) :vlax-true)
46.         (vl-catch-all-apply
47.           '(lambda () (vla-put-freeze item :vlax-false))
48.         ) ;_ end of vl-catch-all-apply
49.       ) ;_ end of if
50.     ) ;_ end of vlax-for
51.   ) ;_ end of defun
52.  
53.   (defun DetachImage (ImgName)
54.     (vl-catch-all-apply
55.       '(lambda ()
56.          (vla-delete
57.            (vla-item
58.              (vla-item
59.                (vla-get-dictionaries
60.                  (vla-get-activedocument (vlax-get-acad-object))
61.                ) ;_ end of vla-get-dictionaries
62.                "ACAD_IMAGE_DICT"
63.              ) ;_ end of vla-Item
64.              ImgName
65.            ) ;_ end of vla-Item
66.          ) ;_ end of vla-Delete
67.        ) ;_ end of lambda
68.     ) ;_ end of vl-catch-all-apply
69.   ) ;_ end of defun
70.   (setq pat '("AcDbRasterImage" "AcDbBlockReference"))
71.   (vlax-for lay (vla-get-layouts
72.                   (vla-get-activedocument (vlax-get-acad-object))
73.                 ) ;_ end of vla-get-Layouts
74.     (princ "\nWait... the search for rasters and xrefs in ")(princ (vla-get-name lay))
75.     (vlax-for item (vla-get-block lay)
76.       (cond
77.         ((and
78.            (member (vla-get-objectname item) pat)
79.            (eq (vla-get-objectname item) "AcDbBlockReference")
80.            (vlax-property-available-p item 'Path)
81.            (setq file (vla-get-path item))
82.            (setq tmpObj
83.                   (vla-item
84.                     (vla-get-blocks
85.                       (vla-get-activedocument (vlax-get-acad-object))
86.                     ) ;_ end of vla-get-Blocks
87.                     (vla-get-name item)
88.                   ) ;_ end of vla-Item
89.            ) ;_ end of setq
90.          ) ;_ end of and
91.          (if
92.            (not (or (findfile file)
93.                     (findfile (strcat (vl-filename-base file)
94.                                       (vl-filename-extension file)
95.                               ) ;_ end of strcat
96.                     ) ;_ end of findfile
97.                 ) ;_ end of or
98.            ) ;_ end of not
99.            (setq retxref (cons tmpobj retxref))
100.          ) ;_ end of if
101.         )
102.         ((and
103.            (member (vla-get-objectname item) pat)
104.            (eq (vla-get-objectname item) "AcDbRasterImage")
105.            (setq file (vla-get-imagefile item))
106.          ) ;_ end of and
107.          (if
108.            (not (or (findfile file)
109.                     (findfile (strcat (vl-filename-base file)
110.                                       (vl-filename-extension file)
111.                               ) ;_ end of strcat
112.                     ) ;_ end of findfile
113.                 ) ;_ end of or
114.            ) ;_ end of not
115.            (progn
116.              (if (not (member (vla-get-name item) retimg))
117.              (setq retimg (cons (vla-get-name item) retimg)))
118.              (setq retimgobj (cons item retimgobj))
119.            )
120.          ) ;_ end of if
121.         )
122.         (t nil)
123.       ) ;_ end of cond
124.     ) ;_ end of vlax-for
125.     (princ " ...OK")
126.   ) ;_ end of vlax-for
127.   (princ "\nTotal: ")
128.   (princ (length retimg))(princ " unfound rasters and ")
129.   (princ (length retxref))(princ " unfound xrefs ")
130.   (if (or retimg retxref)
131.     (progn
132.   (initget "Image Xref Both")
133.   (setq file (getkword "Delete unfound [Image/Xref/Both] <both>: "))
134.   (cond ((= file "Image")
135.          (setq pat '("AcDbRasterImage"))
136.          )
137.         ((= file "Xref")
138.          (setq pat '("AcDbBlockReference"))
139.          )
140.         (t (setq pat '("AcDbRasterImage" "AcDbBlockReference")))
141.         )
142.   (mip:layer-status-save)
143.   (if (member "AcDbRasterImage" pat)
144.     (progn
145.       (mapcar '(lambda(x)
146.                  (vl-catch-all-apply 'vla-delete (list x))
147.                  )
148.               retimgobj
149.               )
150.        (mapcar '(lambda(x)
151.                  (vl-catch-all-apply 'DetachImage (list x))
152.                  )
153.               retimg
154.               )
155.       )
156.     )
157.    (if (member "AcDbBlockReference" pat)
158.     (progn
159.        (mapcar '(lambda(x)
160.                   (vl-catch-all-apply 'vla-detach (list x))
161.                   )
162.                retxref
163.                )
164.       )
165.     )
166.  (mip:layer-status-restore)
167.   )
168.     )
169.   (princ)
170. )

[VVA]

Some more offers
1.Remove DATALINK, DGNLINESTYLECOMP, VBA dictionary

Code: [Select]

(VL-CATCH-ALL-APPLY
   '(lambda()
 (mapcar '(lambda(x)
      (dictremove (namedobjdict) x)
           )
        '(
        "ACAD_DATALINK" 
        "ACAD_DGNLINESTYLECOMP" 
         "ACAD_VBA"
          )
        )
      )
   )
2. Removes the history from 3D solid primitives (_brep _all)
get from kpblc

Code: [Select]

(vlax-for blk_def (vla-get-blocks adoc)
        (if (equal (vla-get-isxref blk_def) :vlax-false)
          (vlax-for subent blk_def
            (if (= (vla-get-objectname subent) "AcDb3dSolid")
              (setq ent_lst (cons (vlax-vla-object->ename subent) ent_lst))
              ) ;_ end of if
            ) ;_ end of vlax-for
          ) ;_ end of if
        ) ;_ end of vlax-for
      (foreach ent ent_lst
        (if (and (cdr (assoc 350 (entget ent)))
                 (not (vl-catch-all-error-p
                        (vl-catch-all-apply
                          (function
                            (lambda () (entget (cdr (assoc 350 (entget ent)))))
                            ) ;_ end of function
                          ) ;_ end of vl-catch-all-apply
                        ) ;_ end of vl-catch-all-error-p
                      ) ;_ end of not
                 (entget (cdr (assoc 350 (entget ent))))
                 ) ;_ end of and
          (entdel (cdr (assoc 350 (entget ent))))
          ) ;_ end of if
        ) ;_ end of foreach


[ronjonp]

My take is if you're cleaning up files for internal use ( background ) .. Blast the smithereens out of them. .  if you're sharing use caution.

[Keith™]

My take is if you're cleaning up files for internal use ( background ) .. Blast the smithereens out of them. .  if you're sharing use caution.

I agree 82.5% mainly because it really depends upon why you are sharing the drawings.

Again, everything I do is 2D plan view ... I remove everything that isn't absolutely necessary for the user to actually see the layout of the plans.