Topic: function to create a list out of strings

[andrew_nao]

sorry i have to ask this
there was a post here at one point that had a function to create a list of strings without assigning it to a variable.
im unable to find it in a serarch and for the life of me i dont even remember who make it but i do remember seeing it here.

would anyone happen to know what im refering to and would you have that link?

[Gasty]

Hi,

I'm not sure to understand, where are the strings? or where they come from?

Gaston Nunez

[dgorsman]

Do you mean, create several variable names in sequence ie. var1 var2 var3 ?

[reltro]

Hey...

Not sure what u mean...
maybe like this?

Code - Auto/Visual Lisp: [Select]

1. (mapcar 'getstring '("Enter String 01: " "Enter String 02: " "Enter String 03: " "Enter String 04: "))

This piece of code collects 4 strings by asking the user to enter them...
The return is a list of the collected strings...

greets reltro

[andrew_nao]

thanks for everyones replies
i found the code in an old lisp test file that i had
sadly i dont know who wrote it to give the credit to.

here is the code tho if anyone has need. credit to "unknown"

Code: [Select]

(defun str2lst (str sep / pos)
  (if (setq pos (vl-string-search sep str))
    (cons (substr str 1 pos)
  (str2lst (substr str (+ (strlen sep) pos 1)) sep)
    )
    (list str)
  )
)

;useage: (str2lst var " ")


[Lee Mac]

Perhaps this was the droids thread you were looking for?

http://www.theswamp.org/index.php?topic=32845.0

[Marc'Antonio Alessi]

here is the code tho if anyone has need. credit to "unknown"

credit to gile (France).
http://www.theswamp.org/index.php?topic=22034.msg265916#msg265916

Another version:

Code: [Select]

; Function: ALE_String_ToList
;
; Version 1.00 - 01/2010
;
; Description:
;   convert a string into a list of strings
;
; Arguments:
;   InpStr = string [STR]
;   CarDlm = delimiter [STR] 1 character
;   TrueFl = if nil remove dupes delimiter
;
; Examples:
;  (ALE_String_ToList "aaa_vvv_hhh__yyy ___lll_" "_" T)
;  ("aaa" "vvv" "hhh" "" "yyy " "" "" "lll" "lll")
;
;  (ALE_String_ToList "aaa_vvv_hhh__yyy ___lll_" "_" nil)
;  ("aaa" "vvv" "hhh" "yyy " "lll")
;
(defun ALE_String_ToList (InpStr CarDlm TrueFl / SttPos EndPos TmpLst TmpStr)
  (setq
    CarDlm (ascii CarDlm)   SttPos 0
    EndPos (vl-string-position CarDlm InpStr)
  )
  (while EndPos
    (setq
      TmpStr (substr InpStr (1+ SttPos) (- EndPos SttPos))
      SttPos (1+ EndPos) EndPos (vl-string-position CarDlm InpStr SttPos)
    )
    (and
      (or (/= TmpStr "") TrueFl)
      (setq TmpLst (cons TmpStr TmpLst))
    )
  )
  (if (or (/= (setq TmpStr (substr InpStr (1+ SttPos))) "") TrueFl)
    (reverse (cons TmpStr TmpLst))
    (reverse TmpLst)
  )
)

[andrew_nao]

here is the code tho if anyone has need. credit to "unknown"

credit to gile (France).
http://www.theswamp.org/index.php?topic=22034.msg265916#msg265916

thanks Marc'Antonio. thats the thread i was looking for

and thanks Lee  for your post as well. i dont know why they didnt show up in the search
and thanks Gile for your code

[andrew_nao]

my title is misleading because its supposed to say create a list out of string
sorry

[ronjonp]

my title is misleading because its supposed to say create a list out of string
sorry

You can change the title still ...

[andrew_nao]

done.

didnt realize that, thanks