Topic: isolate/turnoff blocks

[GISDUDE]

Hey all,
Is there a small LISP file that may be out there to turn off a block? The problem I have is that I frequently get CAD drawings from other firms' that have their own blocks, but I would like to be able to turn off the blocks. The issue is that the the layers the blocks were created on - the block will still be visible b/c the layer is still visible.

My gut feeling is you'll say - explode blocks and put them on one layer. That is a lot of blocks to explode!

Many thanks, - BTW I'm on bricscad 12.2

[Lee Mac]

Does Bricscad 12.2 have the ISOLATEOBJECTS command?

If not, try this simple program to toggle the DXF Visibility flag:

Code - Auto/Visual Lisp: [Select]

1. (defun c:showit ( / i s )
2.     (if (setq s (ssget "_X" '((60 . 1))))
3.         (repeat (setq i (sslength s))
4.             (_substdxf 60 0 (entget (ssname s (setq i (1- i)))))
5.         )
6.     )
7.     (princ)
8. )
9.  
10. (defun c:hideit ( / i s )
11.     (if (setq s (ssget "_:L"))
12.         (repeat (setq i (sslength s))
13.             (_substdxf 60 1 (entget (ssname s (setq i (1- i)))))
14.         )
15.     )
16.     (princ)
17. )
18.  
19. (defun _substdxf ( key value elst / pair )
20.     (if (setq pair (assoc key elst))
21.         (entmod (subst (cons key value) pair elst))
22.         (entmod (append elst (list (cons key value))))
23.     )
24. )

The above should work for all objects, not just blocks.

[GISDUDE]

Lee,
Thanks for the reply.
1) Bricscad doesn't have the ISOLATEOBJECTS command. Bummer, b/c I think that would've solved the problem fairly quickly.

2) Bricscad doesn't have a DXF VISIBILITY FLAG, either. However, the little code snippet you posted did work out tremendsously. My supervisor is a LISP guy and he kinda showed me how to execute this particular code. One thing though, why couldn't there be a way to explode those PARTICULAR BLOCKS (in this case there were 62), and then turn off those layers? I'm assuming this is probably 2 or 3 more steps in a LISP script?

Thanks again, that was definitely a bonus.

[Tharwat]

Hi Lee .

When the variable pair would return nil to go to the else option in if function into your sub-routine _substdxf ?

Thanks

[roy_043]

@ GISDUDE:
The fact that Lee's code works proves that Bricscad does have a dxf visibility flag!
But I would strongly advise against using this method. Invisible objects can, obviously, be very confusing both for other users and for you yourself in the future. Why don't you put the inserts on a dedicated layer and FREEZE that layer?

[gile]

Hi Lee .

When the variable pair would return nil to go to the else option in if function into your sub-routine _substdxf ?

Thanks

With the 62 DXF group for example, when the entity color is ByLayer.

[Tharwat]

Hi Lee .

When the variable pair would return nil to go to the else option in if function into your sub-routine _substdxf ?

Thanks

With the 62 DXF group for example, when the entity color is ByLayer.

Hi gile .

I think Lee used the DXF Visibility flag and not the 62 dxf for color !
Thanks

[gile]

Hi Lee .

When the variable pair would return nil to go to the else option in if function into your sub-routine _substdxf ?

Thanks

With the 62 DXF group for example, when the entity color is ByLayer.

Hi gile .

I think Lee used the DXF Visibility flag and not the 62 dxf for color !
Thanks

Yes but I think the _substdxf is a 'generic purpose function' not directly related to this subject.

[Tharwat]

Yes but I think the _substdxf is a 'generic purpose function' not directly related to this subject.

Now it is clear , thank you so much Gile . 

[Lee Mac]

Lee,
Thanks for the reply.

You're welcome

1) Bricscad doesn't have the ISOLATEOBJECTS command. Bummer, b/c I think that would've solved the problem fairly quickly.

I thought this suggestion might be a long shot since the ISOLATEOBJECTS command is new to AutoCAD 2012, but it was worth a try.

2) Bricscad doesn't have a DXF VISIBILITY FLAG, either. However, the little code snippet you posted did work out tremendsously.

As roy_043 correctly states, the fact that my code works for you would indicate that entities in Bricscad do indeed use the DXF Group 60 Visibility flag.

One thing though, why couldn't there be a way to explode those PARTICULAR BLOCKS (in this case there were 62), and then turn off those layers? I'm assuming this is probably 2 or 3 more steps in a LISP script?

I'm assuming that you cannot simply turn off the layers of the objects constituting the block as there are other objects residing on those layers which should be visible?

When the variable pair would return nil to go to the else option in if function into your sub-routine _substdxf ?

As far as I know, the DXF Group 60 code (visibility flag) will not be present if the object is visible (60 . 0), in the same way that Group 62 will not be present for ByLayer, as gile has posted.