Topic: Dataextraction Using Autolisp....?

[Vince]

Hello Swamp Members,

I am trying to automate the creation of a AutoCAD table, using Autolisp, for specific blocks containing 3 attributes on my drawing files. I would like the table to contain those 3 attributes plus the X, Y, Z coordinates of the insertion point for those blocks. I can accomplish this manually using the Dataextraction command and stepping through the options one screen at a time to eventually create the table.  I even tried to create a template file (.dxe) and used the -Dataextraction command but have been unsuccessful in automating the process (via autolisp) so that our engineers (who are not good CAD operators) can seemlessly create the tables automatically.

Can the creation of the table be automated....??  Is there any examples I can use to help me solve this problem....??

Any assistance would be appreciated....!


Regards,
Vince

[Krushert]

Interesting.  never thought of automating it but the OTB is kind of clunky.   

Sorry I can not offer any assitance but I can offer white noise.   

[BlackBox]

I don't have time to write a full routine specific to this task (more information is needed anyway), but you're welcome to pilfer this code used to extract the point number, elevation, and description from survey points and write this data to a temporary file, which is opened in Excel and can then be saved (or not).

I don't have much need for tables, but if you format the generated file to your liking and save to your project, a simple paste special as AutoCAD entity should do the trick, and link the AutoCAD Table to your Excel.

HTH

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun c:TopoToAscii (/ *error* ss n path acApp acDoc oShell tag pt# elev desc pt)
4.  
5.   (defun *error* (msg)
6.     (if oShell
7.       (vlax-release-object oShell)
8.     )
9.     (if file
10.       (close file)
11.     )
12.     (cond ((not msg))                                                   ; Normal exit
13.           ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
14.           ((princ (strcat "\n** Error: " msg " ** ")))
15.     )                                                                   ; Fatal error, display it
16.     (princ)
17.   )
18.  
19.   (if (and (setq ss (ssget "_x" (list '(0 . "INSERT") (cons 2 "YourBlockName"))))
20.            (setq n (sslength ss))
21.            (setq path
22.                   (strcat (vl-filename-directory (vl-filename-mktemp))
23.                           "\\"
24.                           (getvar 'dwgname)
25.                           ".csv"
26.                   )
27.            )
28.            (setq acApp (vlax-get-acad-object))
29.            (setq acDoc (vla-get-activedocument acApp))
30.            (setq oShell
31.                   (vla-getinterfaceobject acApp "Shell.Application")
32.            )
33.       )
34.     (progn
35.       (setq file (open path "w"))
36.       (vlax-for x (setq ss (vla-get-activeselectionset acDoc))
37.         (foreach attrib (vlax-invoke x 'GetAttributes)
38.           (cond ((= "POINT_NUMBER" (setq tag (vla-get-tagstring attrib)))
39.                  (setq pt# (vla-get-textstring attrib))
40.                 )
41.                 ((= "ELEVATION" tag)
42.                  (setq elev (vla-get-textstring attrib))
43.                 )
44.                 ((= "DESCRIPTION" tag)
45.                  (setq desc (vla-get-textstring attrib))
46.                 )
47.           )
48.         )
49.         (write-line
50.           (strcat
51.             pt#
52.             ","
53.             (rtos (cadr (setq pt (vlax-get x 'insertionpoint))))
54.             ","
55.             (rtos (car pt))
56.             ","
57.             elev
58.             ","
59.             desc
60.           )
61.           file
62.         )
63.       )
64.       (setq file (close file))
65.       (vla-delete ss)
66.       (prompt (strcat "\n** " (itoa n) " blocks processed ** "))
67.       (vlax-invoke oShell 'open path)
68.       (*error* nil)
69.     )
70.     (cond (acDoc
71.            (*error* "Unable to create \"Shell.Application Object\"")
72.           )
73.           (n (*error* "Unable to create temporary file"))
74.           ((*error* "No survey points found"))
75.     )
76.   )
77. )
78.  
79.  

[irneb]

Once you've created one of the DXE files, you could always open it in lisp, have your routine create a duplicate while changing the old DWG filepath to the new one, close the file. Then run the -DataExtraction with the modified DXE - it "should" pick up the settings you made manually in that plethora of dialog boxes, but use the new DWG(s) as sources.