Topic: Changing Plotter for Many Files in Multiple Directories

[Rob...]

I have many files in multiple directories that need the plotters changed. For some reason, the .pc3 files for our OCE plotters causes a very long delay in the plot (and page set up) dialog box coming up. I was wondering if it is possible to do this as batch routine of some sort.

[ronjonp]

Maybe this will help: http://www.theswamp.org/index.php?topic=42422.msg476061#msg476061

Or maybe something as simple as this:

Code: [Select]

(defun _foo (doc old new)
  (vlax-for x (vla-get-layouts doc)
    (if (wcmatch (strcase (vla-get-configname x)) (strcase old))
      (vl-catch-all-apply 'vla-put-configname (list x new))
    )
  )
)
(_foo (vla-get-activedocument (vlax-get-acad-object)) "oldoce.pc3" "newoce.pc3")

[Rob...]

Thank you. Excuse my ignorance of code but could you explain to me what it does? I see where it switches the plotter names (that I would replace with mine). Is it a batch routine or would I have to open each drawing manually?

[ronjonp]

Thank you. Excuse my ignorance of code but could you explain to me what it does? I see where it switches the plotter names (that I would replace with mine). Is it a batch routine or would I have to open each drawing manually?

The code cycles through the layout tabs and looks for a configuration name that you specify. I can put something together that will batch this in a bit via object dbx.

[Rob...]

That would be cool and very much appreciated.

[ronjonp]

Here you go. This will process a directory and its subdirectories.
You will need to specify your old and new plotters at the top of the code.
A log file is created so you can check what files were actually changed.
Please run this on some dummy data first.

Code - Auto/Visual Lisp: [Select]

1. (defun c:changepc3
2.        (/ _openfile _subfolders _getdirectory dir doc folders l logfile new odbx old save v)
3.   (vl-load-com)
4.   ;; Change this value - ie. { "old.pc3" or "\\\\servername\\oldsharedprintername" }
5.   (setq old "old.pc3")
6.   ;; Change this value - ie. { "new.pc3" or "\\\\servername\\newsharedprintername" }
7.   (setq new "new.pc3")
8.   (defun _openfile (file / sh)
9.     (if (findfile file)
10.       (progn (setq sh (vlax-get-or-create-object "Shell.Application"))
11.              (vlax-invoke-method sh 'open (findfile file))
12.              (vlax-release-object sh)
13.              file
14.       )
15.     )
16.   )
17.   (defun _getdirectory (message / sh folder result)
18.     (setq sh (vlax-get-or-create-object "Shell.Application"))
19.     (setq folder (vlax-invoke-method sh 'browseforfolder 0 message 0))
20.     (vlax-release-object sh)
21.     (if folder
22.       (progn (setq result (vlax-get-property (vlax-get-property folder 'self) 'path))
23.              (if (/= (substr result (strlen result)) "\\")
24.                (setq result (strcat result "\\"))
25.                result
26.              )
27.       )
28.     )
29.   )
30.   (defun _subfolders (path / folder fs lst subs)
31.     (setq fs (vlax-get-or-create-object "Scripting.FileSystemObject"))
32.     (if
33.       (and (setq folder (vlax-invoke fs 'getfolder path)) (setq subs (vlax-get folder 'subfolders)))
34.        (mapcar (function (lambda (x) (cons x (apply 'append (_subfolders x)))))
35.                (vlax-for sub subs (setq lst (cons (strcat (vlax-get sub 'path) "\\") lst)))
36.        )
37.     )
38.   )
39.   (setq doc (vlax-get-acad-object))
40.   (cond
41.     ((not (setq odbx (if (< (setq v (substr (getvar 'acadver) 1 2)) "16")
42.                        (vla-getinterfaceobject doc "ObjectDBX.AxDbDocument")
43.                        (vla-getinterfaceobject doc (strcat "ObjectDBX.AxDbDocument." v))
44.                      )
45.           )
46.      )
47.      (princ "\nObject DBX interface not created!")
48.     )
49.     ((if (and (setq dir (_getdirectory "Choose a folder to process (subfolders processed too)..."))
50.               (and (setq folders (apply 'append (_subfolders dir)))
51.                    (setq folders (append (list dir) folders))
52.               )
53.               (setq logfile (open (setq l (strcat dir "logfile.csv")) "w"))
54.          )
55.        (progn
56.          (write-line "FILE,TABS UPDATED,SAVED" logfile)
57.          (foreach folder folders
58.            (foreach file (vl-directory-files folder "*.dwg" 0)
59.              (if (vl-catch-all-error-p
60.                    (vl-catch-all-apply 'vla-open (list odbx (strcat folder file)))
61.                  )
62.                (write-line (strcase (strcat "!!Error opening: " (strcat folder file))) logfile)
63.                (progn
64.                  (setq save 0)
65.                  (vlax-for x (vla-get-layouts odbx)
66.                    (if (wcmatch (strcase (vla-get-configname x)) (strcase old))
67.                      (progn (and (not (vl-catch-all-error-p
68.                                         (vl-catch-all-apply 'vla-put-configname (list x new))
69.                                       )
70.                                  )
71.                                  (setq save (1+ save))
72.                             )
73.                      )
74.                    )
75.                  )
76.                  (if (zerop save)
77.                    (write-line (strcat (strcat folder file "," (itoa save) ",NO")) logfile)
78.                    (progn (write-line (strcat (strcat folder file "," (itoa save) ",YES")) logfile)
79.                           (vla-saveas odbx (vla-get-name odbx))
80.                    )
81.                  )
82.                )
83.              )
84.            )
85.          )
86.          (close logfile)
87.          (_openfile l)
88.        )
89.      )
90.     )
91.   )
92.   (princ)
93. )

[ronjonp]

Did this work for you?

[Rob...]

Mr. Jonp,

Thank you for this. Sorry to leave you hanging but I was out sick for a couple days. I will definitely give this a trial run, hopefully today if I get caught up enough.

[ronjonp]

Mr. Jonp,

Thank you for this. Sorry to leave you hanging but I was out sick for a couple days. I will definitely give this a trial run, hopefully today if I get caught up enough.

No worries .. let me know how it goes.  Hope you feel better.

[Rob...]

It works. Because some people don't know how to not change page set-ups, I changed the old name to "*". Worked like a charm.

[ronjonp]

It works. Because some people don't know how to not change page set-ups, I changed the old name to "*". Worked like a charm.