Topic: associative dimentions, can i turn of associative in vlisp?

[Amsterdammed]

hello there,

it seems that the vertical we are using has a problem with associative dimensions, sometimes they all go bananas and run all over the place after certain commands. so, can i turn the asso of with a vlisp in existing dimensions?

Thanks!

[BlackBox]

Consider the DIMASSOC System Variable for new Dimensions... Not really sure how to do this for existing Dimensions.

[irneb]

Not really sure how to do this for existing Dimensions.

Move the dimensions an arbitrary distance away, then move them back again.

[zoltan]

Remove the ACAD_DIMASSOC record from the dimension's Extension Dictionary.

Code - Auto/Visual Lisp: [Select]

1. (Defun C:RemoveAssoc()
2.  
3.   (VL-Load-Com )
4.  
5.   (SetQ eDim (Car (EntSel)) )
6.  
7.   (SetQ oDictionary (VLA-GetExtensionDictionary (VLAX-Ename->VLA-Object eDim)) )
8.  
9.   (SetQ entAssocDict (DictSearch (VLAX-VLA-Object->Ename oDictionary) "ACAD_DIMASSOC") )
10.  
11.   (EntDel (Cdr (Assoc -1 entAssocDict)))
12.  
13.   (DictRemove (VLAX-VLA-Object->Ename oDictionary) "ACAD_DIMASSOC" )
14.  
15. )
16.  

(WARNING:  I have not written Lisp in a few years!  That may not be the right way to do it!)

[BlackBox]

Remove the ACAD_DIMASSOC record from the dimension's Extension Dictionary.

Code - Auto/Visual Lisp: [Select]

1. (Defun C:RemoveAssoc()
2.  
3.   (VL-Load-Com )
4.  
5.   (SetQ eDim (Car (EntSel)) )
6.  
7.   (SetQ oDictionary (VLA-GetExtensionDictionary (VLAX-Ename->VLA-Object eDim)) )
8.  
9.   (SetQ entAssocDict (DictSearch (VLAX-VLA-Object->Ename oDictionary) "ACAD_DIMASSOC") )
10.  
11.   (EntDel (Cdr (Assoc -1 entAssocDict)))
12.  
13.   (DictRemove (VLAX-VLA-Object->Ename oDictionary) "ACAD_DIMASSOC" )
14.  
15. )
16.  

(WARNING:  I have not written Lisp in a few years!  That may not be the right way to do it!)

I love the disclaimer, Zoltan... Just beware (= eDim nil). 

[BlackBox]

Also, take from this what you will....

You really should test for the selection(s) being valid dimension entities, on unlocked layers, and include vl-catch-all-apply in the case where Dimensions that have no association are selected.

Pseudo code:

Code - Auto/Visual Lisp: [Select]

1. (defun c:RDA () (c:RemDimAssoc))
2. (defun c:RemDimAssoc  (/ _RemDimAssoc ss i eName)
3.   (vl-load-com)
4.   (princ "\rREMDIMASSOC ")
5.  
6.   (defun _RemDimAssoc  (eName / oDictionary)
7.     (vl-catch-all-apply
8.       'entdel
9.       (list (cdr (assoc -1
10.                         (dictsearch
11.                           (vlax-vla-object->ename
12.                             (setq oDictionary
13.                                    (vla-getextensiondictionary
14.                                      (vlax-ename->vla-object eName))))
15.                           "ACAD_DIMASSOC")))))
16.     (dictremove (vlax-vla-object->ename oDictionary) "ACAD_DIMASSOC"))
17.  
18.   (if (setq ss (ssget "_:L" '((0 . "DIMENSION"))))
19.     (progn
20.       (setq i -1)
21.       (while (setq eName (ssname ss (setq i (1+ i))))
22.         (_RemDimAssoc eName)
23.         )
24.       )
25.     (prompt "\n** Nothing selected ** ")
26.     )
27.   (princ)
28.   )
29.  

** Edit - I forgot to localize 'eName'

[zoltan]

Thank you for the thorough error-handling, RenderMan.  I just threw that together quickly for testing purposes, I never intended anyone to use it in production.

[BlackBox]

Thank you for the thorough error-handling, RenderMan.  I just threw that together quickly for testing purposes, I never intended anyone to use it in production.

Happy to help, Zoltan; I wasn't trying to harp on you. LoL

[Amsterdammed]

Thanks!

[Lee Mac]

I think:

Code - Auto/Visual Lisp: [Select]

1. ;; Remove Dimension Associativity  -  Lee Mac 2012
2. (defun c:rda ( / d e i s )
3.     (if (setq s (ssget "_:L" '((0 . "*DIMENSION") (102 . "{ACAD_XDICTIONARY") (102 . "{ACAD_REACTORS"))))
4.         (repeat (setq i (sslength s))
5.             (setq e (entget (ssname s (setq i (1- i)))))
6.             (dictremove (setq d (cdr (assoc 360 e))) "ACAD_DIMASSOC")
7.             (if (null (dictnext d t))
8.                 (vla-delete (vlax-ename->vla-object d))
9.             )
10.             (vla-delete (vlax-ename->vla-object (cdr (assoc 330 e))))
11.         )
12.     )
13.     (princ)
14. )

[BlackBox]

Succinct as always, Lee.

Cheers, mate! :beer:

[Lee Mac]

Succinct as always, Lee.

Cheers, mate! :beer:

Thanks Renderman 

Be careful with yours, as although it deletes and removes the DIMASSOC Dictionary (though, I think only dictremove is needed here), it will not remove the XDictionary & associated Reactors and hence not truly disassociate the dimension until the user modifies the dimension in some way.

Lee

[BlackBox]

Be careful with yours, as although it deletes and removes the DIMASSOC Dictionary (though, I think only dictremove is needed here), it will not remove the XDictionary & associated Reactors and hence truly disassociate the dimension until the user modifies the dimension in some way.

I always appreciate constructive criticism; as I said above:

... Not really sure how to do this for existing Dimensions.