Topic: purge everything but layers

[andrew_nao]

in a lisp im using this line to purge everything

Code: [Select]

(vla-purgeall (vla-get-activedocument (vlax-get-acad-object)))its is in a file that is loaded on startup and (not thinking) this seems to be effecting my dwg templates by deleting my layers.
i would like to change this around and have it purge everything except my layers and im having a bit of a brain fart.
can anyone suggest a better way?

[Lee Mac]

The purgeall method is unfortunately an 'all-or-nothing' approach - you cannot control which collections will be purged. As an aside, note that the purgeall method will also skip Multileader Styles when purging a drawing - this is a known bug.

Since you don't wish to purge your template, how about testing whether the drawing has been saved before performing the purge, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (if (= 1 (getvar 'dwgtitled))
2.     (progn
3.         (setq doc (vla-get-activedocument (vlax-get-acad-object)))
4.         (repeat 3 (vla-purgeall doc))
5.     )
6. )

Alternatively, use the -purge command to purge specific colections.

[Tharwat]

This could be of a use . 

Code - Auto/Visual Lisp: [Select]

1. (defun c:test (/ l p)
2.   (while
3.     (setq l (tblnext "LAYER" (null l)))
4.      (setq p (cons (entmakex (list '(0 . "POINT")
5.                                    (list 10 0. 0. 0.)
6.                                    (cons 8 (cdr (assoc 2 l)))
7.                              )
8.                    )
9.                    p
10.              )
11.      )
12.   )
13.   (repeat 3
14.     (vla-purgeall
15.       (vla-get-activedocument (vlax-get-acad-object))
16.     )
17.   )
18.   (foreach x p (entdel x))
19.   (princ)
20. )

[ronjonp]

You might want to check that the layer is unlocked before creating the points. Otherwise they will not get removed.

[irneb]

Another alternative way might be to simply save a list of layers into a variable, do the purgeall, then step through the list recreating any layers not found with their saved properties. Something like this:

Code - Auto/Visual Lisp: [Select]

1. (defun PurgeAll-ButLayers  (doc / layers layer-collection new)
2.   (vl-load-com)
3.   (vlax-for lay  (setq layer-collection (vla-get-Layers doc))
4.     (setq layers
5.            (cons (mapcar '(lambda (property) (cons property (vl-catch-all-apply 'vlax-get (list lay property))))
6.                          '("Name"           "Description"    "Freeze"         "LayerOn"        "Linetype"
7.                            "Lineweight"     "Lock"           "Material"       "PlotStyleName"  "Plottable"
8.                            "TrueColor"      "ViewportDefault"))
9.                  layers)))
10.   (vla-PurgeAll doc)
11.   (foreach lay  layers
12.     (if (not (vl-catch-all-error-p (setq new (vl-catch-all-apply 'vla-add (list layer-collection (cdar lay))))))
13.       (foreach property (cdr lay) (vl-catch-all-apply 'vlax-put (list new (car property) (cdr property)))))))