Topic: Problem retrieving Attribute Tags

[kruuger]

Maybe there's some sort of issue in 2006 with the vlax-for when it encounters a nested block reference.

yes. that's 2006 problem. i was able to make test on this version.
kruuger

[Jeff_M]

It's not the Blockrefderence keeping the lisp from completing, it is the RTEXT object as I mentioned previously. Remove the RTEXT from the block and the routine will run all the way through. This is not a problem in newer versions (2010+?), as the RTEXT ActiveX code was fixed at some point.

[CAB]

Exactly correct, I removed the Rtext from the block and it worked in 2006.
I added the Rtext back which cause it to be the last object in the block definition and it also worked.
Problem may come back it you edit the block (Battman or Block Editor) and any attribute edited may be placed after the Rtext.

[irneb]

So it's probably something like the ObjectName not defined as a property of RText, thus failing when that is called. Perhaps wrap it in a vl-catch-all-apply call. Or perhaps (if that still causes an error) wrap the vlax-for in a vl-catch-all-apply. Something like this:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:GetBlockInternals  (/ en eo blk lst)
3.   (if (and (setq en (entsel "Select Block: "))
4.            (setq eo (vlax-ename->vla-object (car en)))
5.            (eq (vla-get-ObjectName eo) "AcDbBlockReference")
6.            (setq blk (vla-Item (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object)))
7.                                (vla-get-EffectiveName eo))))
8.     (vl-catch-all-apply
9.       '(lambda ()
10.          (vlax-for item  blk
11.            (if (eq (vl-catch-all-apply 'vla-get-ObjectName (list item)) "AcDbAttributeDefinition")
12.              (setq lst (cons (vla-get-PromptString item) lst)))))))
13.   (reverse lst))

[Jeff_M]

CAB already tried the vl-catch-all-apply. Trouble is, it doesn't throw an error, it just stops the execution of the vlax-for loop. RTEXT just plain makes any ActiveX code (lisp and VBA) not work correctly. I complained to Autodesk about this quite often way back when I first encountered it. It took many years of complaining before it was corrected.

[CAB]

So it's probably something like the ObjectName not defined as a property of RText, thus failing when that is called. Perhaps wrap it in a vl-catch-all-apply call. Or perhaps (if that still causes an error) wrap the vlax-for in a vl-catch-all-apply. Something like this:

This is what I get with the bad block:

Code: [Select]

Command: GETBLOCKINTERNALS
Select Block: nil

[irneb]

Hell! So the only workaround would be to use DXF codes instead. Something like this:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:GetAttributePrompts  (/ en eo blk lst)
3.   (if (setq en (entsel "Select Block: "))
4.     (if (> (atoi (getvar "ACADVER")) 16)
5.       (if (and (setq eo (vlax-ename->vla-object (car en)))
6.                (eq (vla-get-ObjectName eo) "AcDbBlockReference")
7.                (setq blk (vla-Item (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object)))
8.                                    (vla-get-EffectiveName eo))))
9.         (vlax-for item  blk
10.           (if (eq (vla-get-ObjectName item) "AcDbAttributeDefinition")
11.             (setq lst (cons (vla-get-PromptString item) lst)))))
12.       (if (and (setq eo (entget (car en)))
13.                (eq "INSERT" (cdr (assoc 0 eo)))
14.                (setq en (tblobjname "BLOCK" (cdr (assoc 2 eo)))))
15.         (while (setq en (entnext en))
16.           (if (eq "ATTDEF" (cdr (assoc 0 (setq eo (entget en)))))
17.             (setq lst (cons (cdr (assoc 3 eo)) lst)))))))
18.   (reverse lst))

Hopefully the "fix" happened since 2007, otherwise the 16 needs to be altered.