Topic: Support File Search Paths being deleted.

[Bryco]

We have paths pointing to servers on 2 different drives,
When the server goes down some seats lose all the paths pointing to the now non available server drives.
Sometimes the Cuis are taken as well.  Even more annoying
Any one else have this?
Acad 2013 mechanical.

[Rob...]

That happens here all the time. The profile is getting fried when the server goes down. Fix it by importing the saved profile. Prevent it by shutting down AutoCAD before server goes down.

[Bryco]

Thanks Rob,  have you reported this to cad?

[Rob...]

LOL, nope.

[BlackBox]

While this will do nothing to restore server paths that are not accessible, I manage the SFSP (and other parts of the Profile) via Acad.lsp:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. ;;;--------------------------------------------------------------------;
3. (defun c:AcadLsp (/ *error*)
4.  
5.   (defun *error* (msg)
6.     (and oldCmdecho (setvar 'cmdecho oldCmdecho))
7.     (cond ((not msg))                                                   ; Normal exit
8.           ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
9.           ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
10.     )
11.     (princ)
12.   )
13.  
14.   ((lambda
15.      (user oldCmdecho arxList arxFiles netFiles / oFiles acadLoc)
16.       (setvar 'cmdecho 0)
17.       (terpri)
18.  
19.       ;; Load arx utilities
20.       (acad-push-dbmod)
21.       (foreach x arxFiles
22.         (if (and (findfile x)
23.                  (not (vl-position (vl-filename-base x) arxList))
24.             )
25.           (vl-catch-all-apply 'arxload (list x))
26.         )
27.       )
28.       (acad-pop-dbmod)
29.  
30.       ;; Load net utilities
31.       (foreach dll netFiles
32.         (if (findfile dll)
33.           (progn
34.             (terpri)
35.             (command "netload" dll)
36.           )
37.         )
38.       )
39.  
40.       ;; Profile information
41.       (setq oFiles (vla-get-files
42.                      (vla-get-preferences (vlax-get-acad-object))
43.                    )
44.       )
45.  
46.       (setq acadloc
47.              (vl-registry-read
48.                (strcat "HKEY_LOCAL_MACHINE\\"
49.                        (if vlax-user-product-key                        ; If 2013
50.                          (vlax-user-product-key)                        ; Use 2013 function
51.                          (vlax-product-key)                             ; Use legacy function
52.                        )
53.                )
54.                "ACADLOCATION"
55.              )
56.       )
57.  
58.       (vla-put-SupportPath
59.         oFiles
60.         (vl-string-right-trim
61.           ";"
62.           (apply
63.             'strcat
64.             (mapcar
65.               '(lambda (x) (strcat x ";"))
66.               (list
67.                 ;; <- Your custom paths
68.  
69.                 (strcat (getvar 'roamablerootprefix) "support;")
70.                 (strcat acadloc "\\civil")
71.                 (strcat acadloc "\\express")
72.                 (strcat acadloc "\\fdo\\bin")
73.                 (strcat acadloc "\\fonts")
74.                 (strcat acadloc "\\help")
75.                 (strcat acadloc "\\support")
76.                 (strcat acadloc "\\support\\color")
77.                 "C:\\programdata\\autodesk\\<SomeApp>\\enu\\data\\symbols\\mvblocks"
78.                 "C:\\program files\\autodesk\\raster design 20XX oe"
79.                 "C:\\program files\\common files\\autodesk shared"
80.                 "C:\\program files\\adsk_raster_design_20XX"
81.                 "C:\\program files\\adsk_raster_design_20XX\\help"
82.                 (strcat
83.                  "C:\\users\\"
84.                  user
85.                  "\\appdata\\roaming\\autodesk\\ard20XX\\r1X.X\\enu\\support"
86.                 )
87.                )
88.             )
89.           )
90.         )
91.       )
92.  
93.       (*error* nil)
94.    )
95.     (getvar 'loginname)                                                 ; User
96.     (getvar 'cmdecho)
97.     (arx)                                                               ; arxList
98.     '(                                                                  ; arxFiles
99.       "SomeFolder\\SomeArxName.arx"
100.       ;; <- others
101.      )
102.     '(                                                                  ; netFiles
103.       "SomeFolder\\SomeAssemblyName.dll"
104.       ;; <- others
105.      )
106.   )
107. )
108. ;;;--------------------------------------------------------------------;
109. (c:AcadLsp)
110. (prompt "\n... Acad.lsp loaded. ")
111. (princ)
112.  

[Bryco]

Thanks Renderman.
I wrote a bit of net to readd the paths and cunningly put it in a menu, that also disappeared.
Perhaps I need to set a different profile, then  check the drives for availability then set the correct profile.
For me it is a bug that cad should have fixed big time.  Anyway it is a case at autocad now.

[rkmcswain]

...... I manage the SFSP (and other parts of the Profile) via Acad.lsp:

LIKE ^^^^^^^^ 

[BlackBox]

Thanks Renderman.

You're welcome; hope it helps.

...... I manage the SFSP (and other parts of the Profile) via Acad.lsp:

LIKE ^^^^^^^^ 

While I've tried to make some thoughtful enhancements, what spawned my usage of this methodology was a very wise man who was kind enough to make this post over at CAD Panacea.