Topic: IP address...

[Andrea]

ok..

there is another one..
Can we get the IP address in LISP ??

some command like (vl-getip)  ??


 

[TR]

Not 100% sure but try doslib.

http://www.mcneel.com/doslib.htm

[MP]

I've been using a small dll I wrote years ago in VB that encapsulates a number of network related API calls. I can call it from Visual LISP.

See www.vbnet.mvps.org.

[Andrea]

Not 100% sure but try doslib.

http://www.mcneel.com/doslib.htm

Yes, I know...
but i forgot to tell that i don'T want to load an ARX just for adding a simple line in LISp...

[Andrea]

I've been using a small dll I wrote years ago in VB that encapsulates a number of network related API calls. I can call it from Visual LISP.

See www.vbnet.mvps.org.

sorry..but same thing with DLL...
just need to know if there is a command or variable in LISP.

[MP]

:)

[Andrea]

Sorry,...but don't want to load anything else that the LISP file..
so in VBA need to load VBA module.. (VBALOAD)   see ?

[kozmos]

you can add a .dvb file into VLX as resource file while compile and then load the dvb in runtime

[SMadsen]

Here's a lisp you can tweak into getting some IP's

Code: [Select]

(defun IPReport (/ ws fn fp ln)
  (setq ws (vlax-get-or-create-object "WScript.Shell")
        fn (strcat (getenv "SystemDrive") "\\ipid.txt"))

  (vlax-invoke-method ws "Run" (strcat "%comspec% /c ipconfig /all >> " fn))

  (cond ((findfile fn)
         (setq fp (open fn "r"))
         (while (setq ln (read-line fp))
           (princ ln)
           (terpri)
         )
         (close fp)
         (vl-file-delete fn)
        )
  )
  (vlax-release-object ws)
  (princ)
)

[MP]

Good one Stig, I forgot about that technique.

Note: If one uses the redirected ipconfig output be careful when parsing the ipaddress -- the ipconfig output format changes slightly between Windows versions.

This works under Windows 2000, not sure about other Windows versions:

Code: [Select]

(defun GetIPAddress ( / cmdecho tempfile handle stream result  )

    (setq cmdecho (getvar "cmdecho"))
    (setvar "cmdecho" 0)

    (command ".shell"
        (strcat "ipconfig > "
            (setq tempfile
                (vl-filename-mktemp "ipconfig.txt")
            )            
        )
    )
   
    (setvar "cmdecho" cmdecho)
   
    (cond
        (   (setq handle (open tempfile "r"))
            (vl-catch-all-apply
               '(lambda ()
                    (while (setq stream (read-line handle))
                        (cond
                            (   (wcmatch
                                    (setq stream (strcase stream))
                                    "*IP ADDRESS*"
                                )
                                (setq result stream)
                                (exit)
                            )    
                        )
                    )
                )
            )    
            (close handle)
        )    
    )
   
    (if result
        (vl-string-trim " "
            (vl-list->string
                (cdr
                    (member 58
                        (vl-string->list result)
                    )
                )
            )    
        )    
    )    
)

[MP]

A friend just confirmed it works under Windows XP Pro.

[SMadsen]

Somehow I couldn't get ipconfig to write to a file with the wscript method. That's why I did the %comspec% call. It worked.
Of course, the SHELL command hovered right over my head without ever touching down  Heh
Thanks for the reminder, Michael.

[MP]

Funny, when I saw the use of wscript I thought "That's great, no more momentary dos window flash", but it still appears, so I thought shell would be just as effective; maybe a smidge faster. Still wscript, file system object etc. are good tools for the box.

Thanks for the initial idea Stig, have a great weekend.

:)

[Andrea]

hey...this is cool..

but how can i run this witout the DOS screen ?

[Kerry]

Not really off topic ..

Has anyone had difficulty using WScript with regard to Virus Scanners ??