Topic: Mleader drawing Entmake or visual Lisp ?? (Figure includes)

[rlxozzang]

To Mleader LISP site when I search for it on the s command syntax. entmake or Visual Lisp Is it possible?

Code: [Select]

(defun c:DrawMleader (/ cc_echo cc_ss cc_texteval CL)
(command ".undo" "begin")
(setq CL (getvar "CLAYER"))
; (LoadMLstyle)
; (set-ML-layer)
(setq cc_texteval (getvar "texteval"))
(setvar "texteval" 1)
(setq cc_echo (getvar "cmdecho"))
(setvar "cmdecho" 1)
; (command "_.acad_dim.mleader")
; (while (= (logand (getvar "cmdactive") 1) 1)
; (command pause)
; )

(command "_.acad_dim.mleader" pause pause "")

(setvar "cmdecho" cc_echo)
(setvar "texteval" cc_texteval)
(setq cc_ss (entlast))
(if (= (vla-get-ContentType (vlax-ename->vla-object cc_ss)) 2) ;check availability of mtext content
(command "_.ddedit" cc_ss "") ;edit text and exit command
)
(setvar "CLAYER" CL)
(command ".undo" "end")
(princ)
)


[irneb]

You can use VLisp and work with the ActiveX objects. The model space object's AddMLeader method can do this for you, it creates a MLeader without any attachments (i.e. text/block). It returns a MLeader object which you can then set properties on as you wish.

[rlxozzang]

You can use VLisp and work with the ActiveX objects. The model space object's AddMLeader method can do this for you, it creates a MLeader without any attachments (i.e. text/block). It returns a MLeader object which you can then set properties on as you wish.

Lack of my skills to a visual approach to help the Lisp examples, the question once again sought help. ㅜ ㅜ

[DW]

Here's a Multileader routine which utilises a standard mleader style assuming it has one leader and some text rather than a block.  I've put it in a grread  loop so its a bit more dynamic. 

You might want to set up or modify an existing multilieader style before using it. 

Hope this helps 

Code - Auto/Visual Lisp: [Select]

1. (defun c:vlMl (/ p1 p2 label input *lead)
2.   (vl-load-com)
3.  
4.   (if (and (setq label (getstring T "\nSpecify label text"))
5.            (setq p1 (getpoint "\nPick Mulitleader start point"))
6.       )
7.    
8.   (progn (setq p2 p1)
9.          (princ "\nPick label location")
10.          (while (and p2
11.                      (setq input (grread t 9 0))
12.                      (or (= (car input) 5) (= (car input) 3) (= (car input) 2))
13.                 )
14.            (cond ((= (car input) 5) (mkmleader (cadr input))) ;tracking coordinates returned
15.                  
16.                  ((= (car input) 2) (setq p2 nil) (if *lead (vla-delete *lead))) ;keyboard input - exit
17.                  
18.                  ((= (car input) 3) (setq p2 nil));point picked - exit while loop
19.                  
20.                  (T (setq p2 nil)(if *lead (vla-delete *lead)))
21.            )
22.          )
23.     (princ)
24.   )
25. )
26.   )
27.  
28. (defun mkmleader ( p2 / pts)
29.  
30.   (if (not *lead);create the multileader if it doesn't exist
31.      (progn (setq pts (list (trans p1 1 0) (trans p2 1 0))
32.                   pts (gc:3dPointListToVariant pts)
33.             )
34.            (setq *lead (vla-AddMLeader
35.                         (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)));get modelspace object
36.                         pts
37.                         0
38.                       )
39.            )
40.            (vla-put-textstring *lead label)
41.            (vla-rotate
42.              *lead
43.              (vlax-3d-point (trans p2 1 0))
44.              (angle (trans '(0 0 0) 1 0) (trans '(1 0 0) 1 0))
45.            )
46.       )
47.     ;the object already exists so just update it
48.     (progn
49.       (setq pts (list (trans p1 1 0) (trans p2 1 0))
50.             pts (gc:3dPointListToVariant pts))
51.      
52.       (vla-SetLeaderLineVertices *lead 0 pts);redefine the vertices
53.       (vla-SetDogLegDirection *lead 0 (vlax-3D-point (trans (list (if (> (car p2) (car p1)) 1 -1) 0 0) 1 0 T)));change direction of dogleg according to cursor position relative to start point
54.       (vla-update *lead)
55.     )
56.   )
57. )
58.  
59. ;; Thanks to Gile!
60. ;;
61. ;; Return a variant of 3d coordinates
62. ;;
63. ;; Argument: a 3d points list -type (x y z)-
64.  
65. (defun gc:3dPointListToVariant (lst)
66.   (vlax-make-variant
67.     (vlax-safearray-fill
68.       (vlax-make-safearray
69.         vlax-VbDouble
70.         (cons 0 (1- (* 3 (length lst))))
71.       )
72.       (apply 'append lst)
73.     )
74.   )
75. )
76.  

[rlxozzang]

Here's a Multileader routine which utilises a standard mleader style assuming it has one leader and some text rather than a block.  I've put it in a grread  loop so its a bit more dynamic. 

You might want to set up or modify an existing multilieader style before using it. 

Hope this helps 

DW Thank you.^ ^ Multileader saw a ray of light.