Topic: eKeyNotFound

[poncelet]

Hello guys, i'm trying to create a class to manipulate layers. I got a eKeyNotFound when i dimension xr.

Code - vb.net: [Select]

    Public Sub IsolateLayerType(ByVal Name As String)
 
        Using trans As Transaction = db.TransactionManager.StartTransaction()
            Dim lt As LayerTable = trans.GetObject(db.LayerTableId, OpenMode.ForRead)
            Dim v() As TypedValue
 
            For Each id As ObjectId In lt
                Dim ltr As LayerTableRecord
                ltr = trans.GetObject(id, OpenMode.ForWrite)
 
                Dim Dict As DBDictionary = trans.GetObject(ltr.ExtensionDictionary, OpenMode.ForRead, False)
                Dim xr As Xrecord = trans.GetObject(Dict.GetAt("LayerType"), OpenMode.ForRead)
 
                v = xr.Data.AsArray
                If v(0).Value.ToString = Name Then
                    ltr.IsOff = False
                Else
                    ltr.IsOff = True
                End If
            Next
 
        End Using
 
    End Sub
 

[TJK44]

I believe this is because "LayerType" does not exist in the dictionary. You should check if the dictionary contains a record before trying to use the record.

[fixo]

Not sure about if this helps but you may want to use
Try...Catch statement and also add some check to recognize
object state, something like:

Code - vb.net: [Select]

  <CommandMethod("iso")> _
        Public Sub TestIso()
            IsolateLayerType("0")
        End Sub
        Public Sub IsolateLayerType(ByVal Name As String)
            Dim doc = Autodesk.AutoCAD.ApplicationServices.Application.DocumentManager.MdiActiveDocument
            Dim ed = doc.Editor
            Dim db = doc.Database
            Dim result As Boolean = False
            Try
                Using trans As Transaction = db.TransactionManager.StartTransaction()
 
                    Dim lt As LayerTable = trans.GetObject(db.LayerTableId, OpenMode.ForRead)
                    Dim v() As TypedValue
                    For Each id As ObjectId In lt
 
                        Dim ltr As LayerTableRecord
                        ltr = trans.GetObject(id, OpenMode.ForWrite)
                        If db.Clayer = id Then
                            Continue For
                        End If
 
                        Dim Dict As DBDictionary = trans.GetObject(ltr.ExtensionDictionary, OpenMode.ForRead, False)
                        Dim xr As Xrecord = TryCast(trans.GetObject(Dict.GetAt("LayerType"), OpenMode.ForRead), Xrecord)
                        If xr Is Nothing Then
                            ed.WriteMessage(vbLf + "Key not found")
                            result = False
                            Return
                        End If
                        v = xr.Data.AsArray
                        If v(0).Value.ToString = Name Then
 
                            ltr.IsOff = False
                        Else
                            ltr.IsOff = True
                        End If
                        result = True
                    Next
                    trans.Commit()
                End Using
 
            Catch ex As System.Exception
                ed.WriteMessage(ex.ToString)
            Finally
                ed.WriteMessage(vbLf + "Program ended up with result of: {0}", result)
            End Try
        End Sub

~'J'~


edit:kdub->code = vbnet

[TJK44]

If xr Is Nothing Then
                           ed.WriteMessage(vbLf + "Key not found")
                           result = False
                           Return
                       End If

fixo, correct me if I'm wrong but I don't think you'll ever reach this bit of code if the key is not found because there will be an error when trying to Dim xr if the record does not exist. I think the better way to do this is check if the dictionary contains the key and if it does then use it. Sorry if I'm wrong on this... I havent been programming CAD very long. Just my two cents.

[poncelet]

Thanks guys. You were right. Didn't check if xrecord exists.

Code - vb.net: [Select]

    Public Sub IsolateLayerType(ByVal Name As String)
 
        Using trans As Transaction = db.TransactionManager.StartTransaction()
            Dim lt As LayerTable = trans.GetObject(db.LayerTableId, OpenMode.ForRead)
            Dim v() As TypedValue
 
            For Each id As ObjectId In lt
                Dim ltr As LayerTableRecord
                ltr = trans.GetObject(id, OpenMode.ForWrite)
 
                If ltr.ExtensionDictionary = ObjectId.Null Then
                    ltr.IsOff = True
                    Continue For
                End If
 
                Dim Dict As DBDictionary = trans.GetObject(ltr.ExtensionDictionary, OpenMode.ForRead, False)
 
                If Not Dict.Contains("LayerType") Then
                    ltr.IsOff = True
                    Continue For
                End If
 
                Dim xr As Xrecord = trans.GetObject(Dict.GetAt("LayerType"), OpenMode.ForRead)
 
                v = xr.Data.AsArray
                If v(0).Value.ToString = Name Then
                    ltr.IsOff = False
                Else
                    ltr.IsOff = True
                End If
            Next
 
            trans.Commit()
        End Using
 
    End Sub

[fixo]

If xr Is Nothing Then
                           ed.WriteMessage(vbLf + "Key not found")
                           result = False
                           Return
                       End If

fixo, correct me if I'm wrong but I don't think you'll ever reach this bit of code if the key is not found because there will be an error when trying to Dim xr if the record does not exist. I think the better way to do this is check if the dictionary contains the key and if it does then use it. Sorry if I'm wrong on this... I havent been programming CAD very long. Just my two cents.

I think you are completely right, firstly we need to check if dictionary exists, then go further..
Regards,

~'J'~

[fixo]

Thanks guys. You were right. Didn't check if xrecord exists.

Glad if this helps
Cheers

~'J'~